configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl Init autoconf
   4 AC_INIT(src/aubio.h)
   5
   6 dnl Package name and version
   7 PACKAGE=aubio
   8 . $srcdir/VERSION
   9 AUBIO_VERSION=${AUBIO_MAJOR_VERSION}.${AUBIO_MINOR_VERSION}.${AUBIO_PATCH_VERSION}${AUBIO_VERSION_STATUS}
  10 VERSION=${AUBIO_VERSION}
  11
  12 dnl Shared library version
  13 SHARED_VERSION_INFO=${LIBAUBIO_LT_CUR}:${LIBAUBIO_LT_REV}:${LIBAUBIO_LT_AGE}
  14 AC_SUBST(SHARED_VERSION_INFO)
  15
  16 dnl Init automake
  17 AM_INIT_AUTOMAKE(${PACKAGE}, ${VERSION})
  18
  19 dnl Enable silent rules, use with make V=0
  20 dnl AM_SILENT_RULES
  21
  22 dnl Maintainer mode
  23 AM_MAINTAINER_MODE
  24
  25 dnl Guess the host
  26 AC_CANONICAL_HOST
  27
  28 dnl Check for programs
  29 AC_PROG_CC
  30 AM_PROG_CC_C_O dnl compiling with per-target flag
  31 if test "$ac_cv_prog_cc" = "no" ; then
  32    AC_MSG_ERROR([*** No C compiler found !])
  33 fi
  34 AC_PROG_CXX
  35 AC_PROG_INSTALL
  36
  37 AUBIO_CFLAGS=
  38
  39 dnl Enable double precision (no)
  40 AC_ARG_ENABLE(double,
  41   AC_HELP_STRING([--enable-double],[compile in double precision [[default=no]]]),
  42   with_double_precision="yes",
  43   with_double_precision="no")
  44 if test "$with_double_precision" = "yes"
  45 then
  46   AC_DEFINE(HAVE_AUBIO_DOUBLE,1,[Define to enable double precision])
  47 fi
  48
  49 dnl Enable debugging (no)
  50 AC_ARG_ENABLE(debug,
  51   AC_HELP_STRING([--enable-debug],[compile in debug mode [[default=no]]]),
  52   with_debug="yes",
  53   with_debug="no")
  54 if test "$with_debug" = "yes"
  55 then
  56   AC_DEFINE(DEBUG,1,[Define to enable debug])
  57   AUBIO_CFLAGS="$AUBIO_CFLAGS -g"
  58 fi
  59
  60 dnl Enable full warnings (yes)
  61 AC_ARG_ENABLE(warnings,
  62   AC_HELP_STRING([--enable-warnings],[compile with all gcc warnings [[default=yes]]]),
  63   with_warnme="no",
  64   with_warnme="yes")
  65 if test "$with_warnme" = "yes"
  66 then
  67   dnl Check for -Wextra support to allow compilation on gcc <= 3.4
  68   AC_CACHE_CHECK([for -Wextra option to $CC], ac_cv_cc_wextra,
  69   [old_CFLAGS="$CFLAGS"
  70   CFLAGS="$CFLAGS -Wextra"
  71   AC_COMPILE_IFELSE([void foo (void) {}],
  72           ac_cv_cc_wextra=yes, ac_cv_cc_wextra=no)
  73   CFLAGS="$old_CFLAGS"
  74   ])
  75   if test "$ac_cv_cc_wextra" = "yes"
  76   then
  77     AUBIO_CFLAGS="$AUBIO_CFLAGS -Wall -Wextra"
  78   else
  79     AUBIO_CFLAGS="$AUBIO_CFLAGS -Wall"
  80   fi
  81 fi
  82
  83 dnl fail on compilation warnings
  84 AC_ARG_ENABLE(errorfail,
  85   AC_HELP_STRING([--enable-errorfail],[fail on compilation warnings [[default=no]]]),
  86   AUBIO_CFLAGS="$AUBIO_CFLAGS -Werror -Wmissing-prototypes -Wmissing-declarations -Wno-unused-parameter",
  87   with_errorfail="no")
  88
  89 dnl add gcov/lcov profiling and coverage flags
  90 AC_ARG_ENABLE(lcov,
  91   AC_HELP_STRING([--enable-lcov],[compile with gcov/lcov profiling flags [[default=no]]]),
  92   AUBIO_CFLAGS="$AUBIO_CFLAGS -fprofile-arcs -ftest-coverage",
  93   with_lcov="no")
  94
  95 dnl Check for libtool
  96 AC_LIBTOOL_DLOPEN
  97 dnl AC_DISABLE_STATIC
  98 dnl allow cross compiling
  99 AC_LIBTOOL_WIN32_DLL
 100 AC_PROG_LIBTOOL
 101
 102 AC_CONFIG_HEADERS(src/config.h)
 103 AC_CONFIG_FILES(aubio.pc)
 104
 105 AM_CONDITIONAL(MINGW, false)
 106 AM_CONDITIONAL(DARWIN, false)
 107 case "${host}" in
 108 *mingw* | *cygwin*)
 109   mingw32_support="yes"
 110   AC_CHECK_HEADER(windows.h)
 111   AM_CONDITIONAL(MINGW, true)
 112   LDFLAGS="$LDFLAGS -no-undefined"
 113   ;;
 114 *darwin* | *rhapsody* | *macosx*)
 115   AC_ISC_POSIX
 116   AM_CONDITIONAL(DARWIN, true)
 117   ;;
 118 *)
 119   AC_ISC_POSIX
 120   ;;
 121 esac
 122
 123 dnl Check for required libraries
 124 AC_CHECK_LIB(pthread, pthread_create)
 125
 126 dnl Check for header files
 127 AC_CHECK_HEADERS([string.h stdlib.h stdio.h math.h limits.h errno.h stdarg.h unistd.h signal.h],,)
 128 AC_CHECK_HEADERS(fftw3.h,,AC_MSG_ERROR([Ouch! missing fftw3.h header]))
 129 AC_ARG_ENABLE(complex,
 130   AC_HELP_STRING([--enable-complex],[compile with complex.h [[default=auto]]]),
 131   [with_complex=$enableval],
 132   with_complex="yes")
 133 if test "$with_complex" = "yes"; then
 134   AC_CHECK_HEADERS(complex.h,,AC_MSG_WARN([Ouch! missing complex.h header]))
 135 fi
 136
 137 dnl Check for __VAR_ARGS__ support
 138 AC_CACHE_CHECK(for C99 __VA_ARGS__ macro,
 139     ac_cv_varargs_macros,
 140 AC_TRY_COMPILE([
 141   #include <stdio.h>
 142   #define AUBIO_ERR(...)                       fprintf(stderr, __VA_ARGS__)
 143 ],
 144 [
 145   AUBIO_ERR("%s\n", "ERR");
 146 ],
 147         ac_cv_varargs_macros=yes,
 148         ac_cv_varargs_macros=no)
 149 )
 150 if test "$ac_cv_varargs_macros" = "yes"; then
 151     AC_DEFINE(HAVE_C99_VARARGS_MACROS, 1,
 152             [Defined when c99 style varargs macros are supported])
 153 fi
 154
 155 dnl Check for pkg-config
 156 AC_PATH_PROG(PKG_CONFIG,pkg-config,no)
 157
 158 PKG_CHECK_MODULES(SNDFILE,     sndfile >= 1.0.4,       HAVE_SNDFILE=1)
 159 if test "${HAVE_SNDFILE}" = "1"; then
 160   AC_DEFINE(HAVE_SNDFILE,1,[Define to enable libsndfile support])
 161 fi
 162
 163 dnl Enable samplerate support (auto)
 164 AC_ARG_ENABLE(samplerate,
 165   AC_HELP_STRING([--enable-samplerate],[compile with samplerate [[default=auto]]]),
 166   [with_samplerate=$enableval],
 167   with_samplerate="yes")
 168 if test "$with_samplerate" = "yes"; then
 169   PKG_CHECK_MODULES(SAMPLERATE, samplerate  >= 0.0.15,  HAVE_SAMPLERATE=1,
 170                     HAVE_SAMPLERATE=0)
 171   if test "${HAVE_SAMPLERATE}" = "1"; then
 172     AC_DEFINE(HAVE_SAMPLERATE,1,[Define to enable libsamplerate support])
 173   fi
 174 fi
 175
 176 dnl Check for fftw3 (required)
 177 dnl if we compile in double precsion, default to fftw3, else fftw3f
 178 if test "$with_double_precision" = "yes"; then
 179     default_fftw3f="no"
 180 else
 181     default_fftw3f="yes"
 182 fi
 183 AC_ARG_ENABLE(fftw3f,
 184   AC_HELP_STRING([--enable-fftw3f],[compile with fftw3f [[default=auto]]]),
 185   [with_fftw3f=$enableval],
 186   [with_fftw3f=$default_fftw3f])
 187 if test "$with_fftw3f" = "yes"; then
 188   PKG_CHECK_MODULES(FFTWLIB,    fftw3f >= 3.0.0,     HAVE_FFTW3F=1, HAVE_FFTW3F=0)
 189 else
 190   PKG_CHECK_MODULES(FFTWLIB,    fftw3  >= 3.0.0,     HAVE_FFTW3=1)
 191 fi
 192 if test "${HAVE_FFTW3F}" = "0"; then
 193   PKG_CHECK_MODULES(FFTWLIB,    fftw3  >= 3.0.0,     HAVE_FFTW3=1)
 194 fi
 195 if test "${HAVE_FFTW3}" = "1"; then
 196   AC_DEFINE(HAVE_FFTW3,1,[Define to enable fftw3 support])
 197 fi
 198 if test "${HAVE_FFTW3F}" = "1"; then
 199   AC_DEFINE(HAVE_FFTW3F,1,[Define to enable fftw3f support])
 200 fi
 201
 202 dnl Enable jack support (auto)
 203 AC_ARG_ENABLE(jack,
 204   AC_HELP_STRING([--enable-jack],[compile with jack [[default=auto]]]),
 205   [with_jack=$enableval],
 206   with_jack="yes")
 207 if test "$with_jack" = "yes"
 208 then
 209   PKG_CHECK_MODULES(JACK,       jack  >= 0.15.0,     HAVE_JACK=1, HAVE_JACK=0)
 210   if test "${HAVE_JACK}" = "1"; then
 211     AC_DEFINE(HAVE_JACK,1,[Define to enable jack support])
 212   fi
 213 fi
 214
 215 dnl Enable lash support
 216 AC_ARG_ENABLE(lash,
 217   AC_HELP_STRING([--enable-lash],[compile with lash [[default=auto]]]),
 218   [with_lash=$enableval],
 219   with_lash="yes")
 220 if test "$with_lash" = "yes"
 221 then
 222   PKG_CHECK_MODULES(LASH,   lash-1.0 >= 0.5.0,   HAVE_LASH=1, HAVE_LASH=0)
 223   if test "${HAVE_LASH}" = "1"; then
 224     LASH_CFLAGS+="-DHAVE_LASH"
 225   fi
 226 fi
 227
 228 dnl Enable unit tests
 229 AC_ARG_ENABLE(testprogs,
 230   AC_HELP_STRING([--enable-testprogs],[compile test programs [[default=no]]]),
 231   [with_testprogs=$enableval],
 232   with_testprogs="no")
 233 AM_CONDITIONAL(COMPILE_TESTS,test "${with_testprogs}" != "no")
 234
 235 AC_SUBST(AUBIO_CFLAGS)
 236
 237 dnl Check for swig and python
 238 dnl should check for swig version and python headers
 239 AC_PATH_PROG(SWIG,swig,no)
 240 AM_CONDITIONAL(SWIGFOUND, test "${SWIG}" != "no")
 241 AM_PATH_PYTHON
 242 AM_CONDITIONAL(PYTHONFOUND, test "${PYTHON}" != "no")
 243
 244 dnl Check for docbook-to-man
 245 AC_PATH_PROG(DOCBOOK_TO_MAN,docbook-to-man,no)
 246 AM_CONDITIONAL(DOCBOOKFOUND, test "${DOCBOOK_TO_MAN}" != "no")
 247
 248 dnl Check for Puredata
 249 AC_CHECK_HEADER(m_pd.h,PUREDATA=y,AC_MSG_WARN([Puredata header not found.]))
 250 AM_CONDITIONAL(PUREDATAFOUND, test "${PUREDATA}" = "y")
 251
 252 dnl Check for Java
 253 AC_CHECK_HEADER(jni.h,JAVAHEADERS=y,AC_MSG_WARN([Java header jni.h not found.]))
 254 AM_CONDITIONAL(JAVAFOUND, test "${JAVAHEADERS}" = "y")
 255
 256 dnl Create Makefiles
 257 AC_OUTPUT([
 258     Makefile
 259     src/Makefile
 260     examples/Makefile
 261     tests/Makefile
 262     tests/src/Makefile
 263     tests/cpp/Makefile
 264     sounds/Makefile
 265     swig/Makefile
 266     python/Makefile
 267     python/aubio/Makefile
 268     interfaces/java/Makefile
 269     interfaces/java/aubio/Makefile
 270     interfaces/cpp/Makefile
 271     plugins/Makefile
 272     plugins/audacity/Makefile
 273     plugins/audacity/plug-ins/Makefile
 274     plugins/wavesurfer/Makefile
 275     plugins/puredata/Makefile
 276     doc/Makefile
 277   ])
 278
 279 dnl Print summary
 280 echo
 281 echo "**************************************************************"
 282 echo "Summary:"
 283 if test "${HAVE_FFTW3F}" = "1"; then
 284   echo "Fftw3:                   yes (using fftw3f)"
 285 else
 286 if test "${HAVE_FFTW3}" = "1"; then
 287   echo "Fftw3:                   yes (not using fftw3f)"
 288 else
 289   echo "Fftw3:                   no (that should not happen)"
 290 fi
 291 fi
 292 if test "${HAVE_SNDFILE}" = "1"; then
 293   echo "Libsndfile:              yes"
 294 else
 295   echo "Libsndfile:              no"
 296 fi
 297 if test "${HAVE_SAMPLERATE}" = "1"; then
 298   echo "Libsamplerate:           yes"
 299 else
 300   echo "Libsamplerate:           no"
 301 fi
 302 if test "${HAVE_JACK}" = "1"; then
 303   echo "JACK:                    yes"
 304 else
 305   echo "JACK:                    no"
 306 fi
 307 if test "${HAVE_LASH}" = "1"; then
 308   echo "Lash:                    yes"
 309 else
 310   echo "Lash:                    no"
 311 fi
 312 if test "${PUREDATA}" = "y"; then
 313   echo "PureData:                yes"
 314 else
 315   echo "PureData:                no"
 316 fi
 317 echo "**************************************************************"
 318 echo Configuration completed successfully. Type \'make\' to build ${PACKAGE}