x11-misc/mozo/mozo-1.22.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python3_6 )
   7 PYTHON_REQ_USE="xml"
   8
   9 inherit python-r1 mate
  10
  11 if [[ ${PV} != 9999 ]]; then
  12         KEYWORDS="amd64 ~arm ~arm64 x86"
  13 fi
  14
  15 DESCRIPTION="Mozo menu editor for MATE"
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 IUSE=""
  19 REQUIRED_USE=${PYTHON_REQUIRED_USE}
  20
  21 COMMON_DEPEND="${PYTHON_DEPS}
  22         >=dev-python/pygobject-3:3[${PYTHON_USEDEP}]
  23         >=mate-base/mate-menus-1.21.0[introspection]
  24         x11-libs/gdk-pixbuf:2[introspection]
  25         >=x11-libs/gtk+-3.22:3[introspection]
  26         virtual/libintl
  27         !!x11-misc/mate-menu-editor"
  28
  29 RDEPEND="${COMMON_DEPEND}"
  30
  31 DEPEND="${COMMON_DEPEND}
  32         >=dev-util/intltool-0.40
  33         sys-devel/gettext:*
  34         virtual/pkgconfig:*"
  35
  36 src_prepare() {
  37         mate_src_prepare
  38         python_copy_sources
  39 }
  40
  41 src_configure() {
  42         python_foreach_impl run_in_build_dir mate_src_configure \
  43                 --disable-icon-update
  44 }
  45
  46 src_compile() {
  47         python_foreach_impl run_in_build_dir default
  48 }
  49
  50 src_test() {
  51         python_foreach_impl run_in_build_dir emake check
  52 }
  53
  54 src_install() {
  55         installing() {
  56                 mate_src_install
  57
  58                 # Massage shebang to make python_doscript happy
  59                 sed -e 's:#! '"${PYTHON}:#!/usr/bin/python:" \
  60                         -i mozo || die
  61
  62                 python_doscript mozo
  63         }
  64
  65         python_foreach_impl run_in_build_dir installing
  66 }