www-misc/litmus/litmus-0.13.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 inherit autotools eutils
   7
   8 # TODO: FAIL (connection refused by '...' port 80: Connection refused)
   9 # We can't run tests that connect with the internet.
  10 RESTRICT="test"
  11
  12 DESCRIPTION="WebDAV server protocol compliance test suite"
  13 HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
  14 SRC_URI="mirror://gentoo/${P}.tar.gz"
  15
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~x86"
  19 IUSE="debug expat gnutls kerberos libproxy +libxml2 pkcs11 +ssl threads"
  20 REQUIRED_USE="?? ( gnutls ssl )
  21         ^^ ( expat libxml2 )
  22         threads? ( ^^ ( gnutls ssl ) )"
  23
  24 NEON_DEP="net-libs/neon:0="
  25 DEPEND="${NEON_DEP}[expat?,gnutls?,kerberos?,libproxy?,pkcs11?,ssl?,zlib]
  26
  27         expat? ( dev-libs/expat:0 )
  28         gnutls? ( net-libs/gnutls:0 )
  29         kerberos? ( app-crypt/mit-krb5:0 )
  30         libproxy? ( net-libs/libproxy:0 )
  31         libxml2? ( dev-libs/libxml2:2 )
  32         pkcs11? ( dev-libs/pakchois:0 )
  33         ssl? ( dev-libs/openssl:0 )"
  34 RDEPEND="${DEPEND}"
  35
  36 DOCS=( ChangeLog FAQ NEWS README THANKS TODO )
  37
  38 src_prepare() {
  39         # Accept Neon 0.30.
  40         epatch "${FILESDIR}/${PV}-autotools-neon-version.patch"
  41
  42         eautoreconf
  43 }
  44
  45 src_configure() {
  46         # No EGD available in the Portage tree.
  47         econf \
  48                 --enable-warnings \
  49                 --without-egd \
  50                 --with-neon \
  51                 --without-included-neon \
  52                 $(use_enable debug) \
  53                 $(use_enable threads threadsafe-ssl posix) \
  54                 $(use_with gnutls ssl gnutls) \
  55                 $(use_with ssl    ssl openssl) \
  56                 $(use_with expat) \
  57                 $(use_with libxml2) \
  58                 $(use_with kerberos gssapi) \
  59                 $(use_with pkcs11 pakchois) \
  60                 $(use_with libproxy)
  61 }