IkiWiki/Plugin/search.pm

   1 #!/usr/bin/perl
   2 # xapian-omega search engine plugin
   3 package IkiWiki::Plugin::search;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 2.00;
   8
   9 sub import { #{{{
  10         hook(type => "checkconfig", id => "search", call => \&checkconfig);
  11         hook(type => "pagetemplate", id => "search", call => \&pagetemplate);
  12         hook(type => "sanitize", id => "search", call => \&index);
  13         hook(type => "delete", id => "search", call => \&delete);
  14         hook(type => "cgi", id => "search", call => \&cgi);
  15 } # }}}
  16
  17 sub checkconfig () { #{{{
  18         foreach my $required (qw(url cgiurl)) {
  19                 if (! length $config{$required}) {
  20                         error(sprintf(gettext("Must specify %s when using the search plugin"), $required));
  21                 }
  22         }
  23
  24         if (! exists $config{omega_cgi}) {
  25                 $config{omega_cgi}="/usr/lib/cgi-bin/omega/omega";
  26         }
  27
  28         if (! -e $config{wikistatedir}."/xapian" || $config{rebuild}) {
  29                 writefile("omega.conf", $config{wikistatedir}."/xapian",
  30                         "database_dir .\n".
  31                         "template_dir ./templates\n");
  32                 writefile("query", $config{wikistatedir}."/xapian/templates",
  33                         IkiWiki::misctemplate(gettext("search"),
  34                                 readfile(IkiWiki::template_file("searchquery.tmpl"))));
  35         }
  36 } #}}}
  37
  38 my $form;
  39 sub pagetemplate (@) { #{{{
  40         my %params=@_;
  41         my $page=$params{page};
  42         my $template=$params{template};
  43
  44         # Add search box to page header.
  45         if ($template->query(name => "searchform")) {
  46                 if (! defined $form) {
  47                         my $searchform = template("searchform.tmpl", blind_cache => 1);
  48                         $searchform->param(searchaction => $config{cgiurl});
  49                         $form=$searchform->output;
  50                 }
  51
  52                 $template->param(searchform => $form);
  53         }
  54 } #}}}
  55
  56 my $scrubber;
  57 sub index (@) { #{{{
  58         my %params=@_;
  59
  60         return $params{content} if $IkiWiki::preprocessing{$params{destpage}};
  61
  62         my $db=xapiandb();
  63         my $doc=Search::Xapian::Document->new();
  64         my $title;
  65         if (exists $pagestate{$params{page}}{meta} &&
  66             exists $pagestate{$params{page}}{meta}{title}) {
  67                 $title=$pagestate{$params{page}}{meta}{title};
  68         }
  69         else {
  70                 $title=IkiWiki::pagetitle($params{page});
  71         }
  72
  73         # Remove html from text to be indexed.
  74         if (! defined $scrubber) {
  75                 eval q{use HTML::Scrubber};
  76                 if (! $@) {
  77                         $scrubber=HTML::Scrubber->new(allow => []);
  78                 }
  79         }
  80         my $toindex = defined $scrubber ? $scrubber->scrub($params{content}) : $params{content};
  81
  82         # Take 512 characters for a sample, then extend it out
  83         # if it stopped in the middle of a word.
  84         my $size=512;
  85         my ($sample)=substr($toindex, 0, $size);
  86         if (length($sample) == $size) {
  87                 my $max=length($toindex);
  88                 my $next;
  89                 while ($size < $max &&
  90                        ($next=substr($toindex, $size++, 1)) !~ /\s/) {
  91                         $sample.=$next;
  92                 }
  93         }
  94         $sample=~s/\n/ /g;
  95         # Decode html entities in the sample since omega encodes them.
  96         eval q{use HTML::Entities};
  97         $sample=decode_entities($sample);
  98
  99         # data used by omega
 100         $doc->set_data(
 101                 "url=".urlto($params{page}, "")."\n".
 102                 "sample=$sample\n".
 103                 "caption=$title\n".
 104                 "modtime=$IkiWiki::pagemtime{$params{page}}\n".
 105                 "size=".length($params{content})."\n"
 106         );
 107
 108         my $tg = Search::Xapian::TermGenerator->new();
 109         $tg->set_stemmer(new Search::Xapian::Stem("english"));
 110         $tg->set_document($doc);
 111         $tg->index_text($params{page}, 2);
 112         $tg->index_text($title, 2);
 113         $tg->index_text($toindex);
 114
 115         my $pageterm=pageterm($params{page});
 116         $doc->add_term($pageterm);
 117         $db->replace_document_by_term($pageterm, $doc);
 118
 119         return $params{content};
 120 } #}}}
 121
 122 sub delete (@) { #{{{
 123         my $db=xapiandb();
 124         foreach my $page (@_) {
 125                 $db->delete_document_by_term(pageterm(pagename($page)));
 126         }
 127 } #}}}
 128
 129 sub cgi ($) { #{{{
 130         my $cgi=shift;
 131
 132         if (defined $cgi->param('P')) {
 133                 # only works for GET requests
 134                 chdir("$config{wikistatedir}/xapian") || error("chdir: $!");
 135                 $ENV{OMEGA_CONFIG_FILE}="./omega.conf";
 136                 $ENV{CGIURL}=$config{cgiurl},
 137                 exec($config{omega_cgi}) || error("$config{omega_cgi} failed: $!");
 138         }
 139 } #}}}
 140
 141 sub pageterm ($) { #{{{
 142         my $page=shift;
 143
 144         # TODO: check if > 255 char page names overflow term
 145         # length; use sha1 if so?
 146         return "U:".$page;
 147 } #}}}
 148
 149 my $db;
 150 sub xapiandb () { #{{{
 151         if (! defined $db) {
 152                 eval q{
 153                         use Search::Xapian;
 154                         use Search::Xapian::WritableDatabase;
 155                 };
 156                 error($@) if $@;
 157                 $db=Search::Xapian::WritableDatabase->new($config{wikistatedir}."/xapian/default",
 158                         Search::Xapian::DB_CREATE_OR_OPEN());
 159         }
 160         return $db;
 161 } #}}}
 162
 163 1