IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use URI::Escape q{uri_escape_utf8};
   9 use POSIX ();
  10 use Storable;
  11 use open qw{:utf8 :std};
  12
  13 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  14         %pagestate %wikistate %renderedfiles %oldrenderedfiles
  15         %pagesources %delpagesources %destsources %depends %depends_simple
  16         @mass_depends %hooks %forcerebuild %loaded_plugins %typedlinks
  17         %oldtypedlinks %autofiles};
  18
  19 use Exporter q{import};
  20 our @EXPORT = qw(hook debug error htmlpage template template_depends
  21         deptype add_depends pagespec_match pagespec_match_list bestlink
  22         htmllink readfile writefile pagetype srcfile pagename
  23         displaytime will_render gettext ngettext urlto targetpage
  24         add_underlay pagetitle titlepage linkpage newpagefile
  25         inject add_link add_autofile
  26         %config %links %pagestate %wikistate %renderedfiles
  27         %pagesources %destsources %typedlinks);
  28 our $VERSION = 3.00; # plugin interface version, next is ikiwiki version
  29 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  30 our $installdir='/usr'; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  31
  32 # Page dependency types.
  33 our $DEPEND_CONTENT=1;
  34 our $DEPEND_PRESENCE=2;
  35 our $DEPEND_LINKS=4;
  36
  37 # Optimisation.
  38 use Memoize;
  39 memoize("abs2rel");
  40 memoize("sortspec_translate");
  41 memoize("pagespec_translate");
  42 memoize("template_file");
  43
  44 sub getsetup () {
  45         wikiname => {
  46                 type => "string",
  47                 default => "wiki",
  48                 description => "name of the wiki",
  49                 safe => 1,
  50                 rebuild => 1,
  51         },
  52         adminemail => {
  53                 type => "string",
  54                 default => undef,
  55                 example => 'me@example.com',
  56                 description => "contact email for wiki",
  57                 safe => 1,
  58                 rebuild => 0,
  59         },
  60         adminuser => {
  61                 type => "string",
  62                 default => [],
  63                 description => "users who are wiki admins",
  64                 safe => 1,
  65                 rebuild => 0,
  66         },
  67         banned_users => {
  68                 type => "string",
  69                 default => [],
  70                 description => "users who are banned from the wiki",
  71                 safe => 1,
  72                 rebuild => 0,
  73         },
  74         srcdir => {
  75                 type => "string",
  76                 default => undef,
  77                 example => "$ENV{HOME}/wiki",
  78                 description => "where the source of the wiki is located",
  79                 safe => 0, # path
  80                 rebuild => 1,
  81         },
  82         destdir => {
  83                 type => "string",
  84                 default => undef,
  85                 example => "/var/www/wiki",
  86                 description => "where to build the wiki",
  87                 safe => 0, # path
  88                 rebuild => 1,
  89         },
  90         url => {
  91                 type => "string",
  92                 default => '',
  93                 example => "http://example.com/wiki",
  94                 description => "base url to the wiki",
  95                 safe => 1,
  96                 rebuild => 1,
  97         },
  98         cgiurl => {
  99                 type => "string",
 100                 default => '',
 101                 example => "http://example.com/wiki/ikiwiki.cgi",
 102                 description => "url to the ikiwiki.cgi",
 103                 safe => 1,
 104                 rebuild => 1,
 105         },
 106         cgi_wrapper => {
 107                 type => "string",
 108                 default => '',
 109                 example => "/var/www/wiki/ikiwiki.cgi",
 110                 description => "filename of cgi wrapper to generate",
 111                 safe => 0, # file
 112                 rebuild => 0,
 113         },
 114         cgi_wrappermode => {
 115                 type => "string",
 116                 default => '06755',
 117                 description => "mode for cgi_wrapper (can safely be made suid)",
 118                 safe => 0,
 119                 rebuild => 0,
 120         },
 121         rcs => {
 122                 type => "string",
 123                 default => '',
 124                 description => "rcs backend to use",
 125                 safe => 0, # don't allow overriding
 126                 rebuild => 0,
 127         },
 128         default_plugins => {
 129                 type => "internal",
 130                 default => [qw{mdwn link inline meta htmlscrubber passwordauth
 131                                 openid signinedit lockedit conditional
 132                                 recentchanges parentlinks editpage}],
 133                 description => "plugins to enable by default",
 134                 safe => 0,
 135                 rebuild => 1,
 136         },
 137         add_plugins => {
 138                 type => "string",
 139                 default => [],
 140                 description => "plugins to add to the default configuration",
 141                 safe => 1,
 142                 rebuild => 1,
 143         },
 144         disable_plugins => {
 145                 type => "string",
 146                 default => [],
 147                 description => "plugins to disable",
 148                 safe => 1,
 149                 rebuild => 1,
 150         },
 151         templatedir => {
 152                 type => "string",
 153                 default => "$installdir/share/ikiwiki/templates",
 154                 description => "additional directory to search for template files",
 155                 advanced => 1,
 156                 safe => 0, # path
 157                 rebuild => 1,
 158         },
 159         underlaydir => {
 160                 type => "string",
 161                 default => "$installdir/share/ikiwiki/basewiki",
 162                 description => "base wiki source location",
 163                 advanced => 1,
 164                 safe => 0, # path
 165                 rebuild => 0,
 166         },
 167         underlaydirbase => {
 168                 type => "internal",
 169                 default => "$installdir/share/ikiwiki",
 170                 description => "parent directory containing additional underlays",
 171                 safe => 0,
 172                 rebuild => 0,
 173         },
 174         wrappers => {
 175                 type => "internal",
 176                 default => [],
 177                 description => "wrappers to generate",
 178                 safe => 0,
 179                 rebuild => 0,
 180         },
 181         underlaydirs => {
 182                 type => "internal",
 183                 default => [],
 184                 description => "additional underlays to use",
 185                 safe => 0,
 186                 rebuild => 0,
 187         },
 188         verbose => {
 189                 type => "boolean",
 190                 example => 1,
 191                 description => "display verbose messages?",
 192                 safe => 1,
 193                 rebuild => 0,
 194         },
 195         syslog => {
 196                 type => "boolean",
 197                 example => 1,
 198                 description => "log to syslog?",
 199                 safe => 1,
 200                 rebuild => 0,
 201         },
 202         usedirs => {
 203                 type => "boolean",
 204                 default => 1,
 205                 description => "create output files named page/index.html?",
 206                 safe => 0, # changing requires manual transition
 207                 rebuild => 1,
 208         },
 209         prefix_directives => {
 210                 type => "boolean",
 211                 default => 1,
 212                 description => "use '!'-prefixed preprocessor directives?",
 213                 safe => 0, # changing requires manual transition
 214                 rebuild => 1,
 215         },
 216         indexpages => {
 217                 type => "boolean",
 218                 default => 0,
 219                 description => "use page/index.mdwn source files",
 220                 safe => 1,
 221                 rebuild => 1,
 222         },
 223         discussion => {
 224                 type => "boolean",
 225                 default => 1,
 226                 description => "enable Discussion pages?",
 227                 safe => 1,
 228                 rebuild => 1,
 229         },
 230         discussionpage => {
 231                 type => "string",
 232                 default => gettext("Discussion"),
 233                 description => "name of Discussion pages",
 234                 safe => 1,
 235                 rebuild => 1,
 236         },
 237         html5 => {
 238                 type => "boolean",
 239                 default => 0,
 240                 description => "generate HTML5? (experimental)",
 241                 advanced => 1,
 242                 safe => 1,
 243                 rebuild => 1,
 244         },
 245         sslcookie => {
 246                 type => "boolean",
 247                 default => 0,
 248                 description => "only send cookies over SSL connections?",
 249                 advanced => 1,
 250                 safe => 1,
 251                 rebuild => 0,
 252         },
 253         default_pageext => {
 254                 type => "string",
 255                 default => "mdwn",
 256                 description => "extension to use for new pages",
 257                 safe => 0, # not sanitized
 258                 rebuild => 0,
 259         },
 260         htmlext => {
 261                 type => "string",
 262                 default => "html",
 263                 description => "extension to use for html files",
 264                 safe => 0, # not sanitized
 265                 rebuild => 1,
 266         },
 267         timeformat => {
 268                 type => "string",
 269                 default => '%c',
 270                 description => "strftime format string to display date",
 271                 advanced => 1,
 272                 safe => 1,
 273                 rebuild => 1,
 274         },
 275         locale => {
 276                 type => "string",
 277                 default => undef,
 278                 example => "en_US.UTF-8",
 279                 description => "UTF-8 locale to use",
 280                 advanced => 1,
 281                 safe => 0,
 282                 rebuild => 1,
 283         },
 284         userdir => {
 285                 type => "string",
 286                 default => "",
 287                 example => "users",
 288                 description => "put user pages below specified page",
 289                 safe => 1,
 290                 rebuild => 1,
 291         },
 292         numbacklinks => {
 293                 type => "integer",
 294                 default => 10,
 295                 description => "how many backlinks to show before hiding excess (0 to show all)",
 296                 safe => 1,
 297                 rebuild => 1,
 298         },
 299         hardlink => {
 300                 type => "boolean",
 301                 default => 0,
 302                 description => "attempt to hardlink source files? (optimisation for large files)",
 303                 advanced => 1,
 304                 safe => 0, # paranoia
 305                 rebuild => 0,
 306         },
 307         umask => {
 308                 type => "integer",
 309                 example => "022",
 310                 description => "force ikiwiki to use a particular umask",
 311                 advanced => 1,
 312                 safe => 0, # paranoia
 313                 rebuild => 0,
 314         },
 315         wrappergroup => {
 316                 type => "string",
 317                 example => "ikiwiki",
 318                 description => "group for wrappers to run in",
 319                 advanced => 1,
 320                 safe => 0, # paranoia
 321                 rebuild => 0,
 322         },
 323         libdir => {
 324                 type => "string",
 325                 default => "",
 326                 example => "$ENV{HOME}/.ikiwiki/",
 327                 description => "extra library and plugin directory",
 328                 advanced => 1,
 329                 safe => 0, # directory
 330                 rebuild => 0,
 331         },
 332         ENV => {
 333                 type => "string",
 334                 default => {},
 335                 description => "environment variables",
 336                 safe => 0, # paranoia
 337                 rebuild => 0,
 338         },
 339         include => {
 340                 type => "string",
 341                 default => undef,
 342                 example => '^\.htaccess$',
 343                 description => "regexp of normally excluded files to include",
 344                 advanced => 1,
 345                 safe => 0, # regexp
 346                 rebuild => 1,
 347         },
 348         exclude => {
 349                 type => "string",
 350                 default => undef,
 351                 example => '^(*\.private|Makefile)$',
 352                 description => "regexp of files that should be skipped",
 353                 advanced => 1,
 354                 safe => 0, # regexp
 355                 rebuild => 1,
 356         },
 357         wiki_file_prune_regexps => {
 358                 type => "internal",
 359                 default => [qr/(^|\/)\.\.(\/|$)/, qr/^\//, qr/^\./, qr/\/\./,
 360                         qr/\.x?html?$/, qr/\.ikiwiki-new$/,
 361                         qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
 362                         qr/(^|\/)_MTN\//, qr/(^|\/)_darcs\//,
 363                         qr/(^|\/)CVS\//, qr/\.dpkg-tmp$/],
 364                 description => "regexps of source files to ignore",
 365                 safe => 0,
 366                 rebuild => 1,
 367         },
 368         wiki_file_chars => {
 369                 type => "string",
 370                 description => "specifies the characters that are allowed in source filenames",
 371                 default => "-[:alnum:]+/.:_",
 372                 safe => 0,
 373                 rebuild => 1,
 374         },
 375         wiki_file_regexp => {
 376                 type => "internal",
 377                 description => "regexp of legal source files",
 378                 safe => 0,
 379                 rebuild => 1,
 380         },
 381         web_commit_regexp => {
 382                 type => "internal",
 383                 default => qr/^web commit (by (.*?(?=: |$))|from ([0-9a-fA-F:.]+[0-9a-fA-F])):?(.*)/,
 384                 description => "regexp to parse web commits from logs",
 385                 safe => 0,
 386                 rebuild => 0,
 387         },
 388         cgi => {
 389                 type => "internal",
 390                 default => 0,
 391                 description => "run as a cgi",
 392                 safe => 0,
 393                 rebuild => 0,
 394         },
 395         cgi_disable_uploads => {
 396                 type => "internal",
 397                 default => 1,
 398                 description => "whether CGI should accept file uploads",
 399                 safe => 0,
 400                 rebuild => 0,
 401         },
 402         post_commit => {
 403                 type => "internal",
 404                 default => 0,
 405                 description => "run as a post-commit hook",
 406                 safe => 0,
 407                 rebuild => 0,
 408         },
 409         rebuild => {
 410                 type => "internal",
 411                 default => 0,
 412                 description => "running in rebuild mode",
 413                 safe => 0,
 414                 rebuild => 0,
 415         },
 416         setup => {
 417                 type => "internal",
 418                 default => undef,
 419                 description => "running in setup mode",
 420                 safe => 0,
 421                 rebuild => 0,
 422         },
 423         clean => {
 424                 type => "internal",
 425                 default => 0,
 426                 description => "running in clean mode",
 427                 safe => 0,
 428                 rebuild => 0,
 429         },
 430         refresh => {
 431                 type => "internal",
 432                 default => 0,
 433                 description => "running in refresh mode",
 434                 safe => 0,
 435                 rebuild => 0,
 436         },
 437         test_receive => {
 438                 type => "internal",
 439                 default => 0,
 440                 description => "running in receive test mode",
 441                 safe => 0,
 442                 rebuild => 0,
 443         },
 444         wrapper_background_command => {
 445                 type => "internal",
 446                 default => '',
 447                 description => "background shell command to run",
 448                 safe => 0,
 449                 rebuild => 0,
 450         },
 451         gettime => {
 452                 type => "internal",
 453                 description => "running in gettime mode",
 454                 safe => 0,
 455                 rebuild => 0,
 456         },
 457         w3mmode => {
 458                 type => "internal",
 459                 default => 0,
 460                 description => "running in w3mmode",
 461                 safe => 0,
 462                 rebuild => 0,
 463         },
 464         wikistatedir => {
 465                 type => "internal",
 466                 default => undef,
 467                 description => "path to the .ikiwiki directory holding ikiwiki state",
 468                 safe => 0,
 469                 rebuild => 0,
 470         },
 471         setupfile => {
 472                 type => "internal",
 473                 default => undef,
 474                 description => "path to setup file",
 475                 safe => 0,
 476                 rebuild => 0,
 477         },
 478         setuptype => {
 479                 type => "internal",
 480                 default => "Standard",
 481                 description => "perl class to use to dump setup file",
 482                 safe => 0,
 483                 rebuild => 0,
 484         },
 485         allow_symlinks_before_srcdir => {
 486                 type => "boolean",
 487                 default => 0,
 488                 description => "allow symlinks in the path leading to the srcdir (potentially insecure)",
 489                 safe => 0,
 490                 rebuild => 0,
 491         },
 492 }
 493
 494 sub defaultconfig () {
 495         my %s=getsetup();
 496         my @ret;
 497         foreach my $key (keys %s) {
 498                 push @ret, $key, $s{$key}->{default};
 499         }
 500         use Data::Dumper;
 501         return @ret;
 502 }
 503
 504 # URL to top of wiki as a path starting with /, valid from any wiki page or
 505 # the CGI; if that's not possible, an absolute URL. Either way, it ends with /
 506 my $local_url;
 507 # URL to CGI script, similar to $local_url
 508 my $local_cgiurl;
 509
 510 sub checkconfig () {
 511         # locale stuff; avoid LC_ALL since it overrides everything
 512         if (defined $ENV{LC_ALL}) {
 513                 $ENV{LANG} = $ENV{LC_ALL};
 514                 delete $ENV{LC_ALL};
 515         }
 516         if (defined $config{locale}) {
 517                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 518                         $ENV{LANG}=$config{locale};
 519                         define_gettext();
 520                 }
 521         }
 522
 523         if (! defined $config{wiki_file_regexp}) {
 524                 $config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
 525         }
 526
 527         if (ref $config{ENV} eq 'HASH') {
 528                 foreach my $val (keys %{$config{ENV}}) {
 529                         $ENV{$val}=$config{ENV}{$val};
 530                 }
 531         }
 532
 533         if ($config{w3mmode}) {
 534                 eval q{use Cwd q{abs_path}};
 535                 error($@) if $@;
 536                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 537                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 538                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 539                         unless $config{cgiurl} =~ m!file:///!;
 540                 $config{url}="file://".$config{destdir};
 541         }
 542
 543         if ($config{cgi} && ! length $config{url}) {
 544                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 545         }
 546
 547         if (length $config{url}) {
 548                 eval q{use URI};
 549                 my $baseurl = URI->new($config{url});
 550
 551                 $local_url = $baseurl->path . "/";
 552                 $local_cgiurl = undef;
 553
 554                 if (length $config{cgiurl}) {
 555                         my $cgiurl = URI->new($config{cgiurl});
 556
 557                         $local_cgiurl = $cgiurl->path;
 558
 559                         if ($cgiurl->scheme ne $baseurl->scheme or
 560                                 $cgiurl->authority ne $baseurl->authority) {
 561                                 # too far apart, fall back to absolute URLs
 562                                 $local_url = "$config{url}/";
 563                                 $local_cgiurl = $config{cgiurl};
 564                         }
 565                 }
 566
 567                 $local_url =~ s{//$}{/};
 568         }
 569
 570         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 571                 unless exists $config{wikistatedir} && defined $config{wikistatedir};
 572
 573         if (defined $config{umask}) {
 574                 umask(possibly_foolish_untaint($config{umask}));
 575         }
 576
 577         run_hooks(checkconfig => sub { shift->() });
 578
 579         return 1;
 580 }
 581
 582 sub listplugins () {
 583         my %ret;
 584
 585         foreach my $dir (@INC, $config{libdir}) {
 586                 next unless defined $dir && length $dir;
 587                 foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
 588                         my ($plugin)=$file=~/.*\/(.*)\.pm$/;
 589                         $ret{$plugin}=1;
 590                 }
 591         }
 592         foreach my $dir ($config{libdir}, "$installdir/lib/ikiwiki") {
 593                 next unless defined $dir && length $dir;
 594                 foreach my $file (glob("$dir/plugins/*")) {
 595                         $ret{basename($file)}=1 if -x $file;
 596                 }
 597         }
 598
 599         return keys %ret;
 600 }
 601
 602 sub loadplugins () {
 603         if (defined $config{libdir} && length $config{libdir}) {
 604                 unshift @INC, possibly_foolish_untaint($config{libdir});
 605         }
 606
 607         foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
 608                 loadplugin($plugin);
 609         }
 610
 611         if ($config{rcs}) {
 612                 if (exists $hooks{rcs}) {
 613                         error(gettext("cannot use multiple rcs plugins"));
 614                 }
 615                 loadplugin($config{rcs});
 616         }
 617         if (! exists $hooks{rcs}) {
 618                 loadplugin("norcs");
 619         }
 620
 621         run_hooks(getopt => sub { shift->() });
 622         if (grep /^-/, @ARGV) {
 623                 print STDERR "Unknown option (or missing parameter): $_\n"
 624                         foreach grep /^-/, @ARGV;
 625                 usage();
 626         }
 627
 628         return 1;
 629 }
 630
 631 sub loadplugin ($;$) {
 632         my $plugin=shift;
 633         my $force=shift;
 634
 635         return if ! $force && grep { $_ eq $plugin} @{$config{disable_plugins}};
 636
 637         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 638                          "$installdir/lib/ikiwiki") {
 639                 if (defined $dir && -x "$dir/plugins/$plugin") {
 640                         eval { require IkiWiki::Plugin::external };
 641                         if ($@) {
 642                                 my $reason=$@;
 643                                 error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
 644                         }
 645                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 646                         $loaded_plugins{$plugin}=1;
 647                         return 1;
 648                 }
 649         }
 650
 651         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 652         eval qq{use $mod};
 653         if ($@) {
 654                 error("Failed to load plugin $mod: $@");
 655         }
 656         $loaded_plugins{$plugin}=1;
 657         return 1;
 658 }
 659
 660 sub error ($;$) {
 661         my $message=shift;
 662         my $cleaner=shift;
 663         log_message('err' => $message) if $config{syslog};
 664         if (defined $cleaner) {
 665                 $cleaner->();
 666         }
 667         die $message."\n";
 668 }
 669
 670 sub debug ($) {
 671         return unless $config{verbose};
 672         return log_message(debug => @_);
 673 }
 674
 675 my $log_open=0;
 676 sub log_message ($$) {
 677         my $type=shift;
 678
 679         if ($config{syslog}) {
 680                 require Sys::Syslog;
 681                 if (! $log_open) {
 682                         Sys::Syslog::setlogsock('unix');
 683                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 684                         $log_open=1;
 685                 }
 686                 return eval {
 687                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 688                 };
 689         }
 690         elsif (! $config{cgi}) {
 691                 return print "@_\n";
 692         }
 693         else {
 694                 return print STDERR "@_\n";
 695         }
 696 }
 697
 698 sub possibly_foolish_untaint ($) {
 699         my $tainted=shift;
 700         my ($untainted)=$tainted=~/(.*)/s;
 701         return $untainted;
 702 }
 703
 704 sub basename ($) {
 705         my $file=shift;
 706
 707         $file=~s!.*/+!!;
 708         return $file;
 709 }
 710
 711 sub dirname ($) {
 712         my $file=shift;
 713
 714         $file=~s!/*[^/]+$!!;
 715         return $file;
 716 }
 717
 718 sub isinternal ($) {
 719         my $page=shift;
 720         return exists $pagesources{$page} &&
 721                 $pagesources{$page} =~ /\._([^.]+)$/;
 722 }
 723
 724 sub pagetype ($) {
 725         my $file=shift;
 726
 727         if ($file =~ /\.([^.]+)$/) {
 728                 return $1 if exists $hooks{htmlize}{$1};
 729         }
 730         my $base=basename($file);
 731         if (exists $hooks{htmlize}{$base} &&
 732             $hooks{htmlize}{$base}{noextension}) {
 733                 return $base;
 734         }
 735         return;
 736 }
 737
 738 my %pagename_cache;
 739
 740 sub pagename ($) {
 741         my $file=shift;
 742
 743         if (exists $pagename_cache{$file}) {
 744                 return $pagename_cache{$file};
 745         }
 746
 747         my $type=pagetype($file);
 748         my $page=$file;
 749         $page=~s/\Q.$type\E*$//
 750                 if defined $type && !$hooks{htmlize}{$type}{keepextension}
 751                         && !$hooks{htmlize}{$type}{noextension};
 752         if ($config{indexpages} && $page=~/(.*)\/index$/) {
 753                 $page=$1;
 754         }
 755
 756         $pagename_cache{$file} = $page;
 757         return $page;
 758 }
 759
 760 sub newpagefile ($$) {
 761         my $page=shift;
 762         my $type=shift;
 763
 764         if (! $config{indexpages} || $page eq 'index') {
 765                 return $page.".".$type;
 766         }
 767         else {
 768                 return $page."/index.".$type;
 769         }
 770 }
 771
 772 sub targetpage ($$;$) {
 773         my $page=shift;
 774         my $ext=shift;
 775         my $filename=shift;
 776
 777         if (defined $filename) {
 778                 return $page."/".$filename.".".$ext;
 779         }
 780         elsif (! $config{usedirs} || $page eq 'index') {
 781                 return $page.".".$ext;
 782         }
 783         else {
 784                 return $page."/index.".$ext;
 785         }
 786 }
 787
 788 sub htmlpage ($) {
 789         my $page=shift;
 790
 791         return targetpage($page, $config{htmlext});
 792 }
 793
 794 sub srcfile_stat {
 795         my $file=shift;
 796         my $nothrow=shift;
 797
 798         return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
 799         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 800                 return "$dir/$file", stat(_) if -e "$dir/$file";
 801         }
 802         error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
 803         return;
 804 }
 805
 806 sub srcfile ($;$) {
 807         return (srcfile_stat(@_))[0];
 808 }
 809
 810 sub add_underlay ($) {
 811         my $dir=shift;
 812
 813         if ($dir !~ /^\//) {
 814                 $dir="$config{underlaydirbase}/$dir";
 815         }
 816
 817         if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
 818                 unshift @{$config{underlaydirs}}, $dir;
 819         }
 820
 821         return 1;
 822 }
 823
 824 sub readfile ($;$$) {
 825         my $file=shift;
 826         my $binary=shift;
 827         my $wantfd=shift;
 828
 829         if (-l $file) {
 830                 error("cannot read a symlink ($file)");
 831         }
 832
 833         local $/=undef;
 834         open (my $in, "<", $file) || error("failed to read $file: $!");
 835         binmode($in) if ($binary);
 836         return \*$in if $wantfd;
 837         my $ret=<$in>;
 838         # check for invalid utf-8, and toss it back to avoid crashes
 839         if (! utf8::valid($ret)) {
 840                 $ret=encode_utf8($ret);
 841         }
 842         close $in || error("failed to read $file: $!");
 843         return $ret;
 844 }
 845
 846 sub prep_writefile ($$) {
 847         my $file=shift;
 848         my $destdir=shift;
 849
 850         my $test=$file;
 851         while (length $test) {
 852                 if (-l "$destdir/$test") {
 853                         error("cannot write to a symlink ($test)");
 854                 }
 855                 if (-f _ && $test ne $file) {
 856                         # Remove conflicting file.
 857                         foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
 858                                 foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
 859                                         if ($f eq $test) {
 860                                                 unlink("$destdir/$test");
 861                                                 last;
 862                                         }
 863                                 }
 864                         }
 865                 }
 866                 $test=dirname($test);
 867         }
 868
 869         my $dir=dirname("$destdir/$file");
 870         if (! -d $dir) {
 871                 my $d="";
 872                 foreach my $s (split(m!/+!, $dir)) {
 873                         $d.="$s/";
 874                         if (! -d $d) {
 875                                 mkdir($d) || error("failed to create directory $d: $!");
 876                         }
 877                 }
 878         }
 879
 880         return 1;
 881 }
 882
 883 sub writefile ($$$;$$) {
 884         my $file=shift; # can include subdirs
 885         my $destdir=shift; # directory to put file in
 886         my $content=shift;
 887         my $binary=shift;
 888         my $writer=shift;
 889
 890         prep_writefile($file, $destdir);
 891
 892         my $newfile="$destdir/$file.ikiwiki-new";
 893         if (-l $newfile) {
 894                 error("cannot write to a symlink ($newfile)");
 895         }
 896
 897         my $cleanup = sub { unlink($newfile) };
 898         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 899         binmode($out) if ($binary);
 900         if ($writer) {
 901                 $writer->(\*$out, $cleanup);
 902         }
 903         else {
 904                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 905         }
 906         close $out || error("failed saving $newfile: $!", $cleanup);
 907         rename($newfile, "$destdir/$file") ||
 908                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 909
 910         return 1;
 911 }
 912
 913 my %cleared;
 914 sub will_render ($$;$) {
 915         my $page=shift;
 916         my $dest=shift;
 917         my $clear=shift;
 918
 919         # Important security check for independently created files.
 920         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 921             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
 922                 my $from_other_page=0;
 923                 # Expensive, but rarely runs.
 924                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
 925                         if (grep {
 926                                 $_ eq $dest ||
 927                                 dirname($_) eq $dest
 928                             } @{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
 929                                 $from_other_page=1;
 930                                 last;
 931                         }
 932                 }
 933
 934                 error("$config{destdir}/$dest independently created, not overwriting with version from $page")
 935                         unless $from_other_page;
 936         }
 937
 938         # If $dest exists as a directory, remove conflicting files in it
 939         # rendered from other pages.
 940         if (-d _) {
 941                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
 942                         foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
 943                                 if (dirname($f) eq $dest) {
 944                                         unlink("$config{destdir}/$f");
 945                                         rmdir(dirname("$config{destdir}/$f"));
 946                                 }
 947                         }
 948                 }
 949         }
 950
 951         if (! $clear || $cleared{$page}) {
 952                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 953         }
 954         else {
 955                 foreach my $old (@{$renderedfiles{$page}}) {
 956                         delete $destsources{$old};
 957                 }
 958                 $renderedfiles{$page}=[$dest];
 959                 $cleared{$page}=1;
 960         }
 961         $destsources{$dest}=$page;
 962
 963         return 1;
 964 }
 965
 966 sub bestlink ($$) {
 967         my $page=shift;
 968         my $link=shift;
 969
 970         my $cwd=$page;
 971         if ($link=~s/^\/+//) {
 972                 # absolute links
 973                 $cwd="";
 974         }
 975         $link=~s/\/$//;
 976
 977         do {
 978                 my $l=$cwd;
 979                 $l.="/" if length $l;
 980                 $l.=$link;
 981
 982                 if (exists $pagesources{$l}) {
 983                         return $l;
 984                 }
 985                 elsif (exists $pagecase{lc $l}) {
 986                         return $pagecase{lc $l};
 987                 }
 988         } while $cwd=~s{/?[^/]+$}{};
 989
 990         if (length $config{userdir}) {
 991                 my $l = "$config{userdir}/".lc($link);
 992                 if (exists $pagesources{$l}) {
 993                         return $l;
 994                 }
 995                 elsif (exists $pagecase{lc $l}) {
 996                         return $pagecase{lc $l};
 997                 }
 998         }
 999
1000         #print STDERR "warning: page $page, broken link: $link\n";
1001         return "";
1002 }
1003
1004 sub isinlinableimage ($) {
1005         my $file=shift;
1006
1007         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
1008 }
1009
1010 sub pagetitle ($;$) {
1011         my $page=shift;
1012         my $unescaped=shift;
1013
1014         if ($unescaped) {
1015                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
1016         }
1017         else {
1018                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
1019         }
1020
1021         return $page;
1022 }
1023
1024 sub titlepage ($) {
1025         my $title=shift;
1026         # support use w/o %config set
1027         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1028         $title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1029         return $title;
1030 }
1031
1032 sub linkpage ($) {
1033         my $link=shift;
1034         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1035         $link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1036         return $link;
1037 }
1038
1039 sub cgiurl (@) {
1040         my %params=@_;
1041
1042         my $cgiurl=$config{cgiurl};
1043         if (exists $params{cgiurl}) {
1044                 $cgiurl=$params{cgiurl};
1045                 delete $params{cgiurl};
1046         }
1047         return $cgiurl."?".
1048                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
1049 }
1050
1051 sub baseurl (;$) {
1052         my $page=shift;
1053
1054         return "$config{url}/" if ! defined $page;
1055
1056         $page=htmlpage($page);
1057         $page=~s/[^\/]+$//;
1058         $page=~s/[^\/]+\//..\//g;
1059         return $page;
1060 }
1061
1062 sub abs2rel ($$) {
1063         # Work around very innefficient behavior in File::Spec if abs2rel
1064         # is passed two relative paths. It's much faster if paths are
1065         # absolute! (Debian bug #376658; fixed in debian unstable now)
1066         my $path="/".shift;
1067         my $base="/".shift;
1068
1069         require File::Spec;
1070         my $ret=File::Spec->abs2rel($path, $base);
1071         $ret=~s/^// if defined $ret;
1072         return $ret;
1073 }
1074
1075 sub displaytime ($;$$) {
1076         # Plugins can override this function to mark up the time to
1077         # display.
1078         my $time=formattime($_[0], $_[1]);
1079         if ($config{html5}) {
1080                 return '<time datetime="'.date_3339($_[0]).'"'.
1081                         ($_[2] ? ' pubdate="pubdate"' : '').
1082                         '>'.$time.'</time>';
1083         }
1084         else {
1085                 return '<span class="date">'.$time.'</span>';
1086         }
1087 }
1088
1089 sub formattime ($;$) {
1090         # Plugins can override this function to format the time.
1091         my $time=shift;
1092         my $format=shift;
1093         if (! defined $format) {
1094                 $format=$config{timeformat};
1095         }
1096
1097         # strftime doesn't know about encodings, so make sure
1098         # its output is properly treated as utf8
1099         return decode_utf8(POSIX::strftime($format, localtime($time)));
1100 }
1101
1102 sub date_3339 ($) {
1103         my $time=shift;
1104
1105         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
1106         POSIX::setlocale(&POSIX::LC_TIME, "C");
1107         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
1108         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
1109         return $ret;
1110 }
1111
1112 sub beautify_urlpath ($) {
1113         my $url=shift;
1114
1115         # Ensure url is not an empty link, and if necessary,
1116         # add ./ to avoid colon confusion.
1117         if ($url !~ /^\// && $url !~ /^\.\.?\//) {
1118                 $url="./$url";
1119         }
1120
1121         if ($config{usedirs}) {
1122                 $url =~ s!/index.$config{htmlext}$!/!;
1123         }
1124
1125         return $url;
1126 }
1127
1128 sub urlto ($$;$) {
1129         my $to=shift;
1130         my $from=shift;
1131         my $absolute=shift;
1132
1133         if (! length $to) {
1134                 return beautify_urlpath(baseurl($from)."index.$config{htmlext}");
1135         }
1136
1137         if (! $destsources{$to}) {
1138                 $to=htmlpage($to);
1139         }
1140
1141         if ($absolute) {
1142                 return $config{url}.beautify_urlpath("/".$to);
1143         }
1144
1145         my $link = abs2rel($to, dirname(htmlpage($from)));
1146
1147         return beautify_urlpath($link);
1148 }
1149
1150 sub isselflink ($$) {
1151         # Plugins can override this function to support special types
1152         # of selflinks.
1153         my $page=shift;
1154         my $link=shift;
1155
1156         return $page eq $link;
1157 }
1158
1159 sub htmllink ($$$;@) {
1160         my $lpage=shift; # the page doing the linking
1161         my $page=shift; # the page that will contain the link (different for inline)
1162         my $link=shift;
1163         my %opts=@_;
1164
1165         $link=~s/\/$//;
1166
1167         my $bestlink;
1168         if (! $opts{forcesubpage}) {
1169                 $bestlink=bestlink($lpage, $link);
1170         }
1171         else {
1172                 $bestlink="$lpage/".lc($link);
1173         }
1174
1175         my $linktext;
1176         if (defined $opts{linktext}) {
1177                 $linktext=$opts{linktext};
1178         }
1179         else {
1180                 $linktext=pagetitle(basename($link));
1181         }
1182
1183         return "<span class=\"selflink\">$linktext</span>"
1184                 if length $bestlink && isselflink($page, $bestlink) &&
1185                    ! defined $opts{anchor};
1186
1187         if (! $destsources{$bestlink}) {
1188                 $bestlink=htmlpage($bestlink);
1189
1190                 if (! $destsources{$bestlink}) {
1191                         my $cgilink = "";
1192                         if (length $config{cgiurl}) {
1193                                 $cgilink = "<a href=\"".
1194                                         cgiurl(
1195                                                 do => "create",
1196                                                 page => lc($link),
1197                                                 from => $lpage
1198                                         )."\" rel=\"nofollow\">?</a>";
1199                         }
1200                         return "<span class=\"createlink\">$cgilink$linktext</span>"
1201                 }
1202         }
1203
1204         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
1205         $bestlink=beautify_urlpath($bestlink);
1206
1207         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
1208                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
1209         }
1210
1211         if (defined $opts{anchor}) {
1212                 $bestlink.="#".$opts{anchor};
1213         }
1214
1215         my @attrs;
1216         foreach my $attr (qw{rel class title}) {
1217                 if (defined $opts{$attr}) {
1218                         push @attrs, " $attr=\"$opts{$attr}\"";
1219                 }
1220         }
1221
1222         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
1223 }
1224
1225 sub userpage ($) {
1226         my $user=shift;
1227         return length $config{userdir} ? "$config{userdir}/$user" : $user;
1228 }
1229
1230 sub openiduser ($) {
1231         my $user=shift;
1232
1233         if ($user =~ m!^https?://! &&
1234             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
1235                 my $display;
1236
1237                 if (Net::OpenID::VerifiedIdentity->can("DisplayOfURL")) {
1238                         $display = Net::OpenID::VerifiedIdentity::DisplayOfURL($user);
1239                 }
1240                 else {
1241                         # backcompat with old version
1242                         my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
1243                         $display=$oid->display;
1244                 }
1245
1246                 # Convert "user.somehost.com" to "user [somehost.com]"
1247                 # (also "user.somehost.co.uk")
1248                 if ($display !~ /\[/) {
1249                         $display=~s/^([-a-zA-Z0-9]+?)\.([-.a-zA-Z0-9]+\.[a-z]+)$/$1 [$2]/;
1250                 }
1251                 # Convert "http://somehost.com/user" to "user [somehost.com]".
1252                 # (also "https://somehost.com/user/")
1253                 if ($display !~ /\[/) {
1254                         $display=~s/^https?:\/\/(.+)\/([^\/#?]+)\/?(?:[#?].*)?$/$2 [$1]/;
1255                 }
1256                 $display=~s!^https?://!!; # make sure this is removed
1257                 eval q{use CGI 'escapeHTML'};
1258                 error($@) if $@;
1259                 return escapeHTML($display);
1260         }
1261         return;
1262 }
1263
1264 sub htmlize ($$$$) {
1265         my $page=shift;
1266         my $destpage=shift;
1267         my $type=shift;
1268         my $content=shift;
1269
1270         my $oneline = $content !~ /\n/;
1271
1272         if (exists $hooks{htmlize}{$type}) {
1273                 $content=$hooks{htmlize}{$type}{call}->(
1274                         page => $page,
1275                         content => $content,
1276                 );
1277         }
1278         else {
1279                 error("htmlization of $type not supported");
1280         }
1281
1282         run_hooks(sanitize => sub {
1283                 $content=shift->(
1284                         page => $page,
1285                         destpage => $destpage,
1286                         content => $content,
1287                 );
1288         });
1289
1290         if ($oneline) {
1291                 # hack to get rid of enclosing junk added by markdown
1292                 # and other htmlizers/sanitizers
1293                 $content=~s/^<p>//i;
1294                 $content=~s/<\/p>\n*$//i;
1295         }
1296
1297         return $content;
1298 }
1299
1300 sub linkify ($$$) {
1301         my $page=shift;
1302         my $destpage=shift;
1303         my $content=shift;
1304
1305         run_hooks(linkify => sub {
1306                 $content=shift->(
1307                         page => $page,
1308                         destpage => $destpage,
1309                         content => $content,
1310                 );
1311         });
1312
1313         return $content;
1314 }
1315
1316 our %preprocessing;
1317 our $preprocess_preview=0;
1318 sub preprocess ($$$;$$) {
1319         my $page=shift; # the page the data comes from
1320         my $destpage=shift; # the page the data will appear in (different for inline)
1321         my $content=shift;
1322         my $scan=shift;
1323         my $preview=shift;
1324
1325         # Using local because it needs to be set within any nested calls
1326         # of this function.
1327         local $preprocess_preview=$preview if defined $preview;
1328
1329         my $handle=sub {
1330                 my $escape=shift;
1331                 my $prefix=shift;
1332                 my $command=shift;
1333                 my $params=shift;
1334                 $params="" if ! defined $params;
1335
1336                 if (length $escape) {
1337                         return "[[$prefix$command $params]]";
1338                 }
1339                 elsif (exists $hooks{preprocess}{$command}) {
1340                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
1341                         # Note: preserve order of params, some plugins may
1342                         # consider it significant.
1343                         my @params;
1344                         while ($params =~ m{
1345                                 (?:([-\w]+)=)?          # 1: named parameter key?
1346                                 (?:
1347                                         """(.*?)"""     # 2: triple-quoted value
1348                                 |
1349                                         "([^"]*?)"      # 3: single-quoted value
1350                                 |
1351                                         (\S+)           # 4: unquoted value
1352                                 )
1353                                 (?:\s+|$)               # delimiter to next param
1354                         }sgx) {
1355                                 my $key=$1;
1356                                 my $val;
1357                                 if (defined $2) {
1358                                         $val=$2;
1359                                         $val=~s/\r\n/\n/mg;
1360                                         $val=~s/^\n+//g;
1361                                         $val=~s/\n+$//g;
1362                                 }
1363                                 elsif (defined $3) {
1364                                         $val=$3;
1365                                 }
1366                                 elsif (defined $4) {
1367                                         $val=$4;
1368                                 }
1369
1370                                 if (defined $key) {
1371                                         push @params, $key, $val;
1372                                 }
1373                                 else {
1374                                         push @params, $val, '';
1375                                 }
1376                         }
1377                         if ($preprocessing{$page}++ > 3) {
1378                                 # Avoid loops of preprocessed pages preprocessing
1379                                 # other pages that preprocess them, etc.
1380                                 return "[[!$command <span class=\"error\">".
1381                                         sprintf(gettext("preprocessing loop detected on %s at depth %i"),
1382                                                 $page, $preprocessing{$page}).
1383                                         "</span>]]";
1384                         }
1385                         my $ret;
1386                         if (! $scan) {
1387                                 $ret=eval {
1388                                         $hooks{preprocess}{$command}{call}->(
1389                                                 @params,
1390                                                 page => $page,
1391                                                 destpage => $destpage,
1392                                                 preview => $preprocess_preview,
1393                                         );
1394                                 };
1395                                 if ($@) {
1396                                         my $error=$@;
1397                                         chomp $error;
1398                                         $ret="[[!$command <span class=\"error\">".
1399                                                 gettext("Error").": $error"."</span>]]";
1400                                 }
1401                         }
1402                         else {
1403                                 # use void context during scan pass
1404                                 eval {
1405                                         $hooks{preprocess}{$command}{call}->(
1406                                                 @params,
1407                                                 page => $page,
1408                                                 destpage => $destpage,
1409                                                 preview => $preprocess_preview,
1410                                         );
1411                                 };
1412                                 $ret="";
1413                         }
1414                         $preprocessing{$page}--;
1415                         return $ret;
1416                 }
1417                 else {
1418                         return "[[$prefix$command $params]]";
1419                 }
1420         };
1421
1422         my $regex;
1423         if ($config{prefix_directives}) {
1424                 $regex = qr{
1425                         (\\?)           # 1: escape?
1426                         \[\[(!)         # directive open; 2: prefix
1427                         ([-\w]+)        # 3: command
1428                         (               # 4: the parameters..
1429                                 \s+     # Must have space if parameters present
1430                                 (?:
1431                                         (?:[-\w]+=)?            # named parameter key?
1432                                         (?:
1433                                                 """.*?"""       # triple-quoted value
1434                                                 |
1435                                                 "[^"]*?"        # single-quoted value
1436                                                 |
1437                                                 [^"\s\]]+       # unquoted value
1438                                         )
1439                                         \s*                     # whitespace or end
1440                                                                 # of directive
1441                                 )
1442                         *)?             # 0 or more parameters
1443                         \]\]            # directive closed
1444                 }sx;
1445         }
1446         else {
1447                 $regex = qr{
1448                         (\\?)           # 1: escape?
1449                         \[\[(!?)        # directive open; 2: optional prefix
1450                         ([-\w]+)        # 3: command
1451                         \s+
1452                         (               # 4: the parameters..
1453                                 (?:
1454                                         (?:[-\w]+=)?            # named parameter key?
1455                                         (?:
1456                                                 """.*?"""       # triple-quoted value
1457                                                 |
1458                                                 "[^"]*?"        # single-quoted value
1459                                                 |
1460                                                 [^"\s\]]+       # unquoted value
1461                                         )
1462                                         \s*                     # whitespace or end
1463                                                                 # of directive
1464                                 )
1465                         *)              # 0 or more parameters
1466                         \]\]            # directive closed
1467                 }sx;
1468         }
1469
1470         $content =~ s{$regex}{$handle->($1, $2, $3, $4)}eg;
1471         return $content;
1472 }
1473
1474 sub filter ($$$) {
1475         my $page=shift;
1476         my $destpage=shift;
1477         my $content=shift;
1478
1479         run_hooks(filter => sub {
1480                 $content=shift->(page => $page, destpage => $destpage,
1481                         content => $content);
1482         });
1483
1484         return $content;
1485 }
1486
1487 sub check_canedit ($$$;$) {
1488         my $page=shift;
1489         my $q=shift;
1490         my $session=shift;
1491         my $nonfatal=shift;
1492
1493         my $canedit;
1494         run_hooks(canedit => sub {
1495                 return if defined $canedit;
1496                 my $ret=shift->($page, $q, $session);
1497                 if (defined $ret) {
1498                         if ($ret eq "") {
1499                                 $canedit=1;
1500                         }
1501                         elsif (ref $ret eq 'CODE') {
1502                                 $ret->() unless $nonfatal;
1503                                 $canedit=0;
1504                         }
1505                         elsif (defined $ret) {
1506                                 error($ret) unless $nonfatal;
1507                                 $canedit=0;
1508                         }
1509                 }
1510         });
1511         return defined $canedit ? $canedit : 1;
1512 }
1513
1514 sub check_content (@) {
1515         my %params=@_;
1516
1517         return 1 if ! exists $hooks{checkcontent}; # optimisation
1518
1519         if (exists $pagesources{$params{page}}) {
1520                 my @diff;
1521                 my %old=map { $_ => 1 }
1522                         split("\n", readfile(srcfile($pagesources{$params{page}})));
1523                 foreach my $line (split("\n", $params{content})) {
1524                         push @diff, $line if ! exists $old{$line};
1525                 }
1526                 $params{diff}=join("\n", @diff);
1527         }
1528
1529         my $ok;
1530         run_hooks(checkcontent => sub {
1531                 return if defined $ok;
1532                 my $ret=shift->(%params);
1533                 if (defined $ret) {
1534                         if ($ret eq "") {
1535                                 $ok=1;
1536                         }
1537                         elsif (ref $ret eq 'CODE') {
1538                                 $ret->() unless $params{nonfatal};
1539                                 $ok=0;
1540                         }
1541                         elsif (defined $ret) {
1542                                 error($ret) unless $params{nonfatal};
1543                                 $ok=0;
1544                         }
1545                 }
1546
1547         });
1548         return defined $ok ? $ok : 1;
1549 }
1550
1551 sub check_canchange (@) {
1552         my %params = @_;
1553         my $cgi = $params{cgi};
1554         my $session = $params{session};
1555         my @changes = @{$params{changes}};
1556
1557         my %newfiles;
1558         foreach my $change (@changes) {
1559                 # This untaint is safe because we check file_pruned and
1560                 # wiki_file_regexp.
1561                 my ($file)=$change->{file}=~/$config{wiki_file_regexp}/;
1562                 $file=possibly_foolish_untaint($file);
1563                 if (! defined $file || ! length $file ||
1564                     file_pruned($file)) {
1565                         error(gettext("bad file name %s"), $file);
1566                 }
1567
1568                 my $type=pagetype($file);
1569                 my $page=pagename($file) if defined $type;
1570
1571                 if ($change->{action} eq 'add') {
1572                         $newfiles{$file}=1;
1573                 }
1574
1575                 if ($change->{action} eq 'change' ||
1576                     $change->{action} eq 'add') {
1577                         if (defined $page) {
1578                                 check_canedit($page, $cgi, $session);
1579                                 next;
1580                         }
1581                         else {
1582                                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
1583                                         IkiWiki::Plugin::attachment::check_canattach($session, $file, $change->{path});
1584                                         check_canedit($file, $cgi, $session);
1585                                         next;
1586                                 }
1587                         }
1588                 }
1589                 elsif ($change->{action} eq 'remove') {
1590                         # check_canremove tests to see if the file is present
1591                         # on disk. This will fail when a single commit adds a
1592                         # file and then removes it again. Avoid the problem
1593                         # by not testing the removal in such pairs of changes.
1594                         # (The add is still tested, just to make sure that
1595                         # no data is added to the repo that a web edit
1596                         # could not add.)
1597                         next if $newfiles{$file};
1598
1599                         if (IkiWiki::Plugin::remove->can("check_canremove")) {
1600                                 IkiWiki::Plugin::remove::check_canremove(defined $page ? $page : $file, $cgi, $session);
1601                                 check_canedit(defined $page ? $page : $file, $cgi, $session);
1602                                 next;
1603                         }
1604                 }
1605                 else {
1606                         error "unknown action ".$change->{action};
1607                 }
1608
1609                 error sprintf(gettext("you are not allowed to change %s"), $file);
1610         }
1611 }
1612
1613
1614 my $wikilock;
1615
1616 sub lockwiki () {
1617         # Take an exclusive lock on the wiki to prevent multiple concurrent
1618         # run issues. The lock will be dropped on program exit.
1619         if (! -d $config{wikistatedir}) {
1620                 mkdir($config{wikistatedir});
1621         }
1622         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
1623                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
1624         if (! flock($wikilock, 2)) { # LOCK_EX
1625                 error("failed to get lock");
1626         }
1627         return 1;
1628 }
1629
1630 sub unlockwiki () {
1631         POSIX::close($ENV{IKIWIKI_CGILOCK_FD}) if exists $ENV{IKIWIKI_CGILOCK_FD};
1632         return close($wikilock) if $wikilock;
1633         return;
1634 }
1635
1636 my $commitlock;
1637
1638 sub commit_hook_enabled () {
1639         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
1640                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1641         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
1642                 close($commitlock) || error("failed closing commitlock: $!");
1643                 return 0;
1644         }
1645         close($commitlock) || error("failed closing commitlock: $!");
1646         return 1;
1647 }
1648
1649 sub disable_commit_hook () {
1650         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
1651                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1652         if (! flock($commitlock, 2)) { # LOCK_EX
1653                 error("failed to get commit lock");
1654         }
1655         return 1;
1656 }
1657
1658 sub enable_commit_hook () {
1659         return close($commitlock) if $commitlock;
1660         return;
1661 }
1662
1663 sub loadindex () {
1664         %oldrenderedfiles=%pagectime=();
1665         if (! $config{rebuild}) {
1666                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
1667                 %destsources=%renderedfiles=%pagecase=%pagestate=
1668                 %depends_simple=%typedlinks=%oldtypedlinks=();
1669         }
1670         my $in;
1671         if (! open ($in, "<", "$config{wikistatedir}/indexdb")) {
1672                 if (-e "$config{wikistatedir}/index") {
1673                         system("ikiwiki-transition", "indexdb", $config{srcdir});
1674                         open ($in, "<", "$config{wikistatedir}/indexdb") || return;
1675                 }
1676                 else {
1677                         $config{gettime}=1; # first build
1678                         return;
1679                 }
1680         }
1681
1682         my $index=Storable::fd_retrieve($in);
1683         if (! defined $index) {
1684                 return 0;
1685         }
1686
1687         my $pages;
1688         if (exists $index->{version} && ! ref $index->{version}) {
1689                 $pages=$index->{page};
1690                 %wikistate=%{$index->{state}};
1691                 # Handle plugins that got disabled by loading a new setup.
1692                 if (exists $config{setupfile}) {
1693                         require IkiWiki::Setup;
1694                         IkiWiki::Setup::disabled_plugins(
1695                                 grep { ! $loaded_plugins{$_} } keys %wikistate);
1696                 }
1697         }
1698         else {
1699                 $pages=$index;
1700                 %wikistate=();
1701         }
1702
1703         foreach my $src (keys %$pages) {
1704                 my $d=$pages->{$src};
1705                 my $page=pagename($src);
1706                 $pagectime{$page}=$d->{ctime};
1707                 $pagesources{$page}=$src;
1708                 if (! $config{rebuild}) {
1709                         $pagemtime{$page}=$d->{mtime};
1710                         $renderedfiles{$page}=$d->{dest};
1711                         if (exists $d->{links} && ref $d->{links}) {
1712                                 $links{$page}=$d->{links};
1713                                 $oldlinks{$page}=[@{$d->{links}}];
1714                         }
1715                         if (ref $d->{depends_simple} eq 'ARRAY') {
1716                                 # old format
1717                                 $depends_simple{$page}={
1718                                         map { $_ => 1 } @{$d->{depends_simple}}
1719                                 };
1720                         }
1721                         elsif (exists $d->{depends_simple}) {
1722                                 $depends_simple{$page}=$d->{depends_simple};
1723                         }
1724                         if (exists $d->{dependslist}) {
1725                                 # old format
1726                                 $depends{$page}={
1727                                         map { $_ => $DEPEND_CONTENT }
1728                                                 @{$d->{dependslist}}
1729                                 };
1730                         }
1731                         elsif (exists $d->{depends} && ! ref $d->{depends}) {
1732                                 # old format
1733                                 $depends{$page}={$d->{depends} => $DEPEND_CONTENT };
1734                         }
1735                         elsif (exists $d->{depends}) {
1736                                 $depends{$page}=$d->{depends};
1737                         }
1738                         if (exists $d->{state}) {
1739                                 $pagestate{$page}=$d->{state};
1740                         }
1741                         if (exists $d->{typedlinks}) {
1742                                 $typedlinks{$page}=$d->{typedlinks};
1743
1744                                 while (my ($type, $links) = each %{$typedlinks{$page}}) {
1745                                         next unless %$links;
1746                                         $oldtypedlinks{$page}{$type} = {%$links};
1747                                 }
1748                         }
1749                 }
1750                 $oldrenderedfiles{$page}=[@{$d->{dest}}];
1751         }
1752         foreach my $page (keys %pagesources) {
1753                 $pagecase{lc $page}=$page;
1754         }
1755         foreach my $page (keys %renderedfiles) {
1756                 $destsources{$_}=$page foreach @{$renderedfiles{$page}};
1757         }
1758         return close($in);
1759 }
1760
1761 sub saveindex () {
1762         run_hooks(savestate => sub { shift->() });
1763
1764         my @plugins=keys %loaded_plugins;
1765
1766         if (! -d $config{wikistatedir}) {
1767                 mkdir($config{wikistatedir});
1768         }
1769         my $newfile="$config{wikistatedir}/indexdb.new";
1770         my $cleanup = sub { unlink($newfile) };
1771         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
1772
1773         my %index;
1774         foreach my $page (keys %pagemtime) {
1775                 next unless $pagemtime{$page};
1776                 my $src=$pagesources{$page};
1777
1778                 $index{page}{$src}={
1779                         ctime => $pagectime{$page},
1780                         mtime => $pagemtime{$page},
1781                         dest => $renderedfiles{$page},
1782                         links => $links{$page},
1783                 };
1784
1785                 if (exists $depends{$page}) {
1786                         $index{page}{$src}{depends} = $depends{$page};
1787                 }
1788
1789                 if (exists $depends_simple{$page}) {
1790                         $index{page}{$src}{depends_simple} = $depends_simple{$page};
1791                 }
1792
1793                 if (exists $typedlinks{$page} && %{$typedlinks{$page}}) {
1794                         $index{page}{$src}{typedlinks} = $typedlinks{$page};
1795                 }
1796
1797                 if (exists $pagestate{$page}) {
1798                         foreach my $id (@plugins) {
1799                                 foreach my $key (keys %{$pagestate{$page}{$id}}) {
1800                                         $index{page}{$src}{state}{$id}{$key}=$pagestate{$page}{$id}{$key};
1801                                 }
1802                         }
1803                 }
1804         }
1805
1806         $index{state}={};
1807         foreach my $id (@plugins) {
1808                 $index{state}{$id}={}; # used to detect disabled plugins
1809                 foreach my $key (keys %{$wikistate{$id}}) {
1810                         $index{state}{$id}{$key}=$wikistate{$id}{$key};
1811                 }
1812         }
1813
1814         $index{version}="3";
1815         my $ret=Storable::nstore_fd(\%index, $out);
1816         return if ! defined $ret || ! $ret;
1817         close $out || error("failed saving to $newfile: $!", $cleanup);
1818         rename($newfile, "$config{wikistatedir}/indexdb") ||
1819                 error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
1820
1821         return 1;
1822 }
1823
1824 sub template_file ($) {
1825         my $name=shift;
1826
1827         my $tpage=($name =~ s/^\///) ? $name : "templates/$name";
1828         my $template;
1829         if ($name !~ /\.tmpl$/ && exists $pagesources{$tpage}) {
1830                 $template=srcfile($pagesources{$tpage}, 1);
1831                 $name.=".tmpl";
1832         }
1833         else {
1834                 $template=srcfile($tpage, 1);
1835         }
1836
1837         if (defined $template) {
1838                 return $template, $tpage, 1 if wantarray;
1839                 return $template;
1840         }
1841         else {
1842                 $name=~s:/::; # avoid path traversal
1843                 foreach my $dir ($config{templatedir},
1844                                  "$installdir/share/ikiwiki/templates") {
1845                         if (-e "$dir/$name") {
1846                                 $template="$dir/$name";
1847                                 last;
1848                         }
1849                 }
1850                 if (defined $template) {
1851                         return $template, $tpage if wantarray;
1852                         return $template;
1853                 }
1854         }
1855
1856         return;
1857 }
1858
1859 sub template_depends ($$;@) {
1860         my $name=shift;
1861         my $page=shift;
1862
1863         my ($filename, $tpage, $untrusted)=template_file($name);
1864         if (! defined $filename) {
1865                 error(sprintf(gettext("template %s not found"), $name))
1866         }
1867
1868         if (defined $page && defined $tpage) {
1869                 add_depends($page, $tpage);
1870         }
1871
1872         my @opts=(
1873                 filter => sub {
1874                         my $text_ref = shift;
1875                         ${$text_ref} = decode_utf8(${$text_ref});
1876                 },
1877                 loop_context_vars => 1,
1878                 die_on_bad_params => 0,
1879                 filename => $filename,
1880                 @_,
1881                 ($untrusted ? (no_includes => 1) : ()),
1882         );
1883         return @opts if wantarray;
1884
1885         require HTML::Template;
1886         return HTML::Template->new(@opts);
1887 }
1888
1889 sub template ($;@) {
1890         template_depends(shift, undef, @_);
1891 }
1892
1893 sub misctemplate ($$;@) {
1894         my $title=shift;
1895         my $content=shift;
1896         my %params=@_;
1897
1898         my $template=template("page.tmpl");
1899
1900         my $page="";
1901         if (exists $params{page}) {
1902                 $page=delete $params{page};
1903         }
1904         run_hooks(pagetemplate => sub {
1905                 shift->(
1906                         page => $page,
1907                         destpage => $page,
1908                         template => $template,
1909                 );
1910         });
1911         templateactions($template, "");
1912
1913         $template->param(
1914                 dynamic => 1,
1915                 title => $title,
1916                 wikiname => $config{wikiname},
1917                 content => $content,
1918                 baseurl => baseurl(),
1919                 html5 => $config{html5},
1920                 %params,
1921         );
1922
1923         return $template->output;
1924 }
1925
1926 sub templateactions ($$) {
1927         my $template=shift;
1928         my $page=shift;
1929
1930         my $have_actions=0;
1931         my @actions;
1932         run_hooks(pageactions => sub {
1933                 push @actions, map { { action => $_ } }
1934                         grep { defined } shift->(page => $page);
1935         });
1936         $template->param(actions => \@actions);
1937
1938         if ($config{cgiurl} && exists $hooks{auth}) {
1939                 $template->param(prefsurl => cgiurl(do => "prefs"));
1940                 $have_actions=1;
1941         }
1942
1943         if ($have_actions || @actions) {
1944                 $template->param(have_actions => 1);
1945         }
1946 }
1947
1948 sub hook (@) {
1949         my %param=@_;
1950
1951         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
1952                 error 'hook requires type, call, and id parameters';
1953         }
1954
1955         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
1956
1957         $hooks{$param{type}}{$param{id}}=\%param;
1958         return 1;
1959 }
1960
1961 sub run_hooks ($$) {
1962         # Calls the given sub for each hook of the given type,
1963         # passing it the hook function to call.
1964         my $type=shift;
1965         my $sub=shift;
1966
1967         if (exists $hooks{$type}) {
1968                 my (@first, @middle, @last);
1969                 foreach my $id (keys %{$hooks{$type}}) {
1970                         if ($hooks{$type}{$id}{first}) {
1971                                 push @first, $id;
1972                         }
1973                         elsif ($hooks{$type}{$id}{last}) {
1974                                 push @last, $id;
1975                         }
1976                         else {
1977                                 push @middle, $id;
1978                         }
1979                 }
1980                 foreach my $id (@first, @middle, @last) {
1981                         $sub->($hooks{$type}{$id}{call});
1982                 }
1983         }
1984
1985         return 1;
1986 }
1987
1988 sub rcs_update () {
1989         $hooks{rcs}{rcs_update}{call}->(@_);
1990 }
1991
1992 sub rcs_prepedit ($) {
1993         $hooks{rcs}{rcs_prepedit}{call}->(@_);
1994 }
1995
1996 sub rcs_commit (@) {
1997         $hooks{rcs}{rcs_commit}{call}->(@_);
1998 }
1999
2000 sub rcs_commit_staged (@) {
2001         $hooks{rcs}{rcs_commit_staged}{call}->(@_);
2002 }
2003
2004 sub rcs_add ($) {
2005         $hooks{rcs}{rcs_add}{call}->(@_);
2006 }
2007
2008 sub rcs_remove ($) {
2009         $hooks{rcs}{rcs_remove}{call}->(@_);
2010 }
2011
2012 sub rcs_rename ($$) {
2013         $hooks{rcs}{rcs_rename}{call}->(@_);
2014 }
2015
2016 sub rcs_recentchanges ($) {
2017         $hooks{rcs}{rcs_recentchanges}{call}->(@_);
2018 }
2019
2020 sub rcs_diff ($) {
2021         $hooks{rcs}{rcs_diff}{call}->(@_);
2022 }
2023
2024 sub rcs_getctime ($) {
2025         $hooks{rcs}{rcs_getctime}{call}->(@_);
2026 }
2027
2028 sub rcs_getmtime ($) {
2029         $hooks{rcs}{rcs_getmtime}{call}->(@_);
2030 }
2031
2032 sub rcs_receive () {
2033         $hooks{rcs}{rcs_receive}{call}->();
2034 }
2035
2036 sub add_depends ($$;$) {
2037         my $page=shift;
2038         my $pagespec=shift;
2039         my $deptype=shift || $DEPEND_CONTENT;
2040
2041         # Is the pagespec a simple page name?
2042         if ($pagespec =~ /$config{wiki_file_regexp}/ &&
2043             $pagespec !~ /[\s*?()!]/) {
2044                 $depends_simple{$page}{lc $pagespec} |= $deptype;
2045                 return 1;
2046         }
2047
2048         # Add explicit dependencies for influences.
2049         my $sub=pagespec_translate($pagespec);
2050         return unless defined $sub;
2051         foreach my $p (keys %pagesources) {
2052                 my $r=$sub->($p, location => $page);
2053                 my $i=$r->influences;
2054                 my $static=$r->influences_static;
2055                 foreach my $k (keys %$i) {
2056                         next unless $r || $static || $k eq $page;
2057                         $depends_simple{$page}{lc $k} |= $i->{$k};
2058                 }
2059                 last if $static;
2060         }
2061
2062         $depends{$page}{$pagespec} |= $deptype;
2063         return 1;
2064 }
2065
2066 sub deptype (@) {
2067         my $deptype=0;
2068         foreach my $type (@_) {
2069                 if ($type eq 'presence') {
2070                         $deptype |= $DEPEND_PRESENCE;
2071                 }
2072                 elsif ($type eq 'links') {
2073                         $deptype |= $DEPEND_LINKS;
2074                 }
2075                 elsif ($type eq 'content') {
2076                         $deptype |= $DEPEND_CONTENT;
2077                 }
2078         }
2079         return $deptype;
2080 }
2081
2082 my $file_prune_regexp;
2083 sub file_pruned ($) {
2084         my $file=shift;
2085
2086         if (defined $config{include} && length $config{include}) {
2087                 return 0 if $file =~ m/$config{include}/;
2088         }
2089
2090         if (! defined $file_prune_regexp) {
2091                 $file_prune_regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
2092                 $file_prune_regexp=qr/$file_prune_regexp/;
2093         }
2094         return $file =~ m/$file_prune_regexp/;
2095 }
2096
2097 sub define_gettext () {
2098         # If translation is needed, redefine the gettext function to do it.
2099         # Otherwise, it becomes a quick no-op.
2100         my $gettext_obj;
2101         my $getobj;
2102         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
2103             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
2104             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
2105                 $getobj=sub {
2106                         $gettext_obj=eval q{
2107                                 use Locale::gettext q{textdomain};
2108                                 Locale::gettext->domain('ikiwiki')
2109                         };
2110                 };
2111         }
2112
2113         no warnings 'redefine';
2114         *gettext=sub {
2115                 $getobj->() if $getobj;
2116                 if ($gettext_obj) {
2117                         $gettext_obj->get(shift);
2118                 }
2119                 else {
2120                         return shift;
2121                 }
2122         };
2123         *ngettext=sub {
2124                 $getobj->() if $getobj;
2125                 if ($gettext_obj) {
2126                         $gettext_obj->nget(@_);
2127                 }
2128                 else {
2129                         return ($_[2] == 1 ? $_[0] : $_[1])
2130                 }
2131         };
2132 }
2133
2134 sub gettext {
2135         define_gettext();
2136         gettext(@_);
2137 }
2138
2139 sub ngettext {
2140         define_gettext();
2141         ngettext(@_);
2142 }
2143
2144 sub yesno ($) {
2145         my $val=shift;
2146
2147         return (defined $val && (lc($val) eq gettext("yes") || lc($val) eq "yes" || $val eq "1"));
2148 }
2149
2150 sub inject {
2151         # Injects a new function into the symbol table to replace an
2152         # exported function.
2153         my %params=@_;
2154
2155         # This is deep ugly perl foo, beware.
2156         no strict;
2157         no warnings;
2158         if (! defined $params{parent}) {
2159                 $params{parent}='::';
2160                 $params{old}=\&{$params{name}};
2161                 $params{name}=~s/.*:://;
2162         }
2163         my $parent=$params{parent};
2164         foreach my $ns (grep /^\w+::/, keys %{$parent}) {
2165                 $ns = $params{parent} . $ns;
2166                 inject(%params, parent => $ns) unless $ns eq '::main::';
2167                 *{$ns . $params{name}} = $params{call}
2168                         if exists ${$ns}{$params{name}} &&
2169                            \&{${$ns}{$params{name}}} == $params{old};
2170         }
2171         use strict;
2172         use warnings;
2173 }
2174
2175 sub add_link ($$;$) {
2176         my $page=shift;
2177         my $link=shift;
2178         my $type=shift;
2179
2180         push @{$links{$page}}, $link
2181                 unless grep { $_ eq $link } @{$links{$page}};
2182
2183         if (defined $type) {
2184                 $typedlinks{$page}{$type}{$link} = 1;
2185         }
2186 }
2187
2188 sub add_autofile ($$$) {
2189         my $file=shift;
2190         my $plugin=shift;
2191         my $generator=shift;
2192
2193         $autofiles{$file}{plugin}=$plugin;
2194         $autofiles{$file}{generator}=$generator;
2195 }
2196
2197 sub sortspec_translate ($$) {
2198         my $spec = shift;
2199         my $reverse = shift;
2200
2201         my $code = "";
2202         my @data;
2203         while ($spec =~ m{
2204                 \s*
2205                 (-?)            # group 1: perhaps negated
2206                 \s*
2207                 (               # group 2: a word
2208                         \w+\([^\)]*\)   # command(params)
2209                         |
2210                         [^\s]+          # or anything else
2211                 )
2212                 \s*
2213         }gx) {
2214                 my $negated = $1;
2215                 my $word = $2;
2216                 my $params = undef;
2217
2218                 if ($word =~ m/^(\w+)\((.*)\)$/) {
2219                         # command with parameters
2220                         $params = $2;
2221                         $word = $1;
2222                 }
2223                 elsif ($word !~ m/^\w+$/) {
2224                         error(sprintf(gettext("invalid sort type %s"), $word));
2225                 }
2226
2227                 if (length $code) {
2228                         $code .= " || ";
2229                 }
2230
2231                 if ($negated) {
2232                         $code .= "-";
2233                 }
2234
2235                 if (exists $IkiWiki::SortSpec::{"cmp_$word"}) {
2236                         if (defined $params) {
2237                                 push @data, $params;
2238                                 $code .= "IkiWiki::SortSpec::cmp_$word(\$data[$#data])";
2239                         }
2240                         else {
2241                                 $code .= "IkiWiki::SortSpec::cmp_$word(undef)";
2242                         }
2243                 }
2244                 else {
2245                         error(sprintf(gettext("unknown sort type %s"), $word));
2246                 }
2247         }
2248
2249         if (! length $code) {
2250                 # undefined sorting method... sort arbitrarily
2251                 return sub { 0 };
2252         }
2253
2254         if ($reverse) {
2255                 $code="-($code)";
2256         }
2257
2258         no warnings;
2259         return eval 'sub { '.$code.' }';
2260 }
2261
2262 sub pagespec_translate ($) {
2263         my $spec=shift;
2264
2265         # Convert spec to perl code.
2266         my $code="";
2267         my @data;
2268         while ($spec=~m{
2269                 \s*             # ignore whitespace
2270                 (               # 1: match a single word
2271                         \!              # !
2272                 |
2273                         \(              # (
2274                 |
2275                         \)              # )
2276                 |
2277                         \w+\([^\)]*\)   # command(params)
2278                 |
2279                         [^\s()]+        # any other text
2280                 )
2281                 \s*             # ignore whitespace
2282         }gx) {
2283                 my $word=$1;
2284                 if (lc $word eq 'and') {
2285                         $code.=' &';
2286                 }
2287                 elsif (lc $word eq 'or') {
2288                         $code.=' |';
2289                 }
2290                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
2291                         $code.=' '.$word;
2292                 }
2293                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
2294                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
2295                                 push @data, $2;
2296                                 $code.="IkiWiki::PageSpec::match_$1(\$page, \$data[$#data], \@_)";
2297                         }
2298                         else {
2299                                 push @data, qq{unknown function in pagespec "$word"};
2300                                 $code.="IkiWiki::ErrorReason->new(\$data[$#data])";
2301                         }
2302                 }
2303                 else {
2304                         push @data, $word;
2305                         $code.=" IkiWiki::PageSpec::match_glob(\$page, \$data[$#data], \@_)";
2306                 }
2307         }
2308
2309         if (! length $code) {
2310                 $code="IkiWiki::FailReason->new('empty pagespec')";
2311         }
2312
2313         no warnings;
2314         return eval 'sub { my $page=shift; '.$code.' }';
2315 }
2316
2317 sub pagespec_match ($$;@) {
2318         my $page=shift;
2319         my $spec=shift;
2320         my @params=@_;
2321
2322         # Backwards compatability with old calling convention.
2323         if (@params == 1) {
2324                 unshift @params, 'location';
2325         }
2326
2327         my $sub=pagespec_translate($spec);
2328         return IkiWiki::ErrorReason->new("syntax error in pagespec \"$spec\"")
2329                 if ! defined $sub;
2330         return $sub->($page, @params);
2331 }
2332
2333 sub pagespec_match_list ($$;@) {
2334         my $page=shift;
2335         my $pagespec=shift;
2336         my %params=@_;
2337
2338         # Backwards compatability with old calling convention.
2339         if (ref $page) {
2340                 print STDERR "warning: a plugin (".caller().") is using pagespec_match_list in an obsolete way, and needs to be updated\n";
2341                 $params{list}=$page;
2342                 $page=$params{location}; # ugh!
2343         }
2344
2345         my $sub=pagespec_translate($pagespec);
2346         error "syntax error in pagespec \"$pagespec\""
2347                 if ! defined $sub;
2348         my $sort=sortspec_translate($params{sort}, $params{reverse})
2349                 if defined $params{sort};
2350
2351         my @candidates;
2352         if (exists $params{list}) {
2353                 @candidates=exists $params{filter}
2354                         ? grep { ! $params{filter}->($_) } @{$params{list}}
2355                         : @{$params{list}};
2356         }
2357         else {
2358                 @candidates=exists $params{filter}
2359                         ? grep { ! $params{filter}->($_) } keys %pagesources
2360                         : keys %pagesources;
2361         }
2362
2363         # clear params, remainder is passed to pagespec
2364         $depends{$page}{$pagespec} |= ($params{deptype} || $DEPEND_CONTENT);
2365         my $num=$params{num};
2366         delete @params{qw{num deptype reverse sort filter list}};
2367
2368         # when only the top matches will be returned, it's efficient to
2369         # sort before matching to pagespec,
2370         if (defined $num && defined $sort) {
2371                 @candidates=IkiWiki::SortSpec::sort_pages(
2372                         $sort, @candidates);
2373         }
2374
2375         my @matches;
2376         my $firstfail;
2377         my $count=0;
2378         my $accum=IkiWiki::SuccessReason->new();
2379         foreach my $p (@candidates) {
2380                 my $r=$sub->($p, %params, location => $page);
2381                 error(sprintf(gettext("cannot match pages: %s"), $r))
2382                         if $r->isa("IkiWiki::ErrorReason");
2383                 unless ($r || $r->influences_static) {
2384                         $r->remove_influence($p);
2385                 }
2386                 $accum |= $r;
2387                 if ($r) {
2388                         push @matches, $p;
2389                         last if defined $num && ++$count == $num;
2390                 }
2391         }
2392
2393         # Add simple dependencies for accumulated influences.
2394         my $i=$accum->influences;
2395         foreach my $k (keys %$i) {
2396                 $depends_simple{$page}{lc $k} |= $i->{$k};
2397         }
2398
2399         # when all matches will be returned, it's efficient to
2400         # sort after matching
2401         if (! defined $num && defined $sort) {
2402                 return IkiWiki::SortSpec::sort_pages(
2403                         $sort, @matches);
2404         }
2405         else {
2406                 return @matches;
2407         }
2408 }
2409
2410 sub pagespec_valid ($) {
2411         my $spec=shift;
2412
2413         return defined pagespec_translate($spec);
2414 }
2415
2416 sub glob2re ($) {
2417         my $re=quotemeta(shift);
2418         $re=~s/\\\*/.*/g;
2419         $re=~s/\\\?/./g;
2420         return qr/^$re$/i;
2421 }
2422
2423 package IkiWiki::FailReason;
2424
2425 use overload (
2426         '""'    => sub { $_[0][0] },
2427         '0+'    => sub { 0 },
2428         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
2429         '&'     => sub { $_[0]->merge_influences($_[1], 1); $_[0] },
2430         '|'     => sub { $_[1]->merge_influences($_[0]); $_[1] },
2431         fallback => 1,
2432 );
2433
2434 our @ISA = 'IkiWiki::SuccessReason';
2435
2436 package IkiWiki::SuccessReason;
2437
2438 use overload (
2439         '""'    => sub { $_[0][0] },
2440         '0+'    => sub { 1 },
2441         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
2442         '&'     => sub { $_[1]->merge_influences($_[0], 1); $_[1] },
2443         '|'     => sub { $_[0]->merge_influences($_[1]); $_[0] },
2444         fallback => 1,
2445 );
2446
2447 sub new {
2448         my $class = shift;
2449         my $value = shift;
2450         return bless [$value, {@_}], $class;
2451 }
2452
2453 sub influences {
2454         my $this=shift;
2455         $this->[1]={@_} if @_;
2456         my %i=%{$this->[1]};
2457         delete $i{""};
2458         return \%i;
2459 }
2460
2461 sub influences_static {
2462         return ! $_[0][1]->{""};
2463 }
2464
2465 sub merge_influences {
2466         my $this=shift;
2467         my $other=shift;
2468         my $anded=shift;
2469
2470         if (! $anded || (($this || %{$this->[1]}) &&
2471                          ($other || %{$other->[1]}))) {
2472                 foreach my $influence (keys %{$other->[1]}) {
2473                         $this->[1]{$influence} |= $other->[1]{$influence};
2474                 }
2475         }
2476         else {
2477                 # influence blocker
2478                 $this->[1]={};
2479         }
2480 }
2481
2482 sub remove_influence {
2483         my $this=shift;
2484         my $torm=shift;
2485
2486         delete $this->[1]{$torm};
2487 }
2488
2489 package IkiWiki::ErrorReason;
2490
2491 our @ISA = 'IkiWiki::FailReason';
2492
2493 package IkiWiki::PageSpec;
2494
2495 sub derel ($$) {
2496         my $path=shift;
2497         my $from=shift;
2498
2499         if ($path =~ m!^\.(/|$)!) {
2500                 if ($1) {
2501                         $from=~s#/?[^/]+$## if defined $from;
2502                         $path=~s#^\./##;
2503                         $path="$from/$path" if defined $from && length $from;
2504                 }
2505                 else {
2506                         $path = $from;
2507                         $path = "" unless defined $path;
2508                 }
2509         }
2510
2511         return $path;
2512 }
2513
2514 my %glob_cache;
2515
2516 sub match_glob ($$;@) {
2517         my $page=shift;
2518         my $glob=shift;
2519         my %params=@_;
2520
2521         $glob=derel($glob, $params{location});
2522
2523         # Instead of converting the glob to a regex every time,
2524         # cache the compiled regex to save time.
2525         my $re=$glob_cache{$glob};
2526         unless (defined $re) {
2527                 $glob_cache{$glob} = $re = IkiWiki::glob2re($glob);
2528         }
2529         if ($page =~ $re) {
2530                 if (! IkiWiki::isinternal($page) || $params{internal}) {
2531                         return IkiWiki::SuccessReason->new("$glob matches $page");
2532                 }
2533                 else {
2534                         return IkiWiki::FailReason->new("$glob matches $page, but the page is an internal page");
2535                 }
2536         }
2537         else {
2538                 return IkiWiki::FailReason->new("$glob does not match $page");
2539         }
2540 }
2541
2542 sub match_internal ($$;@) {
2543         return match_glob(shift, shift, @_, internal => 1)
2544 }
2545
2546 sub match_page ($$;@) {
2547         my $page=shift;
2548         my $match=match_glob($page, shift, @_);
2549         if ($match) {
2550                 my $source=exists $IkiWiki::pagesources{$page} ?
2551                         $IkiWiki::pagesources{$page} :
2552                         $IkiWiki::delpagesources{$page};
2553                 my $type=defined $source ? IkiWiki::pagetype($source) : undef;
2554                 if (! defined $type) {
2555                         return IkiWiki::FailReason->new("$page is not a page");
2556                 }
2557         }
2558         return $match;
2559 }
2560
2561 sub match_link ($$;@) {
2562         my $page=shift;
2563         my $link=lc(shift);
2564         my %params=@_;
2565
2566         $link=derel($link, $params{location});
2567         my $from=exists $params{location} ? $params{location} : '';
2568         my $linktype=$params{linktype};
2569         my $qualifier='';
2570         if (defined $linktype) {
2571                 $qualifier=" with type $linktype";
2572         }
2573
2574         my $links = $IkiWiki::links{$page};
2575         return IkiWiki::FailReason->new("$page has no links", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2576                 unless $links && @{$links};
2577         my $bestlink = IkiWiki::bestlink($from, $link);
2578         foreach my $p (@{$links}) {
2579                 next unless (! defined $linktype || exists $IkiWiki::typedlinks{$page}{$linktype}{$p});
2580
2581                 if (length $bestlink) {
2582                         if ($bestlink eq IkiWiki::bestlink($page, $p)) {
2583                                 return IkiWiki::SuccessReason->new("$page links to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2584                         }
2585                 }
2586                 else {
2587                         if (match_glob($p, $link, %params)) {
2588                                 return IkiWiki::SuccessReason->new("$page links to page $p$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2589                         }
2590                         my ($p_rel)=$p=~/^\/?(.*)/;
2591                         $link=~s/^\///;
2592                         if (match_glob($p_rel, $link, %params)) {
2593                                 return IkiWiki::SuccessReason->new("$page links to page $p_rel$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2594                         }
2595                 }
2596         }
2597         return IkiWiki::FailReason->new("$page does not link to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1);
2598 }
2599
2600 sub match_backlink ($$;@) {
2601         my $ret=match_link($_[1], $_[0], @_);
2602         $ret->influences($_[1] => $IkiWiki::DEPEND_LINKS);
2603         return $ret;
2604 }
2605
2606 sub match_created_before ($$;@) {
2607         my $page=shift;
2608         my $testpage=shift;
2609         my %params=@_;
2610
2611         $testpage=derel($testpage, $params{location});
2612
2613         if (exists $IkiWiki::pagectime{$testpage}) {
2614                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
2615                         return IkiWiki::SuccessReason->new("$page created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2616                 }
2617                 else {
2618                         return IkiWiki::FailReason->new("$page not created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2619                 }
2620         }
2621         else {
2622                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2623         }
2624 }
2625
2626 sub match_created_after ($$;@) {
2627         my $page=shift;
2628         my $testpage=shift;
2629         my %params=@_;
2630
2631         $testpage=derel($testpage, $params{location});
2632
2633         if (exists $IkiWiki::pagectime{$testpage}) {
2634                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
2635                         return IkiWiki::SuccessReason->new("$page created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2636                 }
2637                 else {
2638                         return IkiWiki::FailReason->new("$page not created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2639                 }
2640         }
2641         else {
2642                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2643         }
2644 }
2645
2646 sub match_creation_day ($$;@) {
2647         my $page=shift;
2648         my $d=shift;
2649         if ($d !~ /^\d+$/) {
2650                 return IkiWiki::ErrorReason->new("invalid day $d");
2651         }
2652         if ((localtime($IkiWiki::pagectime{$page}))[3] == $d) {
2653                 return IkiWiki::SuccessReason->new('creation_day matched');
2654         }
2655         else {
2656                 return IkiWiki::FailReason->new('creation_day did not match');
2657         }
2658 }
2659
2660 sub match_creation_month ($$;@) {
2661         my $page=shift;
2662         my $m=shift;
2663         if ($m !~ /^\d+$/) {
2664                 return IkiWiki::ErrorReason->new("invalid month $m");
2665         }
2666         if ((localtime($IkiWiki::pagectime{$page}))[4] + 1 == $m) {
2667                 return IkiWiki::SuccessReason->new('creation_month matched');
2668         }
2669         else {
2670                 return IkiWiki::FailReason->new('creation_month did not match');
2671         }
2672 }
2673
2674 sub match_creation_year ($$;@) {
2675         my $page=shift;
2676         my $y=shift;
2677         if ($y !~ /^\d+$/) {
2678                 return IkiWiki::ErrorReason->new("invalid year $y");
2679         }
2680         if ((localtime($IkiWiki::pagectime{$page}))[5] + 1900 == $y) {
2681                 return IkiWiki::SuccessReason->new('creation_year matched');
2682         }
2683         else {
2684                 return IkiWiki::FailReason->new('creation_year did not match');
2685         }
2686 }
2687
2688 sub match_user ($$;@) {
2689         shift;
2690         my $user=shift;
2691         my %params=@_;
2692
2693         my $regexp=IkiWiki::glob2re($user);
2694
2695         if (! exists $params{user}) {
2696                 return IkiWiki::ErrorReason->new("no user specified");
2697         }
2698
2699         if (defined $params{user} && $params{user}=~$regexp) {
2700                 return IkiWiki::SuccessReason->new("user is $user");
2701         }
2702         elsif (! defined $params{user}) {
2703                 return IkiWiki::FailReason->new("not logged in");
2704         }
2705         else {
2706                 return IkiWiki::FailReason->new("user is $params{user}, not $user");
2707         }
2708 }
2709
2710 sub match_admin ($$;@) {
2711         shift;
2712         shift;
2713         my %params=@_;
2714
2715         if (! exists $params{user}) {
2716                 return IkiWiki::ErrorReason->new("no user specified");
2717         }
2718
2719         if (defined $params{user} && IkiWiki::is_admin($params{user})) {
2720                 return IkiWiki::SuccessReason->new("user is an admin");
2721         }
2722         elsif (! defined $params{user}) {
2723                 return IkiWiki::FailReason->new("not logged in");
2724         }
2725         else {
2726                 return IkiWiki::FailReason->new("user is not an admin");
2727         }
2728 }
2729
2730 sub match_ip ($$;@) {
2731         shift;
2732         my $ip=shift;
2733         my %params=@_;
2734
2735         if (! exists $params{ip}) {
2736                 return IkiWiki::ErrorReason->new("no IP specified");
2737         }
2738
2739         if (defined $params{ip} && lc $params{ip} eq lc $ip) {
2740                 return IkiWiki::SuccessReason->new("IP is $ip");
2741         }
2742         else {
2743                 return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
2744         }
2745 }
2746
2747 package IkiWiki::SortSpec;
2748
2749 # This is in the SortSpec namespace so that the $a and $b that sort() uses
2750 # are easily available in this namespace, for cmp functions to use them.
2751 sub sort_pages {
2752         my $f=shift;
2753         sort $f @_
2754 }
2755
2756 sub cmp_title {
2757         IkiWiki::pagetitle(IkiWiki::basename($a))
2758         cmp
2759         IkiWiki::pagetitle(IkiWiki::basename($b))
2760 }
2761
2762 sub cmp_mtime { $IkiWiki::pagemtime{$b} <=> $IkiWiki::pagemtime{$a} }
2763 sub cmp_age { $IkiWiki::pagectime{$b} <=> $IkiWiki::pagectime{$a} }
2764
2765 1