IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                 },
  53                 rss => {
  54                         type => "boolean",
  55                         example => 0,
  56                         description => "enable rss feeds by default?",
  57                         safe => 1,
  58                         rebuild => 1,
  59                 },
  60                 atom => {
  61                         type => "boolean",
  62                         example => 0,
  63                         description => "enable atom feeds by default?",
  64                         safe => 1,
  65                         rebuild => 1,
  66                 },
  67                 allowrss => {
  68                         type => "boolean",
  69                         example => 0,
  70                         description => "allow rss feeds to be used?",
  71                         safe => 1,
  72                         rebuild => 1,
  73                 },
  74                 allowatom => {
  75                         type => "boolean",
  76                         example => 0,
  77                         description => "allow atom feeds to be used?",
  78                         safe => 1,
  79                         rebuild => 1,
  80                 },
  81                 pingurl => {
  82                         type => "string",
  83                         example => "http://rpc.technorati.com/rpc/ping",
  84                         description => "urls to ping (using XML-RPC) on feed update",
  85                         safe => 1,
  86                         rebuild => 0,
  87                 },
  88 }
  89
  90 sub checkconfig () {
  91         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  92                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  93         }
  94         if ($config{rss}) {
  95                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  96         }
  97         if ($config{atom}) {
  98                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
  99         }
 100         if (! exists $config{pingurl}) {
 101                 $config{pingurl}=[];
 102         }
 103 }
 104
 105 sub format (@) {
 106         my %params=@_;
 107
 108         # Fill in the inline content generated earlier. This is actually an
 109         # optimisation.
 110         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 111                 delete @inline[$1,]
 112         }eg;
 113         return $params{content};
 114 }
 115
 116 sub sessioncgi ($$) {
 117         my $q=shift;
 118         my $session=shift;
 119
 120         if ($q->param('do') eq 'blog') {
 121                 my $page=titlepage(decode_utf8($q->param('title')));
 122                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 123                 # if the page already exists, munge it to be unique
 124                 my $from=$q->param('from');
 125                 my $add="";
 126                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 127                         $add=1 unless length $add;
 128                         $add++;
 129                 }
 130                 $q->param('page', $page.$add);
 131                 # now go create the page
 132                 $q->param('do', 'create');
 133                 # make sure the editpage plugin in loaded
 134                 if (IkiWiki->can("cgi_editpage")) {
 135                         IkiWiki::cgi_editpage($q, $session);
 136                 }
 137                 else {
 138                         error(gettext("page editing not allowed"));
 139                 }
 140                 exit;
 141         }
 142 }
 143
 144 # Back to ikiwiki namespace for the rest, this code is very much
 145 # internal to ikiwiki even though it's separated into a plugin.
 146 package IkiWiki;
 147
 148 my %toping;
 149 my %feedlinks;
 150
 151 sub preprocess_inline (@) {
 152         my %params=@_;
 153
 154         if (! exists $params{pages} && ! exists $params{pagenames}) {
 155                 error gettext("missing pages parameter");
 156         }
 157         my $raw=yesno($params{raw});
 158         my $archive=yesno($params{archive});
 159         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 160         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 161         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 162         my $feeds=exists $params{feeds} ? yesno($params{feeds}) : !$quick;
 163         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 164         my $feedonly=yesno($params{feedonly});
 165         if (! exists $params{show} && ! $archive) {
 166                 $params{show}=10;
 167         }
 168         if (! exists $params{feedshow} && exists $params{show}) {
 169                 $params{feedshow}=$params{show};
 170         }
 171         my $desc;
 172         if (exists $params{description}) {
 173                 $desc = $params{description}
 174         }
 175         else {
 176                 $desc = $config{wikiname};
 177         }
 178         my $actions=yesno($params{actions});
 179         if (exists $params{template}) {
 180                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 181         }
 182         else {
 183                 $params{template} = $archive ? "archivepage" : "inlinepage";
 184         }
 185
 186         my @list;
 187
 188         if (exists $params{pagenames}) {
 189                 foreach my $p (qw(sort pages)) {
 190                         if (exists $params{$p}) {
 191                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 192                                         "pagenames", $p);
 193                         }
 194                 }
 195
 196                 @list = map { bestlink($params{page}, $_) }
 197                         split ' ', $params{pagenames};
 198
 199                 if (yesno($params{reverse})) {
 200                         @list=reverse(@list);
 201                 }
 202
 203                 foreach my $p (@list) {
 204                         add_depends($params{page}, $p, deptype($quick ? "presence" : "content"));
 205                 }
 206         }
 207         else {
 208                 my $num=0;
 209                 if ($params{show}) {
 210                         $num=$params{show};
 211                 }
 212                 if ($params{feedshow} && $num < $params{feedshow}) {
 213                         $num=$params{feedshow};
 214                 }
 215                 if ($params{skip}) {
 216                         $num+=$params{skip};
 217                 }
 218
 219                 @list = use_pagespec($params{page}, $params{pages},
 220                         deptype => deptype($quick ? "presence" : "content"),
 221                         limit => sub { $_[0] ne $params{page} },
 222                         sort => exists $params{sort} ? $params{sort} : "age",
 223                         reverse => yesno($params{reverse}),
 224                         num => $num,
 225                 );
 226         }
 227
 228         if (exists $params{skip}) {
 229                 @list=@list[$params{skip} .. $#list];
 230         }
 231
 232         my @feedlist;
 233         if ($feeds) {
 234                 if (exists $params{feedshow} &&
 235                     $params{feedshow} && @list > $params{feedshow}) {
 236                         @feedlist=@list[0..$params{feedshow} - 1];
 237                 }
 238                 else {
 239                         @feedlist=@list;
 240                 }
 241         }
 242
 243         if ($params{show} && @list > $params{show}) {
 244                 @list=@list[0..$params{show} - 1];
 245         }
 246
 247         if ($feeds && exists $params{feedpages}) {
 248                 @feedlist = use_pagespec($params{page}, "($params{pages}) and ($params{feedpages})",
 249                         deptype => deptype($quick ? "presence" : "content"),
 250                         list => \@feedlist);
 251         }
 252
 253         my ($feedbase, $feednum);
 254         if ($feeds) {
 255                 # Ensure that multiple feeds on a page go to unique files.
 256
 257                 # Feedfile can lead to conflicts if usedirs is not enabled,
 258                 # so avoid supporting it in that case.
 259                 delete $params{feedfile} if ! $config{usedirs};
 260                 # Tight limits on legal feedfiles, to avoid security issues
 261                 # and conflicts.
 262                 if (defined $params{feedfile}) {
 263                         if ($params{feedfile} =~ /\// ||
 264                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 265                                 error("illegal feedfile");
 266                         }
 267                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 268                 }
 269                 $feedbase=targetpage($params{destpage}, "", $params{feedfile});
 270
 271                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 272                 if (exists $knownfeeds{$feedid}) {
 273                         $feednum=$knownfeeds{$feedid};
 274                 }
 275                 else {
 276                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 277                                 if ($feeds) {
 278                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 279                                 }
 280                         }
 281                         else {
 282                                 $feednum=$knownfeeds{$feedid}="";
 283                                 if ($feeds) {
 284                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 285                                 }
 286                         }
 287                 }
 288         }
 289
 290         my $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $rss;
 291         my $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $atom;
 292
 293         my $ret="";
 294
 295         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 296             (exists $params{postform} && yesno($params{postform}))) &&
 297             IkiWiki->can("cgi_editpage")) {
 298                 # Add a blog post form, with feed buttons.
 299                 my $formtemplate=template("blogpost.tmpl", blind_cache => 1);
 300                 $formtemplate->param(cgiurl => $config{cgiurl});
 301                 $formtemplate->param(rootpage => rootpage(%params));
 302                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 303                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 304                 if (exists $params{postformtext}) {
 305                         $formtemplate->param(postformtext =>
 306                                 $params{postformtext});
 307                 }
 308                 else {
 309                         $formtemplate->param(postformtext =>
 310                                 gettext("Add a new post titled:"));
 311                 }
 312                 $ret.=$formtemplate->output;
 313
 314                 # The post form includes the feed buttons, so
 315                 # emptyfeeds cannot be hidden.
 316                 $emptyfeeds=1;
 317         }
 318         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
 319                 # Add feed buttons.
 320                 my $linktemplate=template("feedlink.tmpl", blind_cache => 1);
 321                 $linktemplate->param(rssurl => $rssurl) if $rss;
 322                 $linktemplate->param(atomurl => $atomurl) if $atom;
 323                 $ret.=$linktemplate->output;
 324         }
 325
 326         if (! $feedonly) {
 327                 require HTML::Template;
 328                 my @params=IkiWiki::template_params($params{template}.".tmpl", blind_cache => 1);
 329                 if (! @params) {
 330                         error sprintf(gettext("nonexistant template %s"), $params{template});
 331                 }
 332                 my $template=HTML::Template->new(@params) unless $raw;
 333
 334                 foreach my $page (@list) {
 335                         my $file = $pagesources{$page};
 336                         my $type = pagetype($file);
 337                         if (! $raw || ($raw && ! defined $type)) {
 338                                 unless ($archive && $quick) {
 339                                         # Get the content before populating the
 340                                         # template, since getting the content uses
 341                                         # the same template if inlines are nested.
 342                                         my $content=get_inline_content($page, $params{destpage});
 343                                         $template->param(content => $content);
 344                                 }
 345                                 $template->param(pageurl => urlto($page, $params{destpage}));
 346                                 $template->param(inlinepage => $page);
 347                                 $template->param(title => pagetitle(basename($page)));
 348                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}));
 349                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 350                                 $template->param(first => 1) if $page eq $list[0];
 351                                 $template->param(last => 1) if $page eq $list[$#list];
 352
 353                                 if ($actions) {
 354                                         my $file = $pagesources{$page};
 355                                         my $type = pagetype($file);
 356                                         if ($config{discussion}) {
 357                                                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/ &&
 358                                                     (length $config{cgiurl} ||
 359                                                      exists $links{$page."/".$config{discussionpage}})) {
 360                                                         $template->param(have_actions => 1);
 361                                                         $template->param(discussionlink =>
 362                                                                 htmllink($page,
 363                                                                         $params{destpage},
 364                                                                         $config{discussionpage},
 365                                                                         noimageinline => 1,
 366                                                                         forcesubpage => 1));
 367                                                 }
 368                                         }
 369                                         if (length $config{cgiurl} && defined $type) {
 370                                                 $template->param(have_actions => 1);
 371                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 372                                         }
 373                                 }
 374
 375                                 run_hooks(pagetemplate => sub {
 376                                         shift->(page => $page, destpage => $params{destpage},
 377                                                 template => $template,);
 378                                 });
 379
 380                                 $ret.=$template->output;
 381                                 $template->clear_params;
 382                         }
 383                         else {
 384                                 if (defined $type) {
 385                                         $ret.="\n".
 386                                               linkify($page, $params{destpage},
 387                                               preprocess($page, $params{destpage},
 388                                               filter($page, $params{destpage},
 389                                               readfile(srcfile($file)))));
 390                                 }
 391                         }
 392                 }
 393         }
 394
 395         if ($feeds && ($emptyfeeds || @feedlist)) {
 396                 if ($rss) {
 397                         my $rssp=$feedbase."rss".$feednum;
 398                         will_render($params{destpage}, $rssp);
 399                         if (! $params{preview}) {
 400                                 writefile($rssp, $config{destdir},
 401                                         genfeed("rss",
 402                                                 $config{url}."/".$rssp, $desc, $params{guid}, $params{destpage}, @feedlist));
 403                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 404                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$desc (RSS)" href="$rssurl" />};
 405                         }
 406                 }
 407                 if ($atom) {
 408                         my $atomp=$feedbase."atom".$feednum;
 409                         will_render($params{destpage}, $atomp);
 410                         if (! $params{preview}) {
 411                                 writefile($atomp, $config{destdir},
 412                                         genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{destpage}, @feedlist));
 413                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 414                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$desc (Atom)" href="$atomurl" />};
 415                         }
 416                 }
 417         }
 418
 419         return $ret if $raw || $nested;
 420         push @inline, $ret;
 421         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 422 }
 423
 424 sub pagetemplate_inline (@) {
 425         my %params=@_;
 426         my $page=$params{page};
 427         my $template=$params{template};
 428
 429         $template->param(feedlinks => $feedlinks{$page})
 430                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 431 }
 432
 433 sub get_inline_content ($$) {
 434         my $page=shift;
 435         my $destpage=shift;
 436
 437         my $file=$pagesources{$page};
 438         my $type=pagetype($file);
 439         if (defined $type) {
 440                 $nested++;
 441                 my $ret=htmlize($page, $destpage, $type,
 442                        linkify($page, $destpage,
 443                        preprocess($page, $destpage,
 444                        filter($page, $destpage,
 445                        readfile(srcfile($file))))));
 446                 $nested--;
 447                 return $ret;
 448         }
 449         else {
 450                 return "";
 451         }
 452 }
 453
 454 sub date_822 ($) {
 455         my $time=shift;
 456
 457         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 458         POSIX::setlocale(&POSIX::LC_TIME, "C");
 459         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 460         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 461         return $ret;
 462 }
 463
 464 sub date_3339 ($) {
 465         my $time=shift;
 466
 467         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 468         POSIX::setlocale(&POSIX::LC_TIME, "C");
 469         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
 470         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 471         return $ret;
 472 }
 473
 474 sub absolute_urls ($$) {
 475         # sucky sub because rss sucks
 476         my $content=shift;
 477         my $baseurl=shift;
 478
 479         my $url=$baseurl;
 480         $url=~s/[^\/]+$//;
 481
 482         # what is the non path part of the url?
 483         my $top_uri = URI->new($url);
 484         $top_uri->path_query(""); # reset the path
 485         my $urltop = $top_uri->as_string;
 486
 487         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(#[^"]+)"/$1 href="$baseurl$2"/mig;
 488         # relative to another wiki page
 489         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)([^\/][^"]*)"/$1 href="$url$2"/mig;
 490         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)([^\/][^"]*)"/$1 src="$url$2"/mig;
 491         # relative to the top of the site
 492         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)(\/[^"]*)"/$1 href="$urltop$2"/mig;
 493         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)(\/[^"]*)"/$1 src="$urltop$2"/mig;
 494         return $content;
 495 }
 496
 497 sub genfeed ($$$$$@) {
 498         my $feedtype=shift;
 499         my $feedurl=shift;
 500         my $feeddesc=shift;
 501         my $guid=shift;
 502         my $page=shift;
 503         my @pages=@_;
 504
 505         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 506
 507         my $itemtemplate=template($feedtype."item.tmpl", blind_cache => 1);
 508         my $content="";
 509         my $lasttime = 0;
 510         foreach my $p (@pages) {
 511                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 512                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 513
 514                 $itemtemplate->param(
 515                         title => pagetitle(basename($p)),
 516                         url => $u,
 517                         permalink => $u,
 518                         cdate_822 => date_822($pagectime{$p}),
 519                         mdate_822 => date_822($pagemtime{$p}),
 520                         cdate_3339 => date_3339($pagectime{$p}),
 521                         mdate_3339 => date_3339($pagemtime{$p}),
 522                 );
 523
 524                 if (exists $pagestate{$p}) {
 525                         if (exists $pagestate{$p}{meta}{guid}) {
 526                                 $itemtemplate->param(guid => $pagestate{$p}{meta}{guid});
 527                         }
 528
 529                         if (exists $pagestate{$p}{meta}{updated}) {
 530                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 531                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 532                         }
 533                 }
 534
 535                 if ($itemtemplate->query(name => "enclosure")) {
 536                         my $file=$pagesources{$p};
 537                         my $type=pagetype($file);
 538                         if (defined $type) {
 539                                 $itemtemplate->param(content => $pcontent);
 540                         }
 541                         else {
 542                                 my $size=(srcfile_stat($file))[8];
 543                                 my $mime="unknown";
 544                                 eval q{use File::MimeInfo};
 545                                 if (! $@) {
 546                                         $mime = mimetype($file);
 547                                 }
 548                                 $itemtemplate->param(
 549                                         enclosure => $u,
 550                                         type => $mime,
 551                                         length => $size,
 552                                 );
 553                         }
 554                 }
 555                 else {
 556                         $itemtemplate->param(content => $pcontent);
 557                 }
 558
 559                 run_hooks(pagetemplate => sub {
 560                         shift->(page => $p, destpage => $page,
 561                                 template => $itemtemplate);
 562                 });
 563
 564                 $content.=$itemtemplate->output;
 565                 $itemtemplate->clear_params;
 566
 567                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 568         }
 569
 570         my $template=template($feedtype."page.tmpl", blind_cache => 1);
 571         $template->param(
 572                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 573                 wikiname => $config{wikiname},
 574                 pageurl => $url,
 575                 content => $content,
 576                 feeddesc => $feeddesc,
 577                 guid => $guid,
 578                 feeddate => date_3339($lasttime),
 579                 feedurl => $feedurl,
 580                 version => $IkiWiki::version,
 581         );
 582         run_hooks(pagetemplate => sub {
 583                 shift->(page => $page, destpage => $page,
 584                         template => $template);
 585         });
 586
 587         return $template->output;
 588 }
 589
 590 sub pingurl (@) {
 591         return unless @{$config{pingurl}} && %toping;
 592
 593         eval q{require RPC::XML::Client};
 594         if ($@) {
 595                 debug(gettext("RPC::XML::Client not found, not pinging"));
 596                 return;
 597         }
 598
 599         # daemonize here so slow pings don't slow down wiki updates
 600         defined(my $pid = fork) or error("Can't fork: $!");
 601         return if $pid;
 602         chdir '/';
 603         POSIX::setsid() or error("Can't start a new session: $!");
 604         open STDIN, '/dev/null';
 605         open STDOUT, '>/dev/null';
 606         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 607
 608         # Don't need to keep a lock on the wiki as a daemon.
 609         IkiWiki::unlockwiki();
 610
 611         foreach my $page (keys %toping) {
 612                 my $title=pagetitle(basename($page), 0);
 613                 my $url=urlto($page, "", 1);
 614                 foreach my $pingurl (@{$config{pingurl}}) {
 615                         debug("Pinging $pingurl for $page");
 616                         eval {
 617                                 my $client = RPC::XML::Client->new($pingurl);
 618                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 619                                         $title, $url);
 620                                 my $res = $client->send_request($req);
 621                                 if (! ref $res) {
 622                                         error("Did not receive response to ping");
 623                                 }
 624                                 my $r=$res->value;
 625                                 if (! exists $r->{flerror} || $r->{flerror}) {
 626                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 627                                 }
 628                         };
 629                         if ($@) {
 630                                 error "Ping failed: $@";
 631                         }
 632                 }
 633         }
 634
 635         exit 0; # daemon done
 636 }
 637
 638
 639 sub rootpage (@) {
 640         my %params=@_;
 641
 642         my $rootpage;
 643         if (exists $params{rootpage}) {
 644                 $rootpage=bestlink($params{page}, $params{rootpage});
 645                 if (!length $rootpage) {
 646                         $rootpage=$params{rootpage};
 647                 }
 648         }
 649         else {
 650                 $rootpage=$params{page};
 651         }
 652         return $rootpage;
 653 }
 654
 655 1