dev-python/execnet/execnet-1.1-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header$
   4
   5 EAPI=5
   6
   7 PYTHON_COMPAT=( python{2_6,2_7} pypy pypy2_0 )
   8
   9 inherit distutils-r1
  10
  11 DESCRIPTION="Rapid multi-Python deployment"
  12 HOMEPAGE="http://codespeak.net/execnet/ http://pypi.python.org/pypi/execnet/"
  13 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="doc"
  19
  20 DEPEND="app-arch/unzip
  21         dev-python/setuptools[${PYTHON_USEDEP}]
  22         doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
  23 RDEPEND=""
  24
  25 python_compile_all() {
  26         use doc && emake -C doc html
  27 }
  28
  29 src_test() {
  30         # Tests are a bit fragile to failures in parallel.
  31         # XXX: take a closer look, it may be easy to fix.
  32         local DISTUTILS_NO_PARALLEL_BUILD=1
  33
  34         distutils-r1_src_test
  35 }
  36
  37 python_test() {
  38         # Re-enable in order to properly test disabling it ;).
  39         # https://bitbucket.org/hpk42/execnet/issue/10
  40         unset PYTHONDONTWRITEBYTECODE
  41
  42         py.test || die "Tests fail with ${EPYTHON}"
  43 }
  44
  45 python_install_all() {
  46         use doc && local HTML_DOCS=( doc/_build/html/. )
  47
  48         distutils-r1_python_install_all
  49 }