x11-misc/habak/habak-0.2.5-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="A simple but powerful tool to set desktop wallpaper"
   9 HOMEPAGE="http://home.gna.org/fvwm-crystal/"
  10 SRC_URI="http://download.gna.org/fvwm-crystal/${PN}/${PV}/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 ppc ppc64 sparc x86"
  15 IUSE=""
  16
  17 RDEPEND="media-libs/imlib2[X]
  18         x11-libs/libX11"
  19 DEPEND="${RDEPEND}
  20         x11-base/xorg-proto"
  21
  22 # Skip into the src directory so we avoid a recursive make call that
  23 # is going to break parallel make.
  24 S="${WORKDIR}/${P}/src"
  25
  26 DOCS=( ChangeLog README TODO "${FILESDIR}"/README.en )
  27
  28 src_prepare() {
  29         default
  30         sed -i \
  31                 -e '/(LDFLAGS)/s:$: -lImlib2 -lm -lX11:' \
  32                 -e 's:gcc:$(CC):' \
  33                 "${S}"/Makefile || die "Makefile fixing failed"
  34 }
  35
  36 src_compile() {
  37         emake CC="$(tc-getCC)" ${PN}
  38 }
  39
  40 src_install() {
  41         dobin ${PN}
  42         cd "${WORKDIR}/${P}" || die
  43         einstalldocs
  44 }