x11-libs/libnotify/libnotify-0.7.8.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit gnome.org meson multilib-minimal xdg-utils
   7
   8 DESCRIPTION="A library for sending desktop notifications"
   9 HOMEPAGE="https://gitlab.gnome.org/GNOME/libnotify"
  10
  11 LICENSE="LGPL-2.1+"
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 arm arm64 ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
  14 IUSE="gtk-doc +introspection test"
  15 RESTRICT="!test? ( test )"
  16
  17 RDEPEND="
  18         app-eselect/eselect-notify-send
  19         >=dev-libs/glib-2.26:2[${MULTILIB_USEDEP}]
  20         x11-libs/gdk-pixbuf:2[${MULTILIB_USEDEP}]
  21         introspection? ( >=dev-libs/gobject-introspection-1.54:= )
  22 "
  23 DEPEND="${RDEPEND}"
  24 BDEPEND="
  25         >=dev-libs/gobject-introspection-common-1.32
  26         dev-util/glib-utils
  27         virtual/pkgconfig
  28         gtk-doc? ( dev-util/gtk-doc
  29                 app-text/docbook-xml-dtd:4.1.2 )
  30         test? ( x11-libs/gtk+:3[${MULTILIB_USEDEP}] )
  31 "
  32 PDEPEND="virtual/notification-daemon"
  33
  34 src_prepare() {
  35         default
  36         xdg_environment_reset
  37 }
  38
  39 multilib_src_configure() {
  40         local emesonargs=(
  41                 -Dtests="$(usex test true false)"
  42                 -Dintrospection="$(multilib_native_usex introspection enabled disabled)"
  43                 -Dgtk_doc=$(multilib_native_usex gtk-doc true false)
  44                 -Ddocbook_docs=disabled
  45         )
  46         meson_src_configure
  47 }
  48
  49 multilib_src_install() {
  50         meson_src_install
  51
  52         mv "${ED}"/usr/bin/{,libnotify-}notify-send || die #379941
  53 }
  54
  55 pkg_postinst() {
  56         eselect notify-send update ifunset
  57 }
  58
  59 pkg_postrm() {
  60         eselect notify-send update ifunset
  61 }