x11-terms/rxvt-unicode/rxvt-unicode-9.22-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools eutils
   6
   7 DESCRIPTION="rxvt clone with xft and unicode support"
   8 HOMEPAGE="http://software.schmorp.de/pkg/rxvt-unicode.html"
   9 SRC_URI="http://dist.schmorp.de/rxvt-unicode/Attic/${P}.tar.bz2"
  10
  11 LICENSE="GPL-3"
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris"
  14 IUSE="
  15         256-color blink fading-colors +font-styles gdk-pixbuf iso14755 +mousewheel
  16         +perl startup-notification unicode3 xft
  17 "
  18 RESTRICT="test"
  19
  20 RDEPEND="
  21         >=sys-libs/ncurses-5.7-r6:=
  22         kernel_Darwin? ( dev-perl/Mac-Pasteboard )
  23         media-libs/fontconfig
  24         perl? ( dev-lang/perl:= )
  25         gdk-pixbuf? ( x11-libs/gdk-pixbuf x11-libs/gtk+:2 )
  26         startup-notification? ( x11-libs/startup-notification )
  27         x11-libs/libX11
  28         x11-libs/libXrender
  29         xft? ( x11-libs/libXft )
  30 "
  31 DEPEND="
  32         ${RDEPEND}
  33         virtual/pkgconfig
  34         x11-base/xorg-proto
  35 "
  36 PATCHES=(
  37         "${FILESDIR}"/${PN}-9.06-case-insensitive-fs.patch
  38         "${FILESDIR}"/${PN}-9.21-xsubpp.patch
  39 )
  40
  41 src_prepare() {
  42         default
  43
  44         # kill the rxvt-unicode terminfo file - #192083
  45         sed -i -e "/rxvt-unicode.terminfo/d" doc/Makefile.in || die "sed failed"
  46
  47         eautoreconf
  48 }
  49
  50 src_configure() {
  51         # --enable-everything goes first: the order of the arguments matters
  52         econf \
  53                 --enable-everything \
  54                 $(use_enable 256-color) \
  55                 $(use_enable blink text-blink) \
  56                 $(use_enable fading-colors fading) \
  57                 $(use_enable font-styles) \
  58                 $(use_enable gdk-pixbuf pixbuf) \
  59                 $(use_enable iso14755) \
  60                 $(use_enable mousewheel) \
  61                 $(use_enable perl) \
  62                 $(use_enable startup-notification) \
  63                 $(use_enable unicode3) \
  64                 $(use_enable xft)
  65 }
  66
  67 src_compile() {
  68         default
  69
  70         sed -i \
  71                 -e 's/RXVT_BASENAME = "rxvt"/RXVT_BASENAME = "urxvt"/' \
  72                 "${S}"/doc/rxvt-tabbed || die
  73 }
  74
  75 src_install() {
  76         default
  77
  78         dodoc \
  79                 README.FAQ Changes doc/README* doc/changes.txt doc/etc/* doc/rxvt-tabbed
  80
  81         make_desktop_entry urxvt rxvt-unicode utilities-terminal \
  82                 "System;TerminalEmulator"
  83 }