x11-misc/shared-mime-info/shared-mime-info-1.15.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 HASH=b27eb88e4155d8fccb8bb3cd12025d5b # don't forget to update on version bumps
   7 inherit xdg-utils
   8
   9 DESCRIPTION="The Shared MIME-info Database specification"
  10 HOMEPAGE="https://gitlab.freedesktop.org/xdg/shared-mime-info"
  11 SRC_URI="https://gitlab.freedesktop.org/xdg/${PN}/uploads/${HASH}/${P}.tar.xz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 s390 ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  16
  17 BDEPEND="
  18         dev-util/itstool
  19         sys-devel/gettext
  20         virtual/pkgconfig
  21 "
  22 RDEPEND="
  23         dev-libs/glib:2
  24         dev-libs/libxml2
  25 "
  26 DEPEND="${RDEPEND}"
  27
  28 DOCS=( ChangeLog HACKING NEWS README )
  29
  30 src_configure() {
  31         export ac_cv_func_fdatasync=no #487504
  32         econf --disable-update-mimedb
  33 }
  34
  35 src_install() {
  36         default
  37
  38         # in prefix, install an env.d entry such that prefix patch is used/added
  39         if use prefix; then
  40                 echo "XDG_DATA_DIRS=\"${EPREFIX}/usr/share\"" > "${T}"/50mimeinfo || die
  41                 doenvd "${T}"/50mimeinfo
  42         fi
  43 }
  44
  45 pkg_postinst() {
  46         use prefix && export XDG_DATA_DIRS="${EPREFIX}"/usr/share
  47         xdg_mimeinfo_database_update
  48 }