net-vpn/networkmanager-strongswan: drop legacy libnm-glib usage

libnm-glib is long gone in NM upstream, so stop providing it as an
option to move forward along with NetworkManager bumps.
Depend on new net-libs/libnma instead of nm-applet, as that's
what's needed and it's split out upstream in newer versions.
Fix intltool depend while here (it's a BDEPEND).

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

diff --git a/net-vpn/networkmanager-strongswan/networkmanager-strongswan-1.4.5-r2.ebuild b/net-vpn/networkmanager-strongswan/networkmanager-strongswan-1.4.5-r2.ebuild
new file mode 100644 (file)
index 0000000..c325a0f
--- /dev/null
+++ b/net-vpn/networkmanager-strongswan/networkmanager-strongswan-1.4.5-r2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="NetworkManager"
+MY_P="${P/networkmanager/${MY_PN}}"
+
+DESCRIPTION="NetworkManager StrongSwan plugin"
+HOMEPAGE="https://www.strongswan.org/"
+SRC_URI="https://download.strongswan.org/${MY_PN}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+       app-crypt/libsecret
+       >=net-libs/libnma-1.1.0
+       net-misc/networkmanager
+       net-vpn/strongswan[networkmanager]
+       x11-libs/gtk+:3
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+       dev-util/intltool
+       virtual/pkgconfig
+"
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+       local myeconfargs=(
+               # Don't enable all warnings, as some are treated as errors and the compilation will fail
+               --disable-more-warnings
+               --disable-static
+               --without-libnm-glib
+       )
+
+       econf "${myeconfargs[@]}"
+}
+
+src_install() {
+       default
+
+       find "${D}" -name '*.la' -delete || die
+}