msva-query-agent

   1 #!/usr/bin/perl -wT
   2
   3 # Monkeysphere Validation Agent Client, Perl version
   4 # Copyright © 2010 Jameson Greaf Rollins <jrollins@finestructure.net>
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 use warnings;
  20 use strict;
  21
  22 use Crypt::Monkeysphere::MSVA::Client;
  23
  24 my $context = shift;
  25 if ($context eq '--help') {
  26   printf STDERR "Usage: msva-query-agent CONTEXT PEER PKC_TYPE [PEER_TYPE] <PKC_DATA\n";
  27   printf STDERR "       msva-query-agent CONTEXT PEER PKC_TYPE PEER_TYPE PKC_DATA\n";
  28   printf STDERR "       msva-query-agent --version\n";
  29   exit 0;
  30 } elsif ($context eq '--version') {
  31   my $client = Crypt::Monkeysphere::MSVA::Client->new(
  32                                                       socket => $ENV{MONKEYSPHERE_VALIDATION_AGENT_SOCKET},
  33                                                       log_level => $ENV{MSVA_LOG_LEVEL},
  34                                                      );
  35   my ($status,$ret) = $client->agent_info();
  36   $client->log('verbose', "status: %s\n", $status);
  37   if (defined $ret) {
  38     printf("%s", $ret->{server});
  39     printf("\n") if (-t STDOUT);
  40     exit 0;
  41   }
  42   exit 1;
  43 }
  44
  45 my $peer = shift;
  46 my $pkctype = shift;
  47 my $peertype = shift;
  48 my $pkcdata = shift;
  49
  50 if (!defined $pkcdata) {
  51   # load raw pkc data from stdin
  52   $pkcdata = do {
  53     local $/; # slurp!
  54     <STDIN>;
  55   };
  56 }
  57
  58 my $client = Crypt::Monkeysphere::MSVA::Client->new(
  59                                                     socket => $ENV{MONKEYSPHERE_VALIDATION_AGENT_SOCKET},
  60                                                     log_level => $ENV{MSVA_LOG_LEVEL},
  61                                                    );
  62
  63 my ($status,$ret) = $client->query_agent($context,$peer,$peertype,$pkctype,$pkcdata);
  64
  65 $client->log('verbose', "status: %s\n", $status);
  66 if (defined $ret) {
  67   $client->log('info', "valid: %s\n", $ret->{valid});
  68   $client->log('info', "server: %s\n", $ret->{server});
  69   printf("%s", $ret->{message});
  70   printf("\n") if (-t STDOUT);
  71   exit 0
  72     if ($ret->{valid});
  73 }
  74 exit 1;
  75
  76 __END__
  77
  78 =head1 NAME
  79
  80 msva-query-agent - query a Monkeysphere Validation Agent
  81
  82 =head1 SYNOPSIS
  83
  84 msva-query-agent CONTEXT PEER PKC_TYPE [PEER_TYPE] < /path/to/public_key_carrier
  85
  86 msva-query-agent CONTEXT PEER PKC_TYPE PEER_TYPE PKC_DATA
  87
  88 msva-query-agent --version
  89
  90 =head1 ABSTRACT
  91
  92 msva-query-agent validates certificates for a given use by querying a
  93 running Monkeysphere Validation Agent.
  94
  95 =head1 USAGE
  96
  97 msva-query-agent reads a certificate from standard input, and posts it
  98 to the running Monkeysphere Validation Agent.  The return code
  99 indicates the validity (as determined by the agent) of the certificate
 100 for the specified purpose.  The agent's return message (if any) is
 101 emitted on stdout.
 102
 103 The various arguments are:
 104
 105 =over 4
 106
 107 =item CONTEXT
 108
 109 Context in which the certificate is being validated (e.g. 'https',
 110 'ssh', 'ike')
 111
 112 =item PEER
 113
 114 The name of the intended peer.  When validating a certificate for a
 115 service, supply the host's full DNS name (e.g.  'foo.example.net')
 116
 117 =item PKC_TYPE
 118
 119 The format of public key carrier data provided on standard input
 120 (e.g. 'x509der', 'x509pem', 'opensshpubkey', 'rfc4716', 'openpgp4fpr')
 121
 122 =item PEER_TYPE
 123
 124 The type of peer we are inquiring about (e.g. 'client', 'server',
 125 'peer').  This argument is optional and defaults will be used (based
 126 on CONTEXT) if it is not supplied.
 127
 128 =item PKC_DATA
 129
 130 This is the actual public key carrier data itself.  If less than five
 131 arguments are given, then the PKC_DATA is expected on stdin.  If five
 132 arguments are given, the fifth argument is interpreted as the
 133 PKC_DATA.  This is likely only useful for supplying an OpenPGP
 134 fingerprint with the 'openpgp4fpr' type.
 135
 136 =back
 137
 138 =head1 RETURN CODE
 139
 140 If the certificate is valid for the requested peer in the given
 141 context, the return code is 0.  Otherwise, the return code is 1.
 142
 143 =head1 ENVIRONMENT VARIABLES
 144
 145 msva-query-agent's behavior is controlled by environment variables:
 146
 147 =over 4
 148
 149 =item MONKEYSPHERE_VALIDATION_AGENT_SOCKET
 150
 151 Socket over which to query the validation agent.  If unset, the
 152 default value is 'http://localhost:8901'.
 153
 154 =item MSVA_LOG_LEVEL
 155
 156 Log messages about its operation to stderr.  MSVA_LOG_LEVEL controls
 157 its verbosity, and should be one of (in increasing verbosity): silent,
 158 quiet, fatal, error, info, verbose, debug, debug1, debug2, debug3.
 159 Default is 'error'.
 160
 161 =back
 162
 163 =head1 COMMUNICATION PROTOCOL DETAILS
 164
 165 Communications with the Monkeysphere Validation Agent are in the form
 166 of JSON requests over plain HTTP.  Responses from the agent are also
 167 JSON objects.  For details on the structure of the requests and
 168 responses, please see
 169 http://web.monkeysphere.info/validation-agent/protocol
 170
 171 =head1 SEE ALSO
 172
 173 msva-perl(1), monkeysphere(1), monkeysphere(7)
 174
 175 =head1 BUGS AND FEEDBACK
 176
 177 Bugs or feature requests for msva-perl and associated tools should be
 178 filed with the Monkeysphere project's bug tracker at
 179 https://labs.riseup.net/code/projects/monkeysphere/issues/
 180
 181 =head1 AUTHORS AND CONTRIBUTORS
 182
 183 Jameson Graef Rollins E<lt>jrollins@finestructure.net<gt>
 184 Daniel Kahn Gillmor E<lt>dkg@fifthhorseman.net<gt>
 185
 186 The Monkeysphere Team http://web.monkeysphere.info/
 187
 188 =head1 COPYRIGHT AND LICENSE
 189
 190 Copyright © 2010, Jameson Graef Rollins and others from the Monkeysphere
 191 team.  msva-query-agent is free software, distributed under the GNU
 192 Public License, version 3 or later.