www-apps/bugzilla/bugzilla-4.4.12-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit webapp depend.apache eutils
   7
   8 DESCRIPTION="Bugzilla is the Bug-Tracking System from the Mozilla project"
   9 SRC_URI="https://ftp.mozilla.org/pub/mozilla.org/webtools/${P}.tar.gz"
  10 HOMEPAGE="https://www.bugzilla.org"
  11
  12 LICENSE="MPL-2.0"
  13 KEYWORDS="amd64 x86"
  14
  15 IUSE="modperl extras graphviz mysql postgres sqlite test"
  16 RESTRICT="!test? ( test )"
  17 REQUIRED_USE=" || ( mysql postgres sqlite )"
  18
  19 COMMON_DEPS="
  20         >=dev-lang/perl-5.10.1
  21         >=dev-perl/CGI-3.510.0
  22         virtual/perl-Digest-SHA
  23         >=dev-perl/DateTime-0.500.0
  24         >=dev-perl/DateTime-TimeZone-0.710.0
  25         >=dev-perl/DBI-1.601.0
  26         >=dev-perl/Template-Toolkit-2.22
  27         >=dev-perl/Email-Send-2.40.0
  28         >=dev-perl/Email-MIME-1.904.0
  29         dev-perl/URI
  30         >=dev-perl/List-MoreUtils-0.329.0
  31         dev-perl/Math-Random-ISAAC
  32 "
  33
  34 DEPEND="test? ( dev-perl/Pod-Coverage${COMMON_DEPS} )"
  35 RDEPEND="
  36         virtual/httpd-cgi
  37         ${COMMON_DEPS}
  38         postgres? ( >=dev-perl/DBD-Pg-1.49.0 )
  39         mysql? ( >=dev-perl/DBD-mysql-4.0.5 )
  40         sqlite? ( >=dev-perl/DBD-SQLite-1.290.0 )
  41         extras? (
  42                 >=dev-perl/GD-2.35[png,truetype]
  43                 >=dev-perl/Chart-2.4.1
  44                 dev-perl/Template-GD
  45                 dev-perl/GDTextUtil
  46                 dev-perl/GDGraph
  47                 dev-perl/XML-Twig
  48                 >=dev-perl/MIME-tools-5.427.0
  49                 dev-perl/libwww-perl
  50                 >=dev-perl/PatchReader-0.9.6
  51                 dev-perl/perl-ldap
  52                 dev-perl/Authen-Radius
  53                 dev-perl/Authen-SASL
  54                 >=dev-perl/SOAP-Lite-0.712.0
  55                 dev-perl/JSON-RPC
  56                 >=dev-perl/JSON-XS-2.0.0
  57                 dev-perl/Test-Taint
  58                 >=dev-perl/HTML-Parser-3.67.0
  59                 dev-perl/HTML-Scrubber
  60                 >=virtual/perl-Encode-2.21.0
  61                 dev-perl/Encode-Detect
  62                 dev-perl/Email-MIME-Attachment-Stripper
  63                 dev-perl/Email-Reply
  64                 dev-perl/TheSchwartz
  65                 dev-perl/Daemon-Generic
  66                 dev-perl/File-MimeInfo
  67                 virtual/imagemagick-tools[perl]
  68                 dev-perl/MIME-tools
  69         )
  70         modperl? (
  71                 www-apache/mod_perl:1
  72                 >=dev-perl/Apache-SizeLimit-0.96.0
  73         )
  74         graphviz? ( media-gfx/graphviz )
  75 "
  76 want_apache modperl
  77 need_httpd_cgi
  78
  79 PATCHES=(
  80         "${FILESDIR}/${PN}"-5.0.3-leftbrace.patch
  81 )
  82
  83 pkg_setup() {
  84         depend.apache_pkg_setup modperl
  85         webapp_pkg_setup
  86 }
  87
  88 src_prepare() {
  89         # Get a rid of the bzr files
  90         rm -r .bzr* || die
  91
  92         # Remove bundled perl modules
  93         rm -r lib/ || die
  94
  95         default
  96 }
  97
  98 src_test() {
  99         perl -I. runtests.pl || die
 100 }
 101
 102 src_install() {
 103         webapp_src_preinst
 104
 105         insinto "${MY_HTDOCSDIR}"
 106         doins -r .
 107         doins "${FILESDIR}"/bugzilla.cron.{daily,tab}
 108
 109         webapp_hook_script "${FILESDIR}"/reconfig
 110         webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
 111         webapp_src_install
 112
 113         if use extras; then
 114                 newconfd "${FILESDIR}"/bugzilla-queue.confd bugzilla-queue
 115                 newinitd "${FILESDIR}"/bugzilla-queue.initd bugzilla-queue
 116         fi
 117
 118         # bug #124282
 119         for f in "${D}${MY_HTDOCSDIR}"/*.cgi ; do
 120                 fperms +x "${f#${D}}"
 121         done
 122
 123         fperms u+x "${MY_HTDOCSDIR}"/jobqueue.pl
 124
 125         # configuration must be executable
 126         fperms u+x "${MY_HTDOCSDIR}"/checksetup.pl
 127
 128         # bug 487476
 129         mkdir "${D}${MY_HTDOCSDIR}"/lib || die
 130 }