sci-physics/geant/geant-4.10.6.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake-utils
   7
   8 MY_P=${PN}$(ver_cut 1-2).$(printf %02d $(ver_cut 3))
   9
  10 case ${PV} in
  11 *_beta*)
  12         MY_P+=.b$(printf %02d $(ver_cut 5))
  13         DOCS="ReleaseNotes/Beta$(ver_cut 1-3)-*.txt"
  14         ;;
  15 *_p*)
  16         MY_P+=.p$(printf %02d $(ver_cut 5))
  17         DOCS="ReleaseNotes/Patch$(ver_cut 1-3)-*.txt"
  18         HTML_DOCS="ReleaseNotes/ReleaseNotes$(ver_cut 1-3).html"
  19         ;;
  20 *)
  21         HTML_DOCS="ReleaseNotes/ReleaseNotes$(ver_cut 1-3).html"
  22         ;;
  23 esac
  24
  25 DESCRIPTION="Toolkit for simulation of passage of particles through matter"
  26 HOMEPAGE="https://geant4.cern.ch/"
  27 SRC_URI="https://geant4-data.web.cern.ch/geant4-data/releases/${MY_P}.tar.gz"
  28
  29 LICENSE="geant4"
  30 SLOT="4"
  31 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  32 IUSE="+c++11 c++14 c++17 +data dawn doc examples freetype gdml geant3 hdf5
  33         inventor motif opengl qt5 raytracerx static-libs threads vrml"
  34
  35 REQUIRED_USE="^^ ( c++11 c++14 c++17 )"
  36
  37 RDEPEND="
  38         dev-libs/expat
  39         >=sci-physics/clhep-2.4.1.3:2=[threads?]
  40         data? ( ~sci-physics/geant-data-${PV} )
  41         dawn? ( media-gfx/dawn )
  42         doc? ( ~app-doc/geant-docs-$(ver_cut 1-3) )
  43         gdml? ( dev-libs/xerces-c )
  44         hdf5? ( sci-libs/hdf5[threads?] )
  45         inventor? ( media-libs/SoXt )
  46         motif? ( x11-libs/motif:0 )
  47         opengl? ( virtual/opengl )
  48         qt5? (
  49                 dev-qt/qtcore:5
  50                 dev-qt/qtgui:5
  51                 dev-qt/qtprintsupport:5
  52                 dev-qt/qtwidgets:5
  53                 opengl? ( dev-qt/qtopengl:5 )
  54         )
  55         raytracerx? (
  56                 x11-libs/libX11
  57                 x11-libs/libXmu
  58         )"
  59
  60 PATCHES=( "${FILESDIR}"/geant-4.10.6-datadir.patch )
  61
  62 S="${WORKDIR}/${MY_P}"
  63
  64 src_configure() {
  65         local mycmakeargs=(
  66                 -DCMAKE_INSTALL_DATADIR="${EPREFIX}/usr/share/geant4"
  67                 -DGEANT4_BUILD_CXXSTD=$((usev c++11 || usev c++14 || usev c++17) | cut -c4-)
  68                 -DGEANT4_BUILD_MULTITHREADED=$(usex threads)
  69                 -DGEANT4_BUILD_TLS_MODEL=$(usex threads global-dynamic initial-exec)
  70                 -DGEANT4_INSTALL_DATA=OFF
  71                 -DGEANT4_INSTALL_DATADIR="${EPREFIX}/usr/share/geant4/data"
  72                 -DGEANT4_INSTALL_EXAMPLES=$(usex examples)
  73                 -DGEANT4_USE_FREETYPE=$(usex freetype)
  74                 -DGEANT4_USE_G3TOG4=$(usex geant3)
  75                 -DGEANT4_USE_GDML=$(usex gdml)
  76                 -DGEANT4_USE_INVENTOR=$(usex inventor)
  77                 -DGEANT4_USE_NETWORKDAWN=$(usex dawn)
  78                 -DGEANT4_USE_NETWORKVRML=$(usex vrml)
  79                 -DGEANT4_USE_OPENGL_X11=$(usex opengl)
  80                 -DGEANT4_USE_QT=$(usex qt5)
  81                 -DGEANT4_USE_RAYTRACER_X11=$(usex raytracerx)
  82                 -DGEANT4_USE_SYSTEM_CLHEP=ON
  83                 -DGEANT4_USE_SYSTEM_EXPAT=ON
  84                 -DGEANT4_USE_SYSTEM_ZLIB=ON
  85                 -DGEANT4_USE_WT=OFF
  86                 -DGEANT4_USE_XM=$(usex motif)
  87                 -DBUILD_STATIC_LIBS=$(usex static-libs)
  88                 ${EXTRA_ECONF}
  89         )
  90         if use inventor; then
  91                 mycmakeargs+=(
  92                         -DINVENTOR_INCLUDE_DIR="$(coin-config --includedir)"
  93                         -DINVENTOR_SOXT_INCLUDE_DIR="$(coin-config --includedir)"
  94                 )
  95         fi
  96         cmake-utils_src_configure
  97 }
  98
  99 src_install() {
 100         # adjust clhep linking flags for system clhep
 101         # binmake.gmk is only useful for legacy build systems
 102         sed -i -e 's/-lG4clhep/-lCLHEP/' config/binmake.gmk || die
 103         cmake-utils_src_install
 104         rm "${ED}"/usr/bin/*.{sh,csh} || die "failed to remove obsolete shell scripts"
 105
 106         einstalldocs
 107 }