dev-util/rr: bump up to 5.3.0

Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

diff --git a/dev-util/rr/Manifest b/dev-util/rr/Manifest
index 34ad1590c2b4fcc55bffb33e1c3750175f071702..ebb74bf6e7c2717319e89e47967fb8ef546184b5 100644 (file)
--- a/dev-util/rr/Manifest
+++ b/dev-util/rr/Manifest
@@ -1 +1,2 @@
 DIST mozilla-rr-5.2.0.tar.gz 1168734 BLAKE2B 2f15c4ec4a271f930334577e98b14e37d2a0eb7cd3443e7110d3562ac4ef30c310e6448a588f4e31f2943a6d4ff0af006cbbafc50722543436fcae3bdc8e453f SHA512 4465985f67e9812b62b91ac7942105a9f976faf0c0d7c352a99a638fe6bdfde024f939b3daa922d431c7fc87118ae4d9d039b00345760fb547c349e8737dc168
+DIST mozilla-rr-5.3.0.tar.gz 1343557 BLAKE2B 80ed2feb52fd34b424193902c02408443e5ae943a34d3fe8e75c4c813042c6dd7f39571924ce94aca558ea5f1630f9bda28bea9d5f7e2d429d772a85d3e3e7ad SHA512 6ae37a3ced0c001208fb981abc18f02b912a2851564955dd8da364cb30d9580ea6c91bedbef6495da5d082954d4f261eeaea81df1e9895b4adf948e9998f4c2b

diff --git a/dev-util/rr/rr-5.3.0.ebuild b/dev-util/rr/rr-5.3.0.ebuild
new file mode 100644 (file)
index 0000000..c749db4
--- /dev/null
+++ b/dev-util/rr/rr-5.3.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8} )
+CMAKE_BUILD_TYPE=Release
+
+inherit cmake-utils linux-info python-single-r1
+
+DESCRIPTION="Record and Replay Framework"
+HOMEPAGE="https://rr-project.org/"
+SRC_URI="https://github.com/mozilla/${PN}/archive/${PV}.tar.gz -> mozilla-${P}.tar.gz"
+
+LICENSE="MIT BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="multilib test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+       sys-libs/zlib
+       dev-libs/capnproto
+       ${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+       sys-devel/gdb[xml]"
+# Add all the deps needed only at build/test time.
+DEPEND+="
+       test? (
+               dev-python/pexpect[${PYTHON_USEDEP}]
+               sys-devel/gdb[xml]
+       )"
+
+RESTRICT="test" # toolchain and kernel version dependent
+
+pkg_setup() {
+       if use kernel_linux; then
+               CONFIG_CHECK="SECCOMP"
+               linux-info_pkg_setup
+       fi
+       python-single-r1_pkg_setup
+}
+
+src_prepare() {
+       cmake-utils_src_prepare
+
+       sed -i 's:-Werror::' CMakeLists.txt || die #609192
+}
+
+src_test() {
+       if has usersandbox ${FEATURES} ; then
+               ewarn "Test suite fails under FEATURES=usersandbox (bug #632394). Skipping."
+               return 0
+       fi
+
+       cmake-utils_src_test
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DBUILD_TESTS=$(usex test)
+               -Ddisable32bit=$(usex !multilib) #636786
+       )
+
+       cmake-utils_src_configure
+}