IkiWiki/Plugin/cvs.pm

   1 #!/usr/pkg/bin/perl
   2 package IkiWiki::Plugin::cvs;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7
   8 sub import {
   9         hook(type => "checkconfig", id => "cvs", call => \&checkconfig);
  10         hook(type => "getsetup", id => "cvs", call => \&getsetup);
  11         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  12         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  13         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  14         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  15         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  16         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  17         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  18         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  19         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  20         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  21 }
  22
  23 sub checkconfig () {
  24         if (! defined $config{cvspath}) {
  25                 $config{cvspath}="ikiwiki";
  26         }
  27         if (exists $config{cvspath}) {
  28                 # code depends on the path not having extraneous slashes
  29                 $config{cvspath}=~tr#/#/#s;
  30                 $config{cvspath}=~s/\/$//;
  31                 $config{cvspath}=~s/^\///;
  32         }
  33         if (defined $config{cvs_wrapper} && length $config{cvs_wrapper}) {
  34                 push @{$config{wrappers}}, {
  35                         wrapper => $config{cvs_wrapper},
  36                         wrappermode => (defined $config{cvs_wrappermode} ? $config{cvs_wrappermode} : "04755"),
  37                 };
  38         }
  39 }
  40
  41 sub getsetup () {
  42         return
  43                 plugin => {
  44                         safe => 0, # rcs plugin
  45                         rebuild => undef,
  46                 },
  47                 cvsrepo => {
  48                         type => "string",
  49                         example => "/cvs/wikirepo",
  50                         description => "cvs repository location",
  51                         safe => 0, # path
  52                         rebuild => 0,
  53                 },
  54                 cvspath => {
  55                         type => "string",
  56                         example => "ikiwiki",
  57                         description => "path inside repository where the wiki is located",
  58                         safe => 0, # paranoia
  59                         rebuild => 0,
  60                 },
  61                 cvs_wrapper => {
  62                         type => "string",
  63                         example => "/cvs/wikirepo/CVSROOT/post-commit",
  64                         description => "cvs post-commit hook to generate (triggered by CVSROOT/loginfo entry",
  65                         safe => 0, # file
  66                         rebuild => 0,
  67                 },
  68                 cvs_wrappermode => {
  69                         type => "string",
  70                         example => '04755',
  71                         description => "mode for cvs_wrapper (can safely be made suid)",
  72                         safe => 0,
  73                         rebuild => 0,
  74                 },
  75                 historyurl => {
  76                         type => "string",
  77                         example => "http://cvs.example.org/cvsweb.cgi/ikiwiki/[[file]]",
  78                         description => "cvsweb url to show file history ([[file]] substituted)",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 diffurl => {
  83                         type => "string",
  84                         example => "http://cvs.example.org/cvsweb.cgi/ikiwiki/[[file]].diff?r1=text&amp;tr1=[[r1]]&amp;r2=text&amp;tr2=[[r2]]",
  85                         description => "cvsweb url to show a diff ([[file]], [[r1]], and [[r2]] substituted)",
  86                         safe => 1,
  87                         rebuild => 1,
  88                 },
  89 }
  90
  91 sub cvs_info ($$) {
  92         my $field=shift;
  93         my $file=shift;
  94
  95         chdir $config{srcdir} || error("Cannot chdir to $config{srcdir}: $!");
  96
  97         my $info=`cvs status $file`;
  98         my ($ret)=$info=~/^\s*$field:\s*(\S+)/m;
  99         return $ret;
 100 }
 101
 102 sub cvs_runcvs(@) {
 103         my ($cmd) = @_;
 104         unshift @$cmd, 'cvs', '-Q';
 105
 106         eval q{use IPC::Cmd};
 107         error($@) if $@;
 108
 109         chdir $config{srcdir} || error("Cannot chdir to $config{srcdir}: $!");
 110
 111         debug("runcvs: " . join(" ", @$cmd));
 112
 113         my ($success, $error_code, $full_buf, $stdout_buf, $stderr_buf) =
 114                 IPC::Cmd::run(command => $cmd, verbose => 0);
 115         if (! $success) {
 116                 warn(join(" ", @$cmd) . " exited with code $error_code\n");
 117                 warn(join "", @$stderr_buf);
 118         }
 119         return $success;
 120 }
 121
 122 sub cvs_shquote_commit ($) {
 123         my $message = shift;
 124
 125         eval q{use String::ShellQuote};
 126         error($@) if $@;
 127
 128         return shell_quote(IkiWiki::possibly_foolish_untaint($message));
 129 }
 130
 131 sub cvs_is_controlling {
 132         my $dir=shift;
 133         $dir=$config{srcdir} unless defined($dir);
 134         return (-d "$dir/CVS") ? 1 : 0;
 135 }
 136
 137 sub rcs_update () {
 138         return unless cvs_is_controlling;
 139         cvs_runcvs(['update', '-dP']);
 140 }
 141
 142 sub rcs_prepedit ($) {
 143         # Prepares to edit a file under revision control. Returns a token
 144         # that must be passed into rcs_commit when the file is ready
 145         # for committing.
 146         # The file is relative to the srcdir.
 147         my $file=shift;
 148
 149         return unless cvs_is_controlling;
 150
 151         # For cvs, return the revision of the file when
 152         # editing begins.
 153         my $rev=cvs_info("Repository revision", "$file");
 154         return defined $rev ? $rev : "";
 155 }
 156
 157 sub rcs_commit ($$$;$$) {
 158         # Tries to commit the page; returns undef on _success_ and
 159         # a version of the page with the rcs's conflict markers on failure.
 160         # The file is relative to the srcdir.
 161         my $file=shift;
 162         my $message=shift;
 163         my $rcstoken=shift;
 164         my $user=shift;
 165         my $ipaddr=shift;
 166
 167         return unless cvs_is_controlling;
 168
 169         if (defined $user) {
 170                 $message="web commit by $user".(length $message ? ": $message" : "");
 171         }
 172         elsif (defined $ipaddr) {
 173                 $message="web commit from $ipaddr".(length $message ? ": $message" : "");
 174         }
 175
 176         # Check to see if the page has been changed by someone
 177         # else since rcs_prepedit was called.
 178         my ($oldrev)=$rcstoken=~/^([0-9]+)$/; # untaint
 179         my $rev=cvs_info("Repository revision", "$config{srcdir}/$file");
 180         if (defined $rev && defined $oldrev && $rev != $oldrev) {
 181                 # Merge their changes into the file that we've
 182                 # changed.
 183                 cvs_runcvs(['update', $file]) ||
 184                         warn("cvs merge from $oldrev to $rev failed\n");
 185         }
 186
 187         if (! cvs_runcvs(['commit', '-m', cvs_shquote_commit $message])) {
 188                 my $conflict=readfile("$config{srcdir}/$file");
 189                 cvs_runcvs(['update', '-C', $file]) ||
 190                         warn("cvs revert failed\n");
 191                 return $conflict;
 192         }
 193
 194         return undef # success
 195 }
 196
 197 sub rcs_commit_staged ($$$) {
 198         # Commits all staged changes. Changes can be staged using rcs_add,
 199         # rcs_remove, and rcs_rename.
 200         my ($message, $user, $ipaddr)=@_;
 201
 202         if (defined $user) {
 203                 $message="web commit by $user".(length $message ? ": $message" : "");
 204         }
 205         elsif (defined $ipaddr) {
 206                 $message="web commit from $ipaddr".(length $message ? ": $message" : "");
 207         }
 208
 209         if (! cvs_runcvs(['commit', '-m', cvs_shquote_commit $message])) {
 210                 warn "cvs staged commit failed\n";
 211                 return 1; # failure
 212         }
 213         return undef # success
 214 }
 215
 216 sub rcs_add ($) {
 217         # filename is relative to the root of the srcdir
 218         my $file=shift;
 219         my $parent=IkiWiki::dirname($file);
 220         my @files_to_add = ($file);
 221
 222         until ((length($parent) == 0) || cvs_is_controlling("$config{srcdir}/$parent")){
 223                 push @files_to_add, $parent;
 224                 $parent = IkiWiki::dirname($parent);
 225         }
 226
 227         while ($file = pop @files_to_add) {
 228                 cvs_runcvs(['add', $file]) ||
 229                         warn("cvs add $file failed\n");
 230         }
 231 }
 232
 233 sub rcs_remove ($) {
 234         # filename is relative to the root of the srcdir
 235         my $file=shift;
 236
 237         return unless cvs_is_controlling;
 238
 239         cvs_runcvs(['rm', '-f', $file]) ||
 240                 warn("cvs rm $file failed\n");
 241 }
 242
 243 sub rcs_rename ($$) {
 244         # filenames relative to the root of the srcdir
 245         my ($src, $dest)=@_;
 246
 247         return unless cvs_is_controlling;
 248
 249         chdir $config{srcdir} || error("Cannot chdir to $config{srcdir}: $!");
 250
 251         if (system("mv", "$src", "$dest") != 0) {
 252                 warn("filesystem rename failed\n");
 253         }
 254
 255         rcs_add($dest);
 256         rcs_remove($src);
 257 }
 258
 259 sub rcs_recentchanges($) {
 260         my $num = shift;
 261         my @ret;
 262
 263         return unless cvs_is_controlling;
 264
 265         eval q{use Date::Parse};
 266         error($@) if $@;
 267
 268         chdir $config{srcdir} || error("Cannot chdir to $config{srcdir}: $!");
 269
 270         # there's no option to get the last N changesets, so read backwards
 271         open CVSPS, "env TZ=UTC cvsps -q --cvs-direct -z 30 -x |" || error "couldn't get cvsps output: $!\n";
 272         my @spsvc = reverse <CVSPS>;            # is this great? no it is not
 273         close CVSPS || error "couldn't close cvsps output: $!\n";
 274
 275         while (my $line = shift @spsvc) {
 276                 $line =~ /^$/ || error "expected blank line, got $line";
 277
 278                 my ($rev, $user, $committype, $when);
 279                 my (@message, @pages);
 280
 281                 # We're reading backwards.
 282                 # Forwards, an entry looks like so:
 283                 # ---------------------
 284                 # PatchSet $rev
 285                 # Date: $when
 286                 # Author: $user (or user CGI runs as, for web commits)
 287                 # Branch: branch
 288                 # Tag: tag
 289                 # Log:
 290                 # @message_lines
 291                 # Members:
 292                 #       @pages (and revisions)
 293                 #
 294
 295                 while ($line = shift @spsvc) {
 296                         last if ($line =~ /^Members:/);
 297                         for ($line) {
 298                                 s/^\s+//;
 299                                 s/\s+$//;
 300                         }
 301                         my ($page, $revs) = split(/:/, $line);
 302                         my ($oldrev, $newrev) = split(/->/, $revs);
 303                         $oldrev =~ s/INITIAL/0/;
 304                         $newrev =~ s/\(DEAD\)//;
 305                         my $diffurl = defined $config{diffurl} ? $config{diffurl} : "";
 306                         $diffurl=~s/\[\[file\]\]/$page/g;
 307                         $diffurl=~s/\[\[r1\]\]/$oldrev/g;
 308                         $diffurl=~s/\[\[r2\]\]/$newrev/g;
 309                         unshift @pages, {
 310                                 page => pagename($page),
 311                                 diffurl => $diffurl,
 312                         } if length $page;
 313                 }
 314
 315                 while ($line = shift @spsvc) {
 316                         last if ($line =~ /^Log:$/);
 317                         chomp $line;
 318                         unshift @message, { line => $line };
 319                 }
 320                 $committype = "web";
 321                 if (defined $message[0] &&
 322                     $message[0]->{line}=~/$config{web_commit_regexp}/) {
 323                         $user=defined $2 ? "$2" : "$3";
 324                         $message[0]->{line}=$4;
 325                 } else {
 326                         $committype="cvs";
 327                 }
 328
 329                 $line = shift @spsvc;   # Tag
 330                 $line = shift @spsvc;   # Branch
 331
 332                 $line = shift @spsvc;
 333                 if ($line =~ /^Author: (.*)$/) {
 334                         $user = $1 unless defined $user && length $user;
 335                 } else {
 336                         error "expected Author, got $line";
 337                 }
 338
 339                 $line = shift @spsvc;
 340                 if ($line =~ /^Date: (.*)$/) {
 341                         $when = str2time($1, 'UTC');
 342                 } else {
 343                         error "expected Date, got $line";
 344                 }
 345
 346                 $line = shift @spsvc;
 347                 if ($line =~ /^PatchSet (.*)$/) {
 348                         $rev = $1;
 349                 } else {
 350                         error "expected PatchSet, got $line";
 351                 }
 352
 353                 $line = shift @spsvc;   # ---------------------
 354
 355                 push @ret, {
 356                         rev => $rev,
 357                         user => $user,
 358                         committype => $committype,
 359                         when => $when,
 360                         message => [@message],
 361                         pages => [@pages],
 362                 } if @pages;
 363                 return @ret if @ret >= $num;
 364         }
 365
 366         return @ret;
 367 }
 368
 369 sub rcs_diff ($) {
 370         my $rev=IkiWiki::possibly_foolish_untaint(int(shift));
 371
 372         chdir $config{srcdir} || error("Cannot chdir to $config{srcdir}: $!");
 373
 374         # diff output is unavoidably preceded by the cvsps PatchSet entry
 375         my @cvsps = `env TZ=UTC cvsps -q --cvs-direct -z 30 -g -s $rev`;
 376         my $blank_lines_seen = 0;
 377
 378         while (my $line = shift @cvsps) {
 379                 $blank_lines_seen++ if ($line =~ /^$/);
 380                 last if $blank_lines_seen == 2;
 381         }
 382
 383         if (wantarray) {
 384                 return @cvsps;
 385         } else {
 386                 return join("", @cvsps);
 387         }
 388 }
 389
 390 sub rcs_getctime ($) {
 391         my $file=shift;
 392
 393         my $cvs_log_infoline=qr/^date: (.+);\s+author/;
 394
 395         open CVSLOG, "cvs -Q log -r1.1 '$file' |"
 396                 || error "couldn't get cvs log output: $!\n";
 397
 398         my $date;
 399         while (<CVSLOG>) {
 400                 if (/$cvs_log_infoline/) {
 401                         $date=$1;
 402                 }
 403         }
 404         close CVSLOG || warn "cvs log $file exited $?";
 405
 406         if (! defined $date) {
 407                 warn "failed to parse cvs log for $file\n";
 408                 return 0;
 409         }
 410
 411         eval q{use Date::Parse};
 412         error($@) if $@;
 413         $date=str2time($date, 'UTC');
 414         debug("found ctime ".localtime($date)." for $file");
 415         return $date;
 416 }
 417
 418 1