src/share/keytrans

   1 #!/usr/bin/perl -T
   2
   3 # keytrans: this is an RSA key translation utility; it is capable of
   4 # transforming RSA keys (both public keys and secret keys) between
   5 # several popular representations, including OpenPGP, PEM-encoded
   6 # PKCS#1 DER, and OpenSSH-style public key lines.
   7
   8 # How it behaves depends on the name under which it is invoked.  The
   9 # two implementations currently are: pem2openpgp and openpgp2ssh.
  10
  11
  12
  13 # pem2openpgp: take a PEM-encoded RSA private-key on standard input, a
  14 # User ID as the first argument, and generate an OpenPGP secret key
  15 # and certificate from it.
  16
  17 # WARNING: the secret key material *will* appear on stdout (albeit in
  18 # OpenPGP form) -- if you redirect stdout to a file, make sure the
  19 # permissions on that file are appropriately locked down!
  20
  21 # Usage:
  22
  23 # pem2openpgp 'ssh://'$(hostname -f) < /etc/ssh/ssh_host_rsa_key | gpg --import
  24
  25
  26
  27
  28 # openpgp2ssh: take a stream of OpenPGP packets containing public or
  29 # secret key material on standard input, and a Key ID (or fingerprint)
  30 # as the first argument.  Find the matching key in the input stream,
  31 # and emit it on stdout in an OpenSSH-compatible format.  If the input
  32 # key is an OpenPGP public key (either primary or subkey), the output
  33 # will be an OpenSSH single-line public key.  If the input key is an
  34 # OpenPGP secret key, the output will be a PEM-encoded RSA key.
  35
  36 # Example usage:
  37
  38 # gpg --export-secret-subkeys --export-options export-reset-subkey-passwd $KEYID | \
  39 #  openpgp2ssh $KEYID | ssh-add /dev/stdin
  40
  41
  42 # Authors:
  43 #  Jameson Rollins <jrollins@finestructure.net>
  44 #  Daniel Kahn Gillmor <dkg@fifthhorseman.net>
  45
  46 # Started on: 2009-01-07 02:01:19-0500
  47
  48 # License: GPL v3 or later (we may need to adjust this given that this
  49 # connects to OpenSSL via perl)
  50
  51 use strict;
  52 use warnings;
  53 use File::Basename;
  54 use Crypt::OpenSSL::RSA;
  55 use Crypt::OpenSSL::Bignum;
  56 use Crypt::OpenSSL::Bignum::CTX;
  57 use Digest::SHA;
  58 use MIME::Base64;
  59 use POSIX;
  60
  61 ## make sure all length() and substr() calls use bytes only:
  62 use bytes;
  63
  64 my $old_format_packet_lengths = { one => 0,
  65                                   two => 1,
  66                                   four => 2,
  67                                   indeterminate => 3,
  68 };
  69
  70 # see RFC 4880 section 9.1 (ignoring deprecated algorithms for now)
  71 my $asym_algos = { rsa => 1,
  72                    elgamal => 16,
  73                    dsa => 17,
  74                    };
  75
  76 # see RFC 4880 section 9.2
  77 my $ciphers = { plaintext => 0,
  78                 idea => 1,
  79                 tripledes => 2,
  80                 cast5 => 3,
  81                 blowfish => 4,
  82                 aes128 => 7,
  83                 aes192 => 8,
  84                 aes256 => 9,
  85                 twofish => 10,
  86               };
  87
  88 # see RFC 4880 section 9.3
  89 my $zips = { uncompressed => 0,
  90              zip => 1,
  91              zlib => 2,
  92              bzip2 => 3,
  93            };
  94
  95 # see RFC 4880 section 9.4
  96 my $digests = { md5 => 1,
  97                 sha1 => 2,
  98                 ripemd160 => 3,
  99                 sha256 => 8,
 100                 sha384 => 9,
 101                 sha512 => 10,
 102                 sha224 => 11,
 103               };
 104
 105 # see RFC 4880 section 5.2.3.21
 106 my $usage_flags = { certify => 0x01,
 107                     sign => 0x02,
 108                     encrypt_comms => 0x04,
 109                     encrypt_storage => 0x08,
 110                     encrypt => 0x0c, ## both comms and storage
 111                     split => 0x10, # the private key is split via secret sharing
 112                     authenticate => 0x20,
 113                     shared => 0x80, # more than one person holds the entire private key
 114                   };
 115
 116 # see RFC 4880 section 4.3
 117 my $packet_types = { pubkey_enc_session => 1,
 118                      sig => 2,
 119                      symkey_enc_session => 3,
 120                      onepass_sig => 4,
 121                      seckey => 5,
 122                      pubkey => 6,
 123                      sec_subkey => 7,
 124                      compressed_data => 8,
 125                      symenc_data => 9,
 126                      marker => 10,
 127                      literal => 11,
 128                      trust => 12,
 129                      uid => 13,
 130                      pub_subkey => 14,
 131                      uat => 17,
 132                      symenc_w_integrity => 18,
 133                      mdc => 19,
 134                    };
 135
 136 # see RFC 4880 section 5.2.1
 137 my $sig_types = { binary_doc => 0x00,
 138                   text_doc => 0x01,
 139                   standalone => 0x02,
 140                   generic_certification => 0x10,
 141                   persona_certification => 0x11,
 142                   casual_certification => 0x12,
 143                   positive_certification => 0x13,
 144                   subkey_binding => 0x18,
 145                   primary_key_binding => 0x19,
 146                   key_signature => 0x1f,
 147                   key_revocation => 0x20,
 148                   subkey_revocation => 0x28,
 149                   certification_revocation => 0x30,
 150                   timestamp => 0x40,
 151                   thirdparty => 0x50,
 152                 };
 153
 154
 155 # see RFC 4880 section 5.2.3.23
 156 my $revocation_reasons = { no_reason_specified => 0,
 157                            key_superseded => 1,
 158                            key_compromised => 2,
 159                            key_retired => 3,
 160                            user_id_no_longer_valid => 32,
 161                          };
 162
 163 # see RFC 4880 section 5.2.3.1
 164 my $subpacket_types = { sig_creation_time => 2,
 165                         sig_expiration_time => 3,
 166                         exportable => 4,
 167                         trust_sig => 5,
 168                         regex => 6,
 169                         revocable => 7,
 170                         key_expiration_time => 9,
 171                         preferred_cipher => 11,
 172                         revocation_key => 12,
 173                         issuer => 16,
 174                         notation => 20,
 175                         preferred_digest => 21,
 176                         preferred_compression => 22,
 177                         keyserver_prefs => 23,
 178                         preferred_keyserver => 24,
 179                         primary_uid => 25,
 180                         policy_uri => 26,
 181                         usage_flags => 27,
 182                         signers_uid => 28,
 183                         revocation_reason => 29,
 184                         features => 30,
 185                         signature_target => 31,
 186                         embedded_signature => 32,
 187                        };
 188
 189 # bitstring (see RFC 4880 section 5.2.3.24)
 190 my $features = { mdc => 0x01
 191                };
 192
 193 # bitstring (see RFC 4880 5.2.3.17)
 194 my $keyserver_prefs = { nomodify => 0x80
 195                       };
 196
 197 ###### end lookup tables ######
 198
 199 # FIXME: if we want to be able to interpret openpgp data as well as
 200 # produce it, we need to produce key/value-swapped lookup tables as well.
 201
 202
 203 ########### Math/Utility Functions ##############
 204
 205
 206 # see the bottom of page 44 of RFC 4880 (http://tools.ietf.org/html/rfc4880#page-44)
 207 sub simple_checksum {
 208   my $bytes = shift;
 209
 210   return unpack("%16C*",$bytes);
 211 }
 212
 213 # calculate the multiplicative inverse of a mod b this is euclid's
 214 # extended algorithm.  For more information see:
 215 # http://en.wikipedia.org/wiki/Extended_Euclidean_algorithm the
 216 # arguments here should be Crypt::OpenSSL::Bignum objects.  $a should
 217 # be the larger of the two values, and the two values should be
 218 # coprime.
 219
 220 sub modular_multi_inverse {
 221   my $a = shift;
 222   my $b = shift;
 223
 224
 225   my $origdivisor = $b->copy();
 226
 227   my $ctx = Crypt::OpenSSL::Bignum::CTX->new();
 228   my $x = Crypt::OpenSSL::Bignum->zero();
 229   my $y = Crypt::OpenSSL::Bignum->one();
 230   my $lastx = Crypt::OpenSSL::Bignum->one();
 231   my $lasty = Crypt::OpenSSL::Bignum->zero();
 232
 233   my $finalquotient;
 234   my $finalremainder;
 235
 236   while (! $b->is_zero()) {
 237     my ($quotient, $remainder) = $a->div($b, $ctx);
 238
 239     $a = $b;
 240     $b = $remainder;
 241
 242     my $temp = $x;
 243     $x = $lastx->sub($quotient->mul($x, $ctx));
 244     $lastx = $temp;
 245
 246     $temp = $y;
 247     $y = $lasty->sub($quotient->mul($y, $ctx));
 248     $lasty = $temp;
 249   }
 250
 251   if (!$a->is_one()) {
 252     die "did this math wrong.\n";
 253   }
 254
 255   # let's make sure that we return a positive value because RFC 4880,
 256   # section 3.2 only allows unsigned values:
 257
 258   ($finalquotient, $finalremainder) = $lastx->add($origdivisor)->div($origdivisor, $ctx);
 259
 260   return $finalremainder;
 261 }
 262
 263
 264 ############ OpenPGP formatting functions ############
 265
 266 # make an old-style packet out of the given packet type and body.
 267 # old-style  (see RFC 4880 section 4.2)
 268 sub make_packet {
 269   my $type = shift;
 270   my $body = shift;
 271   my $options = shift;
 272
 273   my $len = length($body);
 274   my $pseudolen = $len;
 275
 276   # if the caller wants to use at least N octets of packet length,
 277   # pretend that we're using that many.
 278   if (defined $options && defined $options->{'packet_length'}) {
 279       $pseudolen = 2**($options->{'packet_length'} * 8) - 1;
 280   }
 281   if ($pseudolen < $len) {
 282       $pseudolen = $len;
 283   }
 284
 285   my $lenbytes;
 286   my $lencode;
 287
 288   if ($pseudolen < 2**8) {
 289     $lenbytes = $old_format_packet_lengths->{one};
 290     $lencode = 'C';
 291   } elsif ($pseudolen < 2**16) {
 292     $lenbytes = $old_format_packet_lengths->{two};
 293     $lencode = 'n';
 294   } elsif ($pseudolen < 2**31) {
 295     ## not testing against full 32 bits because i don't want to deal
 296     ## with potential overflow.
 297     $lenbytes = $old_format_packet_lengths->{four};
 298     $lencode = 'N';
 299   } else {
 300     ## what the hell do we do here?
 301     $lenbytes = $old_format_packet_lengths->{indeterminate};
 302     $lencode = '';
 303   }
 304
 305   return pack('C'.$lencode, 0x80 + ($type * 4) + $lenbytes, $len).
 306     $body;
 307 }
 308
 309
 310 # takes a Crypt::OpenSSL::Bignum, returns it formatted as OpenPGP MPI
 311 # (RFC 4880 section 3.2)
 312 sub mpi_pack {
 313   my $num = shift;
 314
 315   my $val = $num->to_bin();
 316   my $mpilen = length($val)*8;
 317
 318 # this is a kludgy way to get the number of significant bits in the
 319 # first byte:
 320   my $bitsinfirstbyte = length(sprintf("%b", ord($val)));
 321
 322   $mpilen -= (8 - $bitsinfirstbyte);
 323
 324   return pack('n', $mpilen).$val;
 325 }
 326
 327 # takes a Crypt::OpenSSL::Bignum, returns an MPI packed in preparation
 328 # for an OpenSSH-style public key format.  see:
 329 # http://marc.info/?l=openssh-unix-dev&m=121866301718839&w=2
 330 sub openssh_mpi_pack {
 331   my $num = shift;
 332
 333   my $val = $num->to_bin();
 334   my $mpilen = length($val);
 335
 336   my $ret = pack('N', $mpilen);
 337
 338   # if the first bit of the leading byte is high, we should include a
 339   # 0 byte:
 340   if (ord($val) & 0x80) {
 341     $ret = pack('NC', $mpilen+1, 0);
 342   }
 343
 344   return $ret.$val;
 345 }
 346
 347 sub openssh_pubkey_pack {
 348   my $key = shift;
 349
 350   my ($modulus, $exponent) = $key->get_key_parameters();
 351
 352   return openssh_mpi_pack(Crypt::OpenSSL::Bignum->new_from_bin("ssh-rsa")).
 353       openssh_mpi_pack($exponent).
 354         openssh_mpi_pack($modulus);
 355 }
 356
 357 # pull an OpenPGP-specified MPI off of a given stream, returning it as
 358 # a Crypt::OpenSSL::Bignum.
 359 sub read_mpi {
 360   my $instr = shift;
 361   my $readtally = shift;
 362
 363   my $bitlen;
 364   read($instr, $bitlen, 2) or die "could not read MPI length.\n";
 365   $bitlen = unpack('n', $bitlen);
 366   $$readtally += 2;
 367
 368   my $bytestoread = POSIX::floor(($bitlen + 7)/8);
 369   my $ret;
 370   read($instr, $ret, $bytestoread) or die "could not read MPI body.\n";
 371   $$readtally += $bytestoread;
 372   return Crypt::OpenSSL::Bignum->new_from_bin($ret);
 373 }
 374
 375
 376 # FIXME: genericize these to accept either RSA or DSA keys:
 377 sub make_rsa_pub_key_body {
 378   my $key = shift;
 379   my $key_timestamp = shift;
 380
 381   my ($n, $e) = $key->get_key_parameters();
 382
 383   return
 384     pack('CN', 4, $key_timestamp).
 385       pack('C', $asym_algos->{rsa}).
 386         mpi_pack($n).
 387           mpi_pack($e);
 388 }
 389
 390 sub make_rsa_sec_key_body {
 391   my $key = shift;
 392   my $key_timestamp = shift;
 393
 394   # we're not using $a and $b, but we need them to get to $c.
 395   my ($n, $e, $d, $p, $q) = $key->get_key_parameters();
 396
 397   my $c3 = modular_multi_inverse($p, $q);
 398
 399   my $secret_material = mpi_pack($d).
 400     mpi_pack($p).
 401       mpi_pack($q).
 402         mpi_pack($c3);
 403
 404   # according to Crypt::OpenSSL::RSA, the closest value we can get out
 405   # of get_key_parameters is 1/q mod p; but according to sec 5.5.3 of
 406   # RFC 4880, we're actually looking for u, the multiplicative inverse
 407   # of p, mod q.  This is why we're calculating the value directly
 408   # with modular_multi_inverse.
 409
 410   return
 411     pack('CN', 4, $key_timestamp).
 412       pack('C', $asym_algos->{rsa}).
 413         mpi_pack($n).
 414           mpi_pack($e).
 415             pack('C', 0). # seckey material is not encrypted -- see RFC 4880 sec 5.5.3
 416               $secret_material.
 417                 pack('n', simple_checksum($secret_material));
 418 }
 419
 420 # expects an RSA key (public or private) and a timestamp
 421 sub fingerprint {
 422   my $key = shift;
 423   my $key_timestamp = shift;
 424
 425   my $rsabody = make_rsa_pub_key_body($key, $key_timestamp);
 426
 427   return Digest::SHA::sha1(pack('Cn', 0x99, length($rsabody)).$rsabody);
 428 }
 429
 430
 431 # FIXME: handle DSA keys as well!
 432 sub makeselfsig {
 433   my $rsa = shift;
 434   my $uid = shift;
 435   my $args = shift;
 436
 437   # strong assertion of identity is the default (for a self-sig):
 438   if (! defined $args->{certification_type}) {
 439     $args->{certification_type} = $sig_types->{positive_certification};
 440   }
 441
 442   if (! defined $args->{sig_timestamp}) {
 443     $args->{sig_timestamp} = time();
 444   }
 445   my $key_timestamp = $args->{key_timestamp} + 0;
 446
 447   # generate and aggregate subpackets:
 448
 449   # key usage flags:
 450   my $flags = 0;
 451   if (! defined $args->{usage_flags}) {
 452     $flags = $usage_flags->{certify};
 453   } else {
 454     my @ff = split(",", $args->{usage_flags});
 455     foreach my $f (@ff) {
 456       if (! defined $usage_flags->{$f}) {
 457         die "No such flag $f";
 458       }
 459       $flags |= $usage_flags->{$f};
 460     }
 461   }
 462   my $usage_subpacket = pack('CCC', 2, $subpacket_types->{usage_flags}, $flags);
 463
 464   # how should we determine how far off to set the expiration date?
 465   # default is no expiration.  Specify the timestamp in seconds from the
 466   # key creation.
 467   my $expiration_subpacket = '';
 468   if (defined $args->{expiration}) {
 469     my $expires_in = $args->{expiration} + 0;
 470     $expiration_subpacket = pack('CCN', 5, $subpacket_types->{key_expiration_time}, $expires_in);
 471   }
 472
 473
 474   # prefer AES-256, AES-192, AES-128, CAST5, 3DES:
 475   my $pref_sym_algos = pack('CCCCCCC', 6, $subpacket_types->{preferred_cipher},
 476                             $ciphers->{aes256},
 477                             $ciphers->{aes192},
 478                             $ciphers->{aes128},
 479                             $ciphers->{cast5},
 480                             $ciphers->{tripledes}
 481                            );
 482
 483   # prefer SHA-512, SHA-384, SHA-256, SHA-224, RIPE-MD/160, SHA-1
 484   my $pref_hash_algos = pack('CCCCCCCC', 7, $subpacket_types->{preferred_digest},
 485                              $digests->{sha512},
 486                              $digests->{sha384},
 487                              $digests->{sha256},
 488                              $digests->{sha224},
 489                              $digests->{ripemd160},
 490                              $digests->{sha1}
 491                             );
 492
 493   # prefer ZLIB, BZip2, ZIP
 494   my $pref_zip_algos = pack('CCCCC', 4, $subpacket_types->{preferred_compression},
 495                             $zips->{zlib},
 496                             $zips->{bzip2},
 497                             $zips->{zip}
 498                            );
 499
 500   # we support the MDC feature:
 501   my $feature_subpacket = pack('CCC', 2, $subpacket_types->{features},
 502                                $features->{mdc});
 503
 504   # keyserver preference: only owner modify (???):
 505   my $keyserver_pref = pack('CCC', 2, $subpacket_types->{keyserver_prefs},
 506                             $keyserver_prefs->{nomodify});
 507
 508
 509   $args->{hashed_subpackets} =
 510       $usage_subpacket.
 511         $expiration_subpacket.
 512           $pref_sym_algos.
 513             $pref_hash_algos.
 514               $pref_zip_algos.
 515                 $feature_subpacket.
 516                   $keyserver_pref;
 517
 518   return gensig($rsa, $uid, $args);
 519 }
 520
 521 # FIXME: handle non-RSA keys
 522
 523 # FIXME: this currently only makes self-sigs -- we should parameterize
 524 # it to make certifications over keys other than the issuer.
 525 sub gensig {
 526   my $rsa = shift;
 527   my $uid = shift;
 528   my $args = shift;
 529
 530   # FIXME: allow signature creation using digests other than SHA256
 531   $rsa->use_sha256_hash();
 532
 533   # see page 22 of RFC 4880 for why i think this is the right padding
 534   # choice to use:
 535   $rsa->use_pkcs1_padding();
 536
 537   if (! $rsa->check_key()) {
 538     die "key does not check\n";
 539   }
 540
 541   my $certtype = $args->{certification_type} + 0;
 542
 543   my $version = pack('C', 4);
 544   my $sigtype = pack('C', $certtype);
 545   # RSA
 546   my $pubkey_algo = pack('C', $asym_algos->{rsa});
 547   # SHA256 FIXME: allow signature creation using digests other than SHA256
 548   my $hash_algo = pack('C', $digests->{sha256});
 549
 550   # FIXME: i'm worried about generating a bazillion new OpenPGP
 551   # certificates from the same key, which could easily happen if you run
 552   # this script more than once against the same key (because the
 553   # timestamps will differ).  How can we prevent this?
 554
 555   # this argument (if set) overrides the current time, to
 556   # be able to create a standard key.  If we read the key from a file
 557   # instead of stdin, should we use the creation time on the file?
 558   my $sig_timestamp = ($args->{sig_timestamp} + 0);
 559   my $key_timestamp = ($args->{key_timestamp} + 0);
 560
 561   if ($key_timestamp > $sig_timestamp) {
 562     die "key timestamp must not be later than signature timestamp\n";
 563   }
 564
 565   my $creation_time_packet = pack('CCN', 5, $subpacket_types->{sig_creation_time}, $sig_timestamp);
 566
 567   my $hashed_subs = $creation_time_packet.$args->{hashed_subpackets};
 568
 569   my $subpacket_octets = pack('n', length($hashed_subs));
 570
 571   my $sig_data_to_be_hashed =
 572     $version.
 573       $sigtype.
 574         $pubkey_algo.
 575           $hash_algo.
 576             $subpacket_octets.
 577               $hashed_subs;
 578
 579   my $pubkey = make_rsa_pub_key_body($rsa, $key_timestamp);
 580
 581   # this is for signing.  it needs to be an old-style header with a
 582   # 2-packet octet count.
 583
 584   my $key_data = make_packet($packet_types->{pubkey}, $pubkey, {'packet_length'=>2});
 585
 586   # take the last 8 bytes of the fingerprint as the keyid:
 587   my $keyid = substr(fingerprint($rsa, $key_timestamp), 20 - 8, 8);
 588
 589   # the v4 signature trailer is:
 590
 591   # version number, literal 0xff, and then a 4-byte count of the
 592   # signature data itself.
 593   my $trailer = pack('CCN', 4, 0xff, length($sig_data_to_be_hashed));
 594
 595   my $uid_data =
 596     pack('CN', 0xb4, length($uid)).
 597       $uid;
 598
 599   my $datatosign =
 600     $key_data.
 601       $uid_data.
 602         $sig_data_to_be_hashed.
 603           $trailer;
 604
 605   # FIXME: handle signatures over digests other than SHA256:
 606   my $data_hash = Digest::SHA::sha256_hex($datatosign);
 607
 608   my $issuer_packet = pack('CCa8', 9, $subpacket_types->{issuer}, $keyid);
 609
 610   my $sig = Crypt::OpenSSL::Bignum->new_from_bin($rsa->sign($datatosign));
 611
 612   my $sig_body =
 613     $sig_data_to_be_hashed.
 614       pack('n', length($issuer_packet)).
 615         $issuer_packet.
 616           pack('n', hex(substr($data_hash, 0, 4))).
 617             mpi_pack($sig);
 618
 619   return make_packet($packet_types->{sig}, $sig_body);
 620 }
 621
 622 # FIXME: switch to passing the whole packet as the arg, instead of the
 623 # input stream.
 624
 625 # FIXME: think about native perl representation of the packets instead.
 626
 627 # Put a user ID into the $data
 628 sub finduid {
 629   my $data = shift;
 630   my $instr = shift;
 631   my $tag = shift;
 632   my $packetlen = shift;
 633
 634   my $dummy;
 635   ($tag == $packet_types->{uid}) or die "This should not be called on anything but a User ID packet\n";
 636
 637   read($instr, $dummy, $packetlen);
 638   $data->{uid}->{$dummy} = {};
 639   $data->{current}->{uid} = $dummy;
 640 }
 641
 642
 643 # find signatures associated with the given fingerprint and user ID.
 644 sub findsig {
 645   my $data = shift;
 646   my $instr = shift;
 647   my $tag = shift;
 648   my $packetlen = shift;
 649
 650   ($tag == $packet_types->{sig}) or die "No calling findsig on anything other than a signature packet.\n";
 651
 652   my $dummy;
 653   my $readbytes = 0;
 654
 655   read($instr, $dummy, $packetlen - $readbytes) or die "Could not read in this packet.\n";
 656
 657   if ((! defined $data->{key}) ||
 658       (! defined $data->{uid}) ||
 659       (! defined $data->{uid}->{$data->{target}->{uid}})) {
 660     # the user ID we are looking for has not been found yet.
 661     return;
 662   }
 663
 664   # FIXME: if we get two primary keys on stdin, both with the same
 665   # targetd user ID, we'll store signatures from both keys, which is
 666   # probably wrong.
 667
 668   # the current ID is not what we're looking for:
 669   return if ($data->{current}->{uid} ne $data->{target}->{uid});
 670
 671   # just storing the raw signatures for the moment:
 672   push @{$data->{sigs}}, make_packet($packet_types->{sig}, $dummy);
 673   return;
 674
 675 }
 676
 677 # given an input stream and data, store the found key in data and
 678 # consume the rest of the stream corresponding to the packet.
 679 # data contains: (fpr: fingerprint to find, key: current best guess at key)
 680 sub findkey {
 681   my $data = shift;
 682   my $instr = shift;
 683   my $tag = shift;
 684   my $packetlen = shift;
 685
 686   my $dummy;
 687   my $ver;
 688   my $readbytes = 0;
 689
 690   read($instr, $ver, 1) or die "could not read key version\n";
 691   $readbytes += 1;
 692   $ver = ord($ver);
 693
 694   if ($ver != 4) {
 695     printf(STDERR "We only work with version 4 keys.  This key appears to be version %s.\n", $ver);
 696     read($instr, $dummy, $packetlen - $readbytes) or die "Could not skip past this packet.\n";
 697     return;
 698   }
 699
 700   my $key_timestamp;
 701   read($instr, $key_timestamp, 4) or die "could not read key timestamp.\n";
 702   $readbytes += 4;
 703   $key_timestamp = unpack('N', $key_timestamp);
 704
 705   my $algo;
 706   read($instr, $algo, 1) or die "could not read key algorithm.\n";
 707   $readbytes += 1;
 708   $algo = ord($algo);
 709   if ($algo != $asym_algos->{rsa}) {
 710     printf(STDERR "We only support RSA keys (this key used algorithm %d).\n", $algo);
 711     read($instr, $dummy, $packetlen - $readbytes) or die "Could not skip past this packet.\n";
 712     return;
 713   }
 714
 715   ## we have an RSA key.
 716   my $modulus = read_mpi($instr, \$readbytes);
 717   my $exponent = read_mpi($instr, \$readbytes);
 718
 719   my $pubkey = Crypt::OpenSSL::RSA->new_key_from_parameters($modulus, $exponent);
 720   my $foundfpr = fingerprint($pubkey, $key_timestamp);
 721
 722   my $foundfprstr = Crypt::OpenSSL::Bignum->new_from_bin($foundfpr)->to_hex();
 723   # left-pad with 0's to bring up to full 40-char (160-bit) fingerprint:
 724   $foundfprstr = sprintf("%040s", $foundfprstr);
 725   my $matched = 0;
 726
 727   # is this a match?
 728   if ((!defined($data->{target}->{fpr})) ||
 729       (substr($foundfprstr, -1 * length($data->{target}->{fpr})) eq $data->{target}->{fpr})) {
 730     if (defined($data->{key})) {
 731       die "Found two matching keys.\n";
 732     }
 733     $data->{key} = { 'rsa' => $pubkey,
 734                      'timestamp' => $key_timestamp };
 735     $matched = 1;
 736   }
 737
 738   if ($tag != $packet_types->{seckey} &&
 739       $tag != $packet_types->{sec_subkey}) {
 740     if ($readbytes < $packetlen) {
 741       read($instr, $dummy, $packetlen - $readbytes) or die "Could not skip past this packet.\n";
 742     }
 743     return;
 744   }
 745   if (!$matched) {
 746     # we don't think the public part of this key matches
 747     if ($readbytes < $packetlen) {
 748       read($instr, $dummy, $packetlen - $readbytes) or die "Could not skip past this packet.\n";
 749     }
 750     return;
 751   }
 752
 753   my $s2k;
 754   read($instr, $s2k, 1) or die "Could not read S2K octet.\n";
 755   $readbytes += 1;
 756   $s2k = ord($s2k);
 757   if ($s2k != 0) {
 758     printf(STDERR "We cannot handle encrypted secret keys.  Skipping!\n") ;
 759     read($instr, $dummy, $packetlen - $readbytes) or die "Could not skip past this packet.\n";
 760     return;
 761   }
 762
 763   # secret material is unencrypted
 764   # see http://tools.ietf.org/html/rfc4880#section-5.5.3
 765   my $d = read_mpi($instr, \$readbytes);
 766   my $p = read_mpi($instr, \$readbytes);
 767   my $q = read_mpi($instr, \$readbytes);
 768   my $u = read_mpi($instr, \$readbytes);
 769
 770   my $checksum;
 771   read($instr, $checksum, 2) or die "Could not read checksum of secret key material.\n";
 772   $readbytes += 2;
 773   $checksum = unpack('n', $checksum);
 774
 775   # FIXME: compare with the checksum!  how?  the data is
 776   # gone into the Crypt::OpenSSL::Bignum
 777
 778   $data->{key}->{rsa} = Crypt::OpenSSL::RSA->new_key_from_parameters($modulus,
 779                                                                      $exponent,
 780                                                                      $d,
 781                                                                      $p,
 782                                                                      $q);
 783
 784   $data->{key}->{rsa}->check_key() or die "Secret key is not a valid RSA key.\n";
 785
 786   if ($readbytes < $packetlen) {
 787     read($instr, $dummy, $packetlen - $readbytes) or die "Could not skip past this packet.\n";
 788   }
 789 }
 790
 791 sub openpgp2rsa {
 792   my $instr = shift;
 793   my $fpr = shift;
 794
 795   if (defined $fpr) {
 796     if (length($fpr) < 8) {
 797       die "We need at least 8 hex digits of fingerprint.\n";
 798     }
 799     $fpr = uc($fpr);
 800   }
 801
 802   my $data = { target => { fpr => $fpr,
 803                          },
 804                };
 805   my $subs = { $packet_types->{pubkey} => \&findkey,
 806                $packet_types->{pub_subkey} => \&findkey,
 807                $packet_types->{seckey} => \&findkey,
 808                $packet_types->{sec_subkey} => \&findkey };
 809
 810   packetwalk($instr, $subs, $data);
 811
 812   return $data->{key}->{rsa};
 813 }
 814
 815 sub findkeyfprs {
 816   my $data = shift;
 817   my $instr = shift;
 818   my $tag = shift;
 819   my $packetlen = shift;
 820
 821   findkey($data, $instr, $tag, $packetlen);
 822   if (defined($data->{key})) {
 823     if (defined($data->{key}->{rsa}) && defined($data->{key}->{timestamp})) {
 824       $data->{keys}->{fingerprint($data->{key}->{rsa}, $data->{key}->{timestamp})} = $data->{key};
 825     } else {
 826       die "should have found some key here";
 827     }
 828     undef($data->{key});
 829   }
 830 };
 831
 832 sub getallprimarykeys {
 833   my $instr = shift;
 834
 835   my $subs = { $packet_types->{pubkey} => \&findkeyfprs,
 836                $packet_types->{seckey} => \&findkeyfprs,
 837              };
 838   my $data = {target => { } };
 839
 840   packetwalk($instr, $subs, $data);
 841
 842   if (defined $data->{keys}) {
 843     return $data->{keys};
 844   } else {
 845     return {};
 846   }
 847 }
 848
 849 sub adduserid {
 850   my $instr = shift;
 851   my $fpr = shift;
 852   my $uid = shift;
 853   my $args = shift;
 854
 855   if ((! defined $fpr) ||
 856       (length($fpr) < 8)) {
 857     die "We need at least 8 hex digits of fingerprint.\n";
 858   }
 859
 860   $fpr = uc($fpr);
 861
 862   if (! defined $uid) {
 863     die "No User ID defined.\n";
 864   }
 865
 866   my $data = { target => { fpr => $fpr,
 867                            uid => $uid,
 868                          },
 869              };
 870   my $subs = { $packet_types->{seckey} => \&findkey,
 871                $packet_types->{uid} => \&finduid,
 872                $packet_types->{sig} => \&findsig,
 873              };
 874
 875   packetwalk($instr, $subs, $data);
 876
 877   if ((! defined $data->{key}) ||
 878       (! defined $data->{key}->{rsa}) ||
 879       (! defined $data->{key}->{timestamp})) {
 880     die "The key requested was not found.\n"
 881   }
 882
 883   if (defined $data->{uid}->{$uid}) {
 884     die "The requested User ID '$uid' is already associated with this key.\n";
 885   }
 886   $args->{key_timestamp} = $data->{key}->{timestamp};
 887
 888   return
 889     make_packet($packet_types->{pubkey}, make_rsa_pub_key_body($data->{key}->{rsa}, $data->{key}->{timestamp})).
 890       make_packet($packet_types->{uid}, $uid).
 891         makeselfsig($data->{key}->{rsa},
 892                     $uid,
 893                     $args);
 894
 895 }
 896
 897
 898 sub revokeuserid {
 899   my $instr = shift;
 900   my $fpr = shift;
 901   my $uid = shift;
 902   my $sigtime = shift;
 903
 904   if ((! defined $fpr) ||
 905       (length($fpr) < 8)) {
 906     die "We need at least 8 hex digits of fingerprint.\n";
 907   }
 908
 909   $fpr = uc($fpr);
 910
 911   if (! defined $uid) {
 912     die "No User ID defined.\n";
 913   }
 914
 915   my $data = { target => { fpr => $fpr,
 916                            uid => $uid,
 917                          },
 918              };
 919   my $subs = { $packet_types->{seckey} => \&findkey,
 920                $packet_types->{uid} => \&finduid,
 921                $packet_types->{sig} => \&findsig,
 922              };
 923
 924   packetwalk($instr, $subs, $data);
 925
 926   if ((! defined $data->{uid}) ||
 927       (! defined $data->{uid}->{$uid})) {
 928     die "The User ID \"$uid\" is not associated with this key";
 929   }
 930
 931   if ((! defined $data->{key}) ||
 932       (! defined $data->{key}->{rsa}) ||
 933       (! defined $data->{key}->{timestamp})) {
 934     die "The key requested was not found."
 935   }
 936
 937   my $revocation_reason = 'No longer using this hostname';
 938   if (defined $data->{revocation_reason}) {
 939     $revocation_reason = $data->{revocation_reason};
 940   }
 941
 942   my $rev_reason_subpkt = prefixsubpacket(pack('CC',
 943                                                $subpacket_types->{revocation_reason},
 944                                                $revocation_reasons->{user_id_no_longer_valid}).
 945                                           $revocation_reason);
 946
 947   if (! defined $sigtime) {
 948     $sigtime = time();
 949   }
 950   # what does a signature like this look like?
 951   my $args = { key_timestamp => $data->{key}->{timestamp},
 952                sig_timestamp => $sigtime,
 953                certification_type => $sig_types->{certification_revocation},
 954                hashed_subpackets => $rev_reason_subpkt,
 955              };
 956
 957   return
 958     make_packet($packet_types->{pubkey}, make_rsa_pub_key_body($data->{key}->{rsa}, $data->{key}->{timestamp})).
 959       make_packet($packet_types->{uid}, $uid).
 960         join('', @{$data->{sigs}}).
 961           gensig($data->{key}->{rsa}, $uid, $args);
 962 }
 963
 964
 965 # see 5.2.3.1 for tips on how to calculate the length of a subpacket:
 966 sub prefixsubpacket {
 967   my $subpacket = shift;
 968
 969   my $len = length($subpacket);
 970   my $prefix;
 971   use bytes;
 972   if ($len < 192) {
 973     # one byte:
 974     $prefix = pack('C', $len);
 975   } elsif ($len < 16576) {
 976     my $in = $len - 192;
 977     my $second = $in%256;
 978     my $first = ($in - $second)>>8;
 979     $prefix = pack('CC', $first + 192, $second)
 980   } else {
 981     $prefix = pack('CN', 255, $len);
 982   }
 983   return $prefix.$subpacket;
 984 }
 985
 986
 987
 988 sub packetwalk {
 989   my $instr = shift;
 990   my $subs = shift;
 991   my $data = shift;
 992
 993   my $packettag;
 994   my $dummy;
 995   my $tag;
 996
 997   while (! eof($instr)) {
 998     read($instr, $packettag, 1);
 999     $packettag = ord($packettag);
1000
1001     my $packetlen;
1002     if ( ! (0x80 & $packettag)) {
1003       die "This is not an OpenPGP packet\n";
1004     }
1005     if (0x40 & $packettag) {
1006       # this is a new-format packet.
1007       $tag = (0x3f & $packettag);
1008       my $nextlen = 0;
1009       read($instr, $nextlen, 1);
1010       $nextlen = ord($nextlen);
1011       if ($nextlen < 192) {
1012         $packetlen = $nextlen;
1013       } elsif ($nextlen < 224) {
1014         my $newoct;
1015         read($instr, $newoct, 1);
1016         $newoct = ord($newoct);
1017         $packetlen = (($nextlen - 192) << 8) + ($newoct) + 192;
1018       } elsif ($nextlen == 255) {
1019         read($instr, $nextlen, 4);
1020         $packetlen = unpack('N', $nextlen);
1021       } else {
1022         # packet length is undefined.
1023       }
1024     } else {
1025       # this is an old-format packet.
1026       my $lentype;
1027       $lentype = 0x03 & $packettag;
1028       $tag = ( 0x3c & $packettag ) >> 2;
1029       if ($lentype == 0) {
1030         read($instr, $packetlen, 1) or die "could not read packet length\n";
1031         $packetlen = unpack('C', $packetlen);
1032       } elsif ($lentype == 1) {
1033         read($instr, $packetlen, 2) or die "could not read packet length\n";
1034         $packetlen = unpack('n', $packetlen);
1035       } elsif ($lentype == 2) {
1036         read($instr, $packetlen, 4) or die "could not read packet length\n";
1037         $packetlen = unpack('N', $packetlen);
1038       } else {
1039         # packet length is undefined.
1040       }
1041     }
1042
1043     if (! defined($packetlen)) {
1044       die "Undefined packet lengths are not supported.\n";
1045     }
1046
1047     if (defined $subs->{$tag}) {
1048       $subs->{$tag}($data, $instr, $tag, $packetlen);
1049     } else {
1050       read($instr, $dummy, $packetlen) or die "Could not skip past this packet!\n";
1051     }
1052   }
1053
1054   return $data->{key};
1055 }
1056
1057
1058 for (basename($0)) {
1059   if (/^pem2openpgp$/) {
1060     my $rsa;
1061     my $stdin;
1062
1063     my $uid = shift;
1064     defined($uid) or die "You must specify a user ID string.\n";
1065
1066     # FIXME: fail if there is no given user ID; or should we default to
1067     # hostname_long() from Sys::Hostname::Long ?
1068
1069     if (defined $ENV{PEM2OPENPGP_NEWKEY}) {
1070       $rsa = Crypt::OpenSSL::RSA->generate_key($ENV{PEM2OPENPGP_NEWKEY});
1071     } else {
1072       $stdin = do {
1073         local $/; # slurp!
1074         <STDIN>;
1075       };
1076
1077       $rsa = Crypt::OpenSSL::RSA->new_private_key($stdin);
1078     }
1079
1080     my $key_timestamp = $ENV{PEM2OPENPGP_KEY_TIMESTAMP};
1081     my $sig_timestamp = $ENV{PEM2OPENPGP_TIMESTAMP};
1082     $sig_timestamp = time() if (!defined $sig_timestamp);
1083     $key_timestamp = $sig_timestamp if (!defined $key_timestamp);
1084
1085     print
1086       make_packet($packet_types->{seckey}, make_rsa_sec_key_body($rsa, $key_timestamp)).
1087         make_packet($packet_types->{uid}, $uid).
1088           makeselfsig($rsa,
1089                       $uid,
1090                       { sig_timestamp => $sig_timestamp,
1091                         key_timestamp => $key_timestamp,
1092                         expiration => $ENV{PEM2OPENPGP_EXPIRATION},
1093                         usage_flags => $ENV{PEM2OPENPGP_USAGE_FLAGS},
1094                       }
1095                      );
1096   }
1097   elsif (/^openpgp2ssh$/) {
1098       my $fpr = shift;
1099       my $instream;
1100       open($instream,'-');
1101       binmode($instream, ":bytes");
1102       my $key = openpgp2rsa($instream, $fpr);
1103       if (defined($key)) {
1104         if ($key->is_private()) {
1105           print $key->get_private_key_string();
1106         } else {
1107           print "ssh-rsa ".encode_base64(openssh_pubkey_pack($key), '')."\n";
1108         }
1109       } else {
1110         die "No matching key found.\n";
1111       }
1112   }
1113   elsif (/^keytrans$/) {
1114     # subcommands when keytrans is invoked directly are UNSUPPORTED,
1115     # UNDOCUMENTED, and WILL NOT BE MAINTAINED.
1116     my $subcommand = shift;
1117     for ($subcommand) {
1118       if (/^revokeuserid$/) {
1119         my $fpr = shift;
1120         my $uid = shift;
1121         my $instream;
1122         open($instream,'-');
1123         binmode($instream, ":bytes");
1124
1125         my $revcert = revokeuserid($instream, $fpr, $uid, $ENV{PEM2OPENPGP_TIMESTAMP});
1126
1127         print $revcert;
1128       } elsif (/^adduserid$/) {
1129         my $fpr = shift;
1130         my $uid = shift;
1131         my $instream;
1132         open($instream,'-');
1133         binmode($instream, ":bytes");
1134         my $newuid = adduserid($instream, $fpr, $uid,
1135                                { sig_timestamp => $ENV{PEM2OPENPGP_TIMESTAMP},
1136                                  expiration => $ENV{PEM2OPENPGP_EXPIRATION},
1137                                  usage_flags => $ENV{PEM2OPENPGP_USAGE_FLAGS},
1138                                });
1139
1140         print $newuid;
1141       } elsif (/^listfprs$/) {
1142         my $instream;
1143         open($instream,'-');
1144         binmode($instream, ":bytes");
1145         my $keys = getallprimarykeys($instream);
1146         printf("%s\n", join("\n", map { uc(unpack('H*', $_)) } keys(%{$keys})));
1147       } elsif (/^openpgp2sshfpr$/) {
1148         my $fpr = shift;
1149         my $instream;
1150         open($instream,'-');
1151         binmode($instream, ":bytes");
1152         my $key = openpgp2rsa($instream, $fpr);
1153         if (defined($key)) {
1154           # openssh uses MD5 for key fingerprints:
1155           use Digest::MD5;
1156           printf("%d %s %s\n",
1157                  $key->size() * 8, # size() is in bytes -- we want bits
1158                  join(':', map({unpack("H*", $_)} split(//, Digest::MD5::md5(openssh_pubkey_pack($key))))),
1159                  '(RSA)', # FIXME when we support other than RSA.
1160                 );
1161         } else {
1162           die "No matching key found.\n";
1163         }
1164       } else {
1165         die "Unrecognized subcommand.  keytrans subcommands are not a stable interface!\n";
1166       }
1167     }
1168   }
1169   else {
1170     die "Unrecognized keytrans call.\n";
1171   }
1172 }
1173