msva-query-agent

   1 #!/usr/bin/perl -wT
   2
   3 # Monkeysphere Validation Agent Client, Perl version
   4 # Copyright © 2010 Jameson Greaf Rollins <jrollins@finestructure.net>
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 use warnings;
  20 use strict;
  21
  22 use Crypt::Monkeysphere::MSVA::Client;
  23
  24 sub usage {
  25   my $name = shift;
  26
  27   printf STDERR ("Usage: %s CONTEXT PEER PKC_TYPE [PEER_TYPE] < PKC_DATA
  28        %s CONTEXT PEER PKC_TYPE PEER_TYPE PKC_DATA
  29        %s --version
  30 ", $name, $name, $name);
  31 }
  32
  33 my $context = shift;
  34 if ((!defined($context)) ||
  35     $context eq '--help') {
  36   usage($0);
  37   exit (defined($context) ? 0 : 1);
  38 } elsif ($context eq '--version') {
  39   my $client = Crypt::Monkeysphere::MSVA::Client->new(
  40                                                       socket => $ENV{MONKEYSPHERE_VALIDATION_AGENT_SOCKET},
  41                                                       log_level => $ENV{MSVA_LOG_LEVEL},
  42                                                      );
  43   my ($status,$ret) = $client->agent_info();
  44   $client->log('verbose', "status: %s\n", $status);
  45   if (defined $ret) {
  46     printf("%s", $ret->{server});
  47     exit 0;
  48   }
  49   exit 1;
  50 }
  51
  52 my $peer = shift;
  53 my $pkctype = shift;
  54 my $peertype = shift;
  55 my $pkcdata = shift;
  56
  57 if (!defined $pkcdata) {
  58   # load raw pkc data from stdin
  59   $pkcdata = do {
  60     local $/; # slurp!
  61     <STDIN>;
  62   };
  63 }
  64
  65 my $client = Crypt::Monkeysphere::MSVA::Client->new(
  66                                                     socket => $ENV{MONKEYSPHERE_VALIDATION_AGENT_SOCKET},
  67                                                     log_level => $ENV{MSVA_LOG_LEVEL},
  68                                                    );
  69
  70 my ($status,$ret) = $client->query_agent($context,$peer,$peertype,$pkctype,$pkcdata);
  71
  72 $client->log('verbose', "status: %s\n", $status);
  73 if (defined $ret) {
  74   $client->log('info', "valid: %s\n", $ret->{valid});
  75   $client->log('info', "server: %s\n", $ret->{server});
  76   printf("%s", $ret->{message});
  77   exit 0
  78     if ($ret->{valid});
  79 }
  80 exit 1;
  81
  82 __END__
  83
  84 =head1 NAME
  85
  86 msva-query-agent - query a Monkeysphere Validation Agent
  87
  88 =head1 SYNOPSIS
  89
  90 msva-query-agent CONTEXT PEER PKC_TYPE [PEER_TYPE] < /path/to/public_key_carrier
  91
  92 msva-query-agent CONTEXT PEER PKC_TYPE PEER_TYPE PKC_DATA
  93
  94 msva-query-agent --version
  95
  96 =head1 ABSTRACT
  97
  98 msva-query-agent validates certificates for a given use by querying a
  99 running Monkeysphere Validation Agent.
 100
 101 =head1 USAGE
 102
 103 msva-query-agent reads a certificate from standard input, and posts it
 104 to the running Monkeysphere Validation Agent.  The return code
 105 indicates the validity (as determined by the agent) of the certificate
 106 for the specified purpose.  The agent's return message (if any) is
 107 emitted on stdout.
 108
 109 The various arguments are:
 110
 111 =over 4
 112
 113 =item CONTEXT
 114
 115 Context in which the certificate is being validated (e.g. 'https',
 116 'ssh', 'ike')
 117
 118 =item PEER
 119
 120 The name of the intended peer.  When validating a certificate for a
 121 service, supply the host's full DNS name (e.g.  'foo.example.net')
 122
 123 =item PKC_TYPE
 124
 125 The format of public key carrier data provided on standard input
 126 (e.g. 'x509der', 'x509pem', 'opensshpubkey', 'rfc4716', 'openpgp4fpr')
 127
 128 =item PEER_TYPE
 129
 130 The type of peer we are inquiring about (e.g. 'client', 'server',
 131 'peer').  This argument is optional and defaults will be used (based
 132 on CONTEXT) if it is not supplied.
 133
 134 =item PKC_DATA
 135
 136 This is the actual public key carrier data itself.  If less than five
 137 arguments are given, then the PKC_DATA is expected on stdin.  If five
 138 arguments are given, the fifth argument is interpreted as the
 139 PKC_DATA.  This is likely only useful for supplying an OpenPGP
 140 fingerprint with the 'openpgp4fpr' type.
 141
 142 =back
 143
 144 =head1 RETURN CODE
 145
 146 If the certificate is valid for the requested peer in the given
 147 context, the return code is 0.  Otherwise, the return code is 1.
 148
 149 =head1 ENVIRONMENT VARIABLES
 150
 151 msva-query-agent's behavior is controlled by environment variables:
 152
 153 =over 4
 154
 155 =item MONKEYSPHERE_VALIDATION_AGENT_SOCKET
 156
 157 Socket over which to query the validation agent.  If unset, the
 158 default value is 'http://localhost:8901'.
 159
 160 =item MSVA_LOG_LEVEL
 161
 162 Log messages about its operation to stderr.  MSVA_LOG_LEVEL controls
 163 its verbosity, and should be one of (in increasing verbosity): silent,
 164 quiet, fatal, error, info, verbose, debug, debug1, debug2, debug3.
 165 Default is 'error'.
 166
 167 =back
 168
 169 =head1 COMMUNICATION PROTOCOL DETAILS
 170
 171 Communications with the Monkeysphere Validation Agent are in the form
 172 of JSON requests over plain HTTP.  Responses from the agent are also
 173 JSON objects.  For details on the structure of the requests and
 174 responses, please see
 175 http://web.monkeysphere.info/validation-agent/protocol
 176
 177 =head1 SEE ALSO
 178
 179 msva-perl(1), monkeysphere(1), monkeysphere(7)
 180
 181 =head1 BUGS AND FEEDBACK
 182
 183 Bugs or feature requests for msva-perl and associated tools should be
 184 filed with the Monkeysphere project's bug tracker at
 185 https://labs.riseup.net/code/projects/monkeysphere/issues/
 186
 187 =head1 AUTHORS AND CONTRIBUTORS
 188
 189 Jameson Graef Rollins E<lt>jrollins@finestructure.net<gt>
 190 Daniel Kahn Gillmor E<lt>dkg@fifthhorseman.net<gt>
 191
 192 The Monkeysphere Team http://web.monkeysphere.info/
 193
 194 =head1 COPYRIGHT AND LICENSE
 195
 196 Copyright © 2010, Jameson Graef Rollins and others from the Monkeysphere
 197 team.  msva-query-agent is free software, distributed under the GNU
 198 Public License, version 3 or later.