net-libs/libwebsockets: version bump to 4.0.7

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Jakov Smolic <jakov.smolic@sartura.hr>
Signed-off-by: Luka Perkov <luka.perkov@sartura.hr>
Acked-by: Jaco Kroon <jaco@uls.co.za>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

diff --git a/net-libs/libwebsockets/Manifest b/net-libs/libwebsockets/Manifest
index 5372f552d6c123a8d6bc4936f8b5ed4ccae1a4bd..08b1f983771baba4479e7c30b3b973fc6c3545cf 100644 (file)
--- a/net-libs/libwebsockets/Manifest
+++ b/net-libs/libwebsockets/Manifest
@@ -1,2 +1,3 @@
 DIST libwebsockets-3.2.1.tar.gz 9868342 BLAKE2B d822552c611f7cd0ee416bf9b9576c6052e196c1aa68b12c46a00865d3dcd131840218394317f191485fc61d8f3b7654d4a652a47f11d279a555522df84a2350 SHA512 a2d30a7a0416a26484743efdaa8635542480a74b0ef0f6e172dab5de4688486efb13457fc8a884d9916f76322cab0cbc9ab675f496558edd1dd9b833d087207d
 DIST libwebsockets-4.0.1.tar.gz 12332611 BLAKE2B bc5aaede801b61c389928b41e091a7b84fb24a73a64aa3dc2ba7a1370e146f5c98ede9489ed81fd274884c772de3fa93a9f5b7e3c88be4e28c092a045b7d5e72 SHA512 33eced9690e54106afb63ac58eb25b1eefd7998074d042209c97177f95c14c4aa97c41303918d7b0649863865d85d9579693762b8215df54879621778ffabdf4
+DIST libwebsockets-4.0.7.tar.gz 12337469 BLAKE2B 0ca58050e60afb4fcb349a8035afa629fb2d4645d7413cbaf7f1cf6cae8c5606de2aa72f1dc78778ba00c0fe723dd4aab55cd03c0a96122a1e4ff7d3cdf66644 SHA512 14b2f762db220fd6003d04c05566786b292913bfc71667327b17e8a357f4a7b5b0a09f246fc9ed527f7db106586c567345200120d32428183d39e16ae5a6287e

diff --git a/net-libs/libwebsockets/libwebsockets-4.0.7.ebuild b/net-libs/libwebsockets/libwebsockets-4.0.7.ebuild
new file mode 100644 (file)
index 0000000..7620aaa
--- /dev/null
+++ b/net-libs/libwebsockets/libwebsockets-4.0.7.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="A flexible pure-C library for implementing network protocols"
+HOMEPAGE="https://libwebsockets.org/"
+SRC_URI="https://github.com/warmcat/libwebsockets/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/16" # libwebsockets.so.16
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="access-log caps cgi client dbus generic-sessions http-proxy http2 ipv6
+       +lejp libev libevent libressl libuv peer-limits server-status smtp socks5
+       sqlite3 ssl static-libs threads zip"
+
+REQUIRED_USE="
+       generic-sessions? ( smtp sqlite3 )
+       http-proxy? ( client )
+       smtp? ( libuv )
+       ?? ( libev libevent )
+"
+
+RDEPEND="
+       sys-libs/zlib
+       caps? ( sys-libs/libcap )
+       http-proxy? ( net-libs/libhubbub )
+       libev? ( dev-libs/libev )
+       libevent? ( dev-libs/libevent:= )
+       libuv? ( dev-libs/libuv:= )
+       sqlite3? ( dev-db/sqlite:= )
+       ssl? (
+               !libressl? ( dev-libs/openssl:0= )
+               libressl?  ( dev-libs/libressl:0= )
+       )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl"
+
+PATCHES=(
+       "${FILESDIR}/libwebsockets-3.2.0-check_chown_result.patch"
+)
+
+src_configure() {
+       local mycmakeargs=(
+               -DCMAKE_DISABLE_FIND_PACKAGE_Git=ON
+               -DLWS_HAVE_LIBCAP=$(usex caps)
+               -DLWS_IPV6=$(usex ipv6)
+               -DLWS_ROLE_DBUS=$(usex dbus)
+               -DLWS_WITHOUT_CLIENT=$(usex !client)
+               -DLWS_WITHOUT_TEST_CLIENT=$(usex !client)
+               -DLWS_WITH_ACCESS_LOG=$(usex access-log)
+               -DLWS_WITH_CGI=$(usex cgi)
+               -DLWS_WITH_GENERIC_SESSIONS=$(usex generic-sessions)
+               -DLWS_WITH_HTTP2=$(usex http2)
+               -DLWS_WITH_HTTP_PROXY=$(usex http-proxy)
+               -DLWS_WITH_HUBBUB=$(usex http-proxy)
+               -DLWS_WITH_LEJP=$(usex lejp)
+               -DLWS_WITH_LIBEV=$(usex libev)
+               -DLWS_WITH_LIBEVENT=$(usex libevent)
+               -DLWS_WITH_LIBUV=$(usex libuv)
+               -DLWS_WITH_PEER_LIMITS=$(usex peer-limits)
+               -DLWS_WITH_SERVER_STATUS=$(usex server-status)
+               -DLWS_WITH_SMTP=$(usex smtp)
+               -DLWS_WITH_SOCKS5=$(usex socks5)
+               -DLWS_WITH_SQLITE3=$(usex sqlite3)
+               -DLWS_WITH_SSL=$(usex ssl)
+               -DLWS_WITH_STATIC=$(usex static-libs)
+               -DLWS_WITH_THREADPOOL=$(usex threads)
+               -DLWS_WITH_ZIP_FOPS=$(usex zip)
+               -DLWS_WITHOUT_TESTAPPS=ON
+       )
+
+       cmake_src_configure
+}