sys-devel/sparse/sparse-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit eutils llvm multilib toolchain-funcs
   7
   8 DESCRIPTION="C semantic parser"
   9 HOMEPAGE="https://sparse.wiki.kernel.org/index.php/Main_Page"
  10
  11 if [[ ${PV} == "9999" ]] ; then
  12         inherit git-r3
  13         EGIT_REPO_URI="https://git.kernel.org/pub/scm/devel/${PN}/${PN}.git"
  14         KEYWORDS=""
  15 else
  16         SRC_URI="https://www.kernel.org/pub/software/devel/${PN}/dist/${P}.tar.xz"
  17         KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
  18 fi
  19
  20 LICENSE="MIT"
  21 SLOT="0"
  22 IUSE="gtk llvm test xml"
  23 RESTRICT="!test? ( test )"
  24
  25 LLVM_MAX_SLOT=9
  26
  27 RDEPEND="gtk? ( x11-libs/gtk+:2 )
  28         llvm? ( sys-devel/llvm:${LLVM_MAX_SLOT}= )
  29         xml? ( dev-libs/libxml2 )"
  30 DEPEND="${RDEPEND}
  31         gtk? ( virtual/pkgconfig )
  32         xml? ( virtual/pkgconfig )"
  33
  34 _emake() {
  35         # Makefile does not allow for an easy override of flags.
  36         # Collect them here and override default phases.
  37         emake \
  38                 CC="$(tc-getCC)" \
  39                 LD="$(tc-getCC)" \
  40                 AR="$(tc-getAR)" \
  41                 CFLAGS="${CFLAGS}" \
  42                 PKG_CONFIG="$(tc-getPKG_CONFIG)" \
  43                 \
  44                 HAVE_GTK=$(usex gtk) \
  45                 HAVE_LLVM=$(usex llvm) \
  46                 HAVE_LIBXML=$(usex xml) \
  47                 \
  48                 V=1 \
  49                 PREFIX="${EPREFIX}/usr" \
  50                 \
  51                 "$@"
  52 }
  53
  54 src_compile() {
  55         _emake
  56 }
  57
  58 src_test() {
  59         _emake check
  60 }
  61
  62 src_install() {
  63         _emake DESTDIR="${D}" install
  64
  65         dodoc FAQ README
  66 }