configure.ac

   1
   2 AC_INIT
   3 AC_CONFIG_SRCDIR([comedi/comedi_fops.c])
   4 AC_CONFIG_HEADERS(config.h)
   5
   6 AC_CANONICAL_TARGET([])
   7
   8 if test x$prefix = xNONE ; then
   9   prefix=/
  10 fi
  11
  12 PACKAGE=comedi
  13 COMEDI_MAJORVERSION=0
  14 COMEDI_MINORVERSION=7
  15 COMEDI_MICROVERSION=73
  16 # set the nanoversion to 0 for releases, 1 for CVS, >= 2 for prereleases
  17 COMEDI_NANOVERSION=0
  18
  19 if test x$COMEDI_NANOVERSION = x0 ; then
  20   VERSION=$COMEDI_MAJORVERSION.$COMEDI_MINORVERSION.$COMEDI_MICROVERSION
  21 else
  22   VERSION=$COMEDI_MAJORVERSION.$COMEDI_MINORVERSION.$COMEDI_MICROVERSION.$COMEDI_NANOVERSION
  23 fi
  24
  25 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  26 AM_MAINTAINER_MODE
  27
  28 AC_SUBST(PACKAGE)
  29 AC_SUBST(VERSION)
  30 AC_DEFINE_UNQUOTED(COMEDI_MAJORVERSION, $COMEDI_MAJORVERSION, [Comedi major version])
  31 AC_DEFINE_UNQUOTED(COMEDI_MINORVERSION, $COMEDI_MINORVERSION, [Comedi minor version])
  32 AC_DEFINE_UNQUOTED(COMEDI_MICROVERSION, $COMEDI_MICROVERSION, [Comedi micro version])
  33
  34 AC_PROG_CC()
  35 AM_PROG_CC_C_O
  36 AC_PATH_TOOL([STRIP],[strip])
  37 AC_PATH_PROG([DEPMOD], [depmod], [no], [$PATH:/sbin:/usr/sbin:/usr/local/sbin])
  38 if test "$DEPMOD" == "no" ; then
  39         AC_MSG_ERROR([unable to find the 'depmod' program.])
  40 fi
  41
  42 AS_LINUX()
  43 AS_LINUX_MODTOOL()
  44
  45 AC_ARG_ENABLE([rtai], [  --disable-rtai disable use of rtai],
  46         [ENABLE_RTAI=$enableval], [ENABLE_RTAI="yes"])
  47 DS_RTAI([HAVE_RTAI=yes],[HAVE_RTAI=no])
  48 if test "$HAVE_RTAI" == "yes" -a "$ENABLE_RTAI" == "yes"; then
  49         USE_RTAI="yes"
  50 else
  51         USE_RTAI="no"
  52 fi
  53 DS_RTLINUX([USE_RTLINUX=yes],[USE_RTLINUX=no])
  54 AM_CONDITIONAL([CONFIG_COMEDI_RT],
  55         [test ${USE_RTAI} = "yes" -o ${USE_RTLINUX} = "yes"])
  56 if test ${USE_RTAI} = "yes" -o ${USE_RTLINUX} = "yes" ; then
  57         AC_DEFINE([CONFIG_COMEDI_RT],[true],[Define to enable Comedi's real-time support])
  58 fi
  59
  60
  61 CC=$LINUX_CC
  62
  63 #ERROR_CFLAGS="-Werror"
  64
  65 [COMEDI_CFLAGS="$ERROR_CFLAGS -I\$(top_srcdir)/include/\
  66  -DKBUILD_MODNAME=\$(shell basename \$@ .o | sed 's/\(.*\)_ko.*/\1/g')\
  67  -DKBUILD_BASENAME=\$(shell basename \$< .c)"]
  68 AC_SUBST(COMEDI_CFLAGS)
  69
  70 COMEDI_CHECK_PCMCIA_PROBE([$LINUX_DIR], [ENABLE_PCMCIA="yes"], [ENABLE_PCMCIA="no"])
  71 AC_ARG_ENABLE([pcmcia],[  --disable-pcmcia      Disable support for PCMCIA devices],
  72         [ENABLE_PCMCIA=$enableval],[])
  73 if test "$ENABLE_PCMCIA" = "yes" ; then
  74         AS_LINUX_CONFIG_OPTION_MODULE(CONFIG_PCMCIA)
  75 else
  76         AC_MSG_NOTICE([PCMCIA support disabled])
  77         AM_CONDITIONAL(CONFIG_PCMCIA,false)
  78 fi
  79 AC_ARG_ENABLE([usb],[  --disable-usb            Disable support for USB devices],
  80         [ENABLE_USB=$enableval],[ENABLE_USB="yes"])
  81 if test "$ENABLE_USB" = "yes" ; then
  82         AS_LINUX_CONFIG_OPTION_MODULE(CONFIG_USB)
  83 else
  84         AC_MSG_NOTICE([USB support disabled])
  85         AM_CONDITIONAL(CONFIG_USB,false)
  86 fi
  87 COMEDI_CHECK_LINUX_KBUILD([$LINUX_DIR], [ENABLE_KBUILD="yes"], [ENABLE_KBUILD="no"])
  88 AC_ARG_ENABLE([kbuild], [  --enable-kbuild      Force use (or not) of kernel's Kbuild system to build modules (needs recent 2.6 kernel)],
  89         [ENABLE_KBUILD=$enableval], [])
  90 AM_CONDITIONAL([CONFIG_KBUILD], [test ${ENABLE_KBUILD} = "yes"])
  91 AS_LINUX_CONFIG_OPTION_MODULE(CONFIG_ISA)
  92 AS_LINUX_CONFIG_OPTION_MODULE(CONFIG_PCI)
  93
  94 AC_DEFINE(CONFIG_COMEDI_DEBUG, true, [Define if debugging is enabled])
  95 AC_DEFINE(CONFIG_COMEDI_8255, true, [Define if 8255 support is enabled])
  96
  97 DISTCHECK_CONFIGURE_FLAGS="--with-modulesdir=\\\$\$\(prefix\)/modules"
  98 AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
  99
 100 AC_CONFIG_FILES([
 101 Makefile
 102 comedi/Makefile
 103 comedi/drivers/Makefile
 104 comedi/drivers/addi-data/Makefile
 105 comedi/kcomedilib/Makefile
 106 ])
 107 AC_OUTPUT
 108