sci-electronics/pulseview/pulseview-0.4.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7
   8 inherit cmake-utils gnome2-utils python-single-r1 xdg-utils
   9
  10 if [[ ${PV} == "9999" ]]; then
  11         EGIT_REPO_URI="git://sigrok.org/${PN}"
  12         inherit git-r3
  13 else
  14         SRC_URI="https://sigrok.org/download/source/${PN}/${P}.tar.gz"
  15         KEYWORDS="~amd64 ~x86"
  16 fi
  17
  18 DESCRIPTION="Qt based logic analyzer GUI for sigrok"
  19 HOMEPAGE="https://sigrok.org/wiki/PulseView"
  20
  21 LICENSE="GPL-3"
  22 SLOT="0"
  23 IUSE="+decode static"
  24 REQUIRED_USE="decode? ( ${PYTHON_REQUIRED_USE} )"
  25
  26 RDEPEND="
  27         >=dev-libs/boost-1.55:=
  28         >=dev-libs/glib-2.28.0:2
  29         >=dev-cpp/glibmm-2.28.0:2
  30         >=sci-libs/libsigrok-0.5.1:=[cxx]
  31         dev-qt/qtcore:5
  32         dev-qt/qtgui:5
  33         dev-qt/qtwidgets:5
  34         dev-qt/qtsvg:5
  35         decode? (
  36                 >=sci-libs/libsigrokdecode-0.5.2:=[${PYTHON_USEDEP}]
  37                 ${PYTHON_DEPS}
  38         )"
  39 DEPEND="${RDEPEND}
  40         virtual/pkgconfig"
  41
  42 DOCS=( HACKING NEWS README )
  43
  44 src_configure() {
  45         local mycmakeargs=(
  46                 -DDISABLE_WERROR=TRUE
  47                 -DENABLE_DECODE=$(usex decode)
  48                 -DSTATIC_PKGDEPS_LIBS=$(usex static)
  49         )
  50         cmake-utils_src_configure
  51 }
  52
  53 pkg_postinst() {
  54         gnome2_icon_cache_update
  55         xdg_desktop_database_update
  56 }
  57
  58 pkg_postrm() {
  59         gnome2_icon_cache_update
  60         xdg_desktop_database_update
  61 }