x11-misc/shared-mime-info/shared-mime-info-1.10.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit xdg-utils
   6
   7 DESCRIPTION="The Shared MIME-info Database specification"
   8 HOMEPAGE="https://freedesktop.org/wiki/Software/shared-mime-info"
   9 SRC_URI="https://people.freedesktop.org/~hadess/${P}.tar.xz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 m68k ~mips ppc ppc64 s390 sparc x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  14 IUSE="test"
  15 RESTRICT="!test? ( test )"
  16
  17 RDEPEND=">=dev-libs/glib-2
  18         dev-libs/libxml2"
  19 DEPEND="${RDEPEND}
  20         dev-util/intltool
  21         sys-devel/gettext
  22         virtual/pkgconfig"
  23
  24 DOCS=( ChangeLog HACKING NEWS README )
  25
  26 src_configure() {
  27         export ac_cv_func_fdatasync=no #487504
  28
  29         local myeconfargs=(
  30                 $(use_enable test default-make-check)
  31                 --disable-update-mimedb
  32         )
  33         econf "${myeconfargs[@]}"
  34 }
  35
  36 src_compile() {
  37         # FIXME: 0.91 fails with -j9 every second time like:
  38         # update_mime_database-update-mime-database.o: file not recognized: File truncated
  39         # collect2: ld returned 1 exit status
  40         emake -j1
  41 }
  42
  43 src_install() {
  44         default
  45
  46         # in prefix, install an env.d entry such that prefix patch is used/added
  47         if use prefix; then
  48                 echo "XDG_DATA_DIRS=\"${EPREFIX}/usr/share\"" > "${T}"/50mimeinfo || die
  49                 doenvd "${T}"/50mimeinfo
  50         fi
  51 }
  52
  53 pkg_postinst() {
  54         use prefix && export XDG_DATA_DIRS="${EPREFIX}"/usr/share
  55         xdg_mimeinfo_database_update
  56 }