sys-cluster/nova/nova-2019.2.9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7 inherit distutils-r1 eutils linux-info multilib
   8
   9 DESCRIPTION="Cloud computing fabric controller"
  10 HOMEPAGE="https://launchpad.net/nova"
  11
  12 if [[ ${PV} == *9999 ]];then
  13         inherit git-r3
  14         SRC_URI="https://dev.gentoo.org/~prometheanfire/dist/openstack/nova/train/nova.conf.sample -> nova.conf.sample-${PV}"
  15         EGIT_REPO_URI="https://github.com/openstack/nova.git"
  16         EGIT_BRANCH="stable/train"
  17 else
  18         SRC_URI="https://dev.gentoo.org/~prometheanfire/dist/openstack/nova/train/nova.conf.sample -> nova.conf.sample-${PV}
  19         https://tarballs.openstack.org/${PN}/${P}.tar.gz"
  20         KEYWORDS="~amd64 ~arm64 ~x86"
  21 fi
  22
  23 LICENSE="Apache-2.0"
  24 SLOT="0"
  25 IUSE="+compute compute-only iscsi +memcached +mysql +novncproxy openvswitch postgres +rabbitmq sqlite"
  26 REQUIRED_USE="
  27         !compute-only? ( || ( mysql postgres sqlite ) )
  28         compute-only? ( compute !rabbitmq !memcached !mysql !postgres !sqlite )"
  29
  30 CDEPEND="
  31         >=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
  32         !~dev-python/pbr-2.1.0[${PYTHON_USEDEP}]"
  33 DEPEND="
  34         ${CDEPEND}
  35         app-admin/sudo"
  36
  37 RDEPEND="
  38         ${CDEPEND}
  39         compute-only? (
  40                 >=dev-python/sqlalchemy-1.2.19[${PYTHON_USEDEP}]
  41         )
  42         sqlite? (
  43                 >=dev-python/sqlalchemy-1.2.19[sqlite,${PYTHON_USEDEP}]
  44         )
  45         mysql? (
  46                 >=dev-python/pymysql-0.7.6[${PYTHON_USEDEP}]
  47                 !~dev-python/pymysql-0.7.7[${PYTHON_USEDEP}]
  48                 >=dev-python/sqlalchemy-1.2.19[${PYTHON_USEDEP}]
  49         )
  50         postgres? (
  51                 >=dev-python/psycopg-2.5.0[${PYTHON_USEDEP}]
  52                 >=dev-python/sqlalchemy-1.2.19[${PYTHON_USEDEP}]
  53         )
  54         >=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
  55         >=dev-python/eventlet-0.20.0[${PYTHON_USEDEP}]
  56         !~dev-python/eventlet-0.20.1[${PYTHON_USEDEP}]
  57         >=dev-python/jinja-2.10[${PYTHON_USEDEP}]
  58         >=dev-python/keystonemiddleware-4.17.0[${PYTHON_USEDEP}]
  59         >=dev-python/lxml-2.4.1[${PYTHON_USEDEP}]
  60         !~dev-python/lxml-3.7.0[${PYTHON_USEDEP}]
  61         >=dev-python/routes-2.3.1[${PYTHON_USEDEP}]
  62         >=dev-python/cryptography-2.7[${PYTHON_USEDEP}]
  63         >=dev-python/webob-1.8.2[${PYTHON_USEDEP}]
  64         >=dev-python/greenlet-0.4.10[${PYTHON_USEDEP}]
  65         !~dev-python/greenlet-0.4.14[${PYTHON_USEDEP}]
  66         >=dev-python/pastedeploy-1.5.0-r1[${PYTHON_USEDEP}]
  67         >=dev-python/paste-2.0.2[${PYTHON_USEDEP}]
  68         >=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
  69         <dev-python/prettytable-0.8[${PYTHON_USEDEP}]
  70         >=dev-python/sqlalchemy-migrate-0.11.0[${PYTHON_USEDEP}]
  71         >=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
  72         >=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
  73         >=dev-python/paramiko-2.0.0[${PYTHON_USEDEP}]
  74         >=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
  75         !~dev-python/Babel-2.4.0[${PYTHON_USEDEP}]
  76         >=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
  77         >=dev-python/jsonschema-2.6.0[${PYTHON_USEDEP}]
  78         >=dev-python/python-cinderclient-3.3.0[${PYTHON_USEDEP}]
  79         !~dev-python/python-cinderclient-4.0.0[${PYTHON_USEDEP}]
  80         >=dev-python/keystoneauth-3.16.0[${PYTHON_USEDEP}]
  81         >=dev-python/python-neutronclient-6.7.0[${PYTHON_USEDEP}]
  82         >=dev-python/python-glanceclient-2.8.0[${PYTHON_USEDEP}]
  83         >=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
  84         >=dev-python/six-1.10.0[${PYTHON_USEDEP}]
  85         >=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
  86         >=dev-python/websockify-0.8.0[${PYTHON_USEDEP}]
  87         >=dev-python/oslo-cache-1.26.0[${PYTHON_USEDEP}]
  88         >=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
  89         >=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
  90         >=dev-python/oslo-context-2.19.2[${PYTHON_USEDEP}]
  91         >=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
  92         >=dev-python/oslo-reports-1.18.0[${PYTHON_USEDEP}]
  93         >=dev-python/oslo-serialization-1.21.0[${PYTHON_USEDEP}]
  94         >=dev-python/oslo-upgradecheck-0.1.1[${PYTHON_USEDEP}]
  95         !~dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
  96         >=dev-python/oslo-utils-3.40.2[${PYTHON_USEDEP}]
  97         >=dev-python/oslo-db-4.44.0[${PYTHON_USEDEP}]
  98         >=dev-python/oslo-rootwrap-5.8.0[${PYTHON_USEDEP}]
  99         >=dev-python/oslo-messaging-7.0.0[${PYTHON_USEDEP}]
 100         >=dev-python/oslo-policy-1.35.0[${PYTHON_USEDEP}]
 101         >=dev-python/oslo-privsep-1.33.2[${PYTHON_USEDEP}]
 102         >=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
 103         >=dev-python/oslo-service-1.40.1[${PYTHON_USEDEP}]
 104         >=dev-python/rfc3986-1.1.0[${PYTHON_USEDEP}]
 105         >=dev-python/oslo-middleware-3.31.0[${PYTHON_USEDEP}]
 106         >=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
 107         >=dev-python/oslo-versionedobjects-1.35.0[${PYTHON_USEDEP}]
 108         >=dev-python/os-brick-2.6.1[${PYTHON_USEDEP}]
 109         >=dev-python/os-resource-classes-0.4.0[${PYTHON_USEDEP}]
 110         >=dev-python/os-traits-0.16.0[${PYTHON_USEDEP}]
 111         >=dev-python/os-vif-1.14.0[${PYTHON_USEDEP}]
 112         >=dev-python/os-win-3.0.0[${PYTHON_USEDEP}]
 113         >=dev-python/castellan-0.16.0[${PYTHON_USEDEP}]
 114         >=dev-python/microversion-parse-0.2.1[${PYTHON_USEDEP}]
 115         >=dev-python/os-xenapi-0.3.3[${PYTHON_USEDEP}]
 116         >=dev-python/tooz-1.58.0[${PYTHON_USEDEP}]
 117         >=dev-python/cursive-0.2.1[${PYTHON_USEDEP}]
 118         >=dev-python/pypowervm-1.1.15[${PYTHON_USEDEP}]
 119         >=dev-python/retrying-1.3.3[${PYTHON_USEDEP}]
 120         >=dev-python/os-service-types-1.7.0[${PYTHON_USEDEP}]
 121         >=dev-python/taskflow-2.16.0[${PYTHON_USEDEP}]
 122         >=dev-python/python-dateutil-2.5.3[${PYTHON_USEDEP}]
 123         >=dev-python/zVMCloudConnector-1.3.0[${PYTHON_USEDEP}]
 124         >=dev-python/openstacksdk-0.35.0[${PYTHON_USEDEP}]
 125         dev-python/libvirt-python[${PYTHON_USEDEP}]
 126         app-emulation/libvirt[iscsi?]
 127         app-emulation/spice-html5
 128         novncproxy? ( www-apps/novnc )
 129         sys-apps/iproute2
 130         openvswitch? ( net-misc/openvswitch )
 131         rabbitmq? ( net-misc/rabbitmq-server )
 132         memcached? (
 133                 net-misc/memcached
 134                 >=dev-python/python-memcached-1.58
 135         )
 136         sys-fs/sysfsutils
 137         sys-fs/multipath-tools
 138         net-misc/bridge-utils
 139         compute? (
 140                 app-cdr/cdrtools
 141                 sys-fs/dosfstools
 142                 app-emulation/qemu
 143         )
 144         iscsi? (
 145                 sys-fs/lsscsi
 146                 >=sys-block/open-iscsi-2.0.873-r1
 147         )
 148         acct-user/nova
 149         acct-group/nova"
 150
 151 #PATCHES=(
 152 #)
 153
 154 pkg_setup() {
 155         linux-info_pkg_setup
 156         CONFIG_CHECK_MODULES="BLK_DEV_NBD VHOST_NET IP6_NF_FILTER IP6_NF_IPTABLES IP_NF_TARGET_REJECT \
 157         IP_NF_MANGLE IP_NF_TARGET_MASQUERADE NF_NAT_IPV4 IP_NF_FILTER IP_NF_IPTABLES \
 158         NF_CONNTRACK_IPV4 NF_DEFRAG_IPV4 NF_NAT_IPV4 NF_NAT NF_CONNTRACK NETFILTER_XTABLES \
 159         ISCSI_TCP SCSI_DH DM_MULTIPATH DM_SNAPSHOT"
 160         if linux_config_exists; then
 161                 for module in ${CONFIG_CHECK_MODULES}; do
 162                         linux_chkconfig_present ${module} || ewarn "${module} needs to be enabled in kernel"
 163                 done
 164         fi
 165 }
 166
 167 python_prepare_all() {
 168         sed -i '/^hacking/d' test-requirements.txt || die
 169         distutils-r1_python_prepare_all
 170 }
 171
 172 python_install_all() {
 173         distutils-r1_python_install_all
 174
 175         if use !compute-only; then
 176                 for svc in api conductor consoleauth network scheduler spicehtml5proxy xvpvncproxy; do
 177                         newinitd "${FILESDIR}/nova.initd" "nova-${svc}"
 178                 done
 179         fi
 180         use compute && newinitd "${FILESDIR}/nova.initd" "nova-compute"
 181         use novncproxy && newinitd "${FILESDIR}/nova.initd" "nova-novncproxy"
 182
 183         diropts -m 0750 -o nova -g qemu
 184         dodir /var/log/nova /var/lib/nova/instances
 185         diropts -m 0750 -o nova -g nova
 186
 187         insinto /etc/nova
 188         insopts -m 0640 -o nova -g nova
 189         newins "${DISTDIR}/nova.conf.sample-${PV}" "nova.conf.sample"
 190         doins "${FILESDIR}/nova-compute.conf"
 191         doins "${S}/etc/nova/"*
 192         # rootwrap filters
 193         insopts -m 0644
 194         insinto /etc/nova/rootwrap.d
 195         doins "etc/nova/rootwrap.d/api-metadata.filters"
 196         doins "etc/nova/rootwrap.d/compute.filters"
 197         doins "etc/nova/rootwrap.d/network.filters"
 198
 199         # add sudoers definitions for user nova
 200         insinto /etc/sudoers.d/
 201         insopts -m 0600 -o root -g root
 202         doins "${FILESDIR}/nova-sudoers"
 203
 204         if use iscsi ; then
 205                 # Install udev rules for handle iscsi disk with right links under /dev
 206                 udev_newrules "${FILESDIR}/openstack-scsi-disk.rules" 60-openstack-scsi-disk.rules
 207
 208                 insinto /etc/nova/
 209                 doins "${FILESDIR}/scsi-openscsi-link.sh"
 210         fi
 211         rm -r "${ED}/usr/etc"
 212 }
 213
 214 pkg_postinst() {
 215         if use iscsi ; then
 216                 elog "iscsid needs to be running if you want cinder to connect"
 217         fi
 218 }