sys-process/glances/glances-3.1.4.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 PYTHON_REQ_USE="ncurses"
   8 DISTUTILS_USE_SETUPTOOLS=rdepend
   9
  10 inherit distutils-r1 eutils linux-info
  11
  12 DESCRIPTION="CLI curses based monitoring tool"
  13 HOMEPAGE="https://github.com/nicolargo/glances"
  14 SRC_URI="https://github.com/nicolargo/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  15
  16 LICENSE="LGPL-3"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~arm arm64 ppc64 ~x86 ~amd64-linux ~x86-linux"
  19 IUSE=""
  20
  21 RDEPEND="dev-python/future[${PYTHON_USEDEP}]
  22         >=dev-python/psutil-5.4.3[${PYTHON_USEDEP}]"
  23
  24 CONFIG_CHECK="~TASK_IO_ACCOUNTING ~TASK_DELAY_ACCT ~TASKSTATS"
  25
  26 PATCHES=(
  27         "${FILESDIR}/disable-update-check.patch"
  28 )
  29
  30 distutils_enable_tests setup.py
  31 distutils_enable_sphinx docs --no-autodoc
  32
  33 pkg_setup() {
  34         linux-info_pkg_setup
  35 }
  36
  37 python_prepare_all() {
  38         # Remove duplicate entries of a prebuilt doc build and
  39         # ensure install of the file glances.conf in /etc/${PN}
  40         sed \
  41                 -e '/share\/doc\/glances/d' \
  42                 -e "s/'CONTRIBUTING.md',//" \
  43                 -e "s:'conf/glances.conf':('${EPREFIX}/etc/glances', ['conf/glances.conf':g" \
  44                 -i setup.py || die
  45         sed -i "s/, 'irq']/]/" unitest.py || die
  46         distutils-r1_python_prepare_all
  47 }
  48
  49 python_install_all() {
  50         # add an intended file from original data set from setup.py to DOCS
  51         local DOCS=( README.rst CONTRIBUTING.md conf/glances.conf )
  52         distutils-r1_python_install_all
  53 }
  54
  55 pkg_postinst() {
  56         optfeature "Action script feature" dev-python/pystache
  57         optfeature "Autodiscover mode" dev-python/zeroconf
  58         optfeature "Cloud support" dev-python/requests
  59         optfeature "Quicklook CPU info" dev-python/py-cpuinfo
  60         optfeature "Docker monitoring support" dev-python/docker-py
  61         #optfeature "Export module" \
  62         #       unpackaged/bernhard \
  63         #       unpackaged/cassandra-driver \
  64         #       unpackaged/potsdb \
  65         #       dev-python/couchdb-python \
  66         #       dev-python/elasticsearch-py \
  67         #       dev-python/influxdb \
  68         #       dev-python/kafka-python \
  69         #       dev-python/pika \
  70         #       dev-python/paho-mqtt \
  71         #       dev-python/prometheus_client \
  72         #       dev-python/pyzmq \
  73         #       dev-python/statsd
  74         #optfeature "Nvidia GPU monitoring" unpackaged/nvidia-ml-py3
  75         optfeature "SVG graph support" dev-python/pygal
  76         optfeature "IP plugin" dev-python/netifaces
  77         optfeature "RAID monitoring" dev-python/pymdstat
  78         #optfeature "SMART support" unpackaged/pySMART.smartx
  79         optfeature "RAID support" dev-python/pymdstat
  80         optfeature "SNMP support" dev-python/pysnmp
  81         #optfeature "sparklines plugin" unpackaged/sparklines
  82         optfeature "Web server mode" dev-python/bottle dev-python/requests
  83         optfeature "WIFI plugin" net-wireless/python-wifi
  84 }