net-voip/telepathy-salut/telepathy-salut-0.8.1-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 )
   7 inherit python-any-r1
   8
   9 DESCRIPTION="A link-local XMPP connection manager for Telepathy"
  10 HOMEPAGE="https://telepathy.freedesktop.org/"
  11 SRC_URI="https://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"
  12
  13 LICENSE="LGPL-2.1"
  14 SLOT="0"
  15 KEYWORDS="alpha amd64 ~arm arm64 ~ia64 ppc ~ppc64 sparc x86 ~x86-linux"
  16 IUSE="gnutls test"
  17 RESTRICT="!test? ( test )"
  18
  19 RDEPEND="
  20         >=dev-libs/dbus-glib-0.61
  21         dev-libs/libxml2
  22         >=dev-libs/glib-2.28:2
  23         >=sys-apps/dbus-1.1.0
  24         >=net-libs/telepathy-glib-0.17.1
  25         >=net-dns/avahi-0.6.22[dbus]
  26         net-libs/libsoup:2.4
  27         sys-apps/util-linux
  28         dev-db/sqlite:3
  29         gnutls? ( >=net-libs/gnutls-2.10.2 )
  30         !gnutls? ( >=dev-libs/openssl-0.9.8g:0[-bindist] )
  31 "
  32 DEPEND="${RDEPEND}
  33         ${PYTHON_DEPS}
  34         dev-libs/libxslt
  35         virtual/pkgconfig
  36         test? (
  37                 >=dev-libs/check-0.9.4
  38                 net-libs/libgsasl
  39                 || (
  40                         $(python_gen_any_dep 'dev-python/twisted[${PYTHON_USEDEP}]')
  41                         $(python_gen_any_dep 'dev-python/twisted-words[${PYTHON_USEDEP}]')
  42                 )
  43         )
  44 "
  45 # FIXME: needs xmppstream python module
  46 #               >=net-dns/avahi-0.6.22[python]
  47
  48 PATCHES=(
  49         "${FILESDIR}"/${PN}-0.5.0-uninitialized.patch # upstream bug #37701
  50         "${FILESDIR}"/${P}-openssl-1.1.patch # bug #663994
  51 )
  52
  53 python_check_deps() {
  54         if use test ; then
  55                  has_version "dev-python/twisted[${PYTHON_USEDEP}]" \
  56                         || has_version "dev-python/twisted-words[${PYTHON_USEDEP}]"
  57         fi
  58 }
  59
  60 pkg_setup() {
  61         python-any-r1_pkg_setup
  62 }
  63
  64 src_configure() {
  65         econf \
  66                 --disable-coding-style-checks \
  67                 --disable-plugins \
  68                 --disable-Werror \
  69                 --disable-static \
  70                 --disable-avahi-tests \
  71                 --docdir=/usr/share/doc/${PF} \
  72                 --with-tls=$(usex gnutls gnutls openssl)
  73                 #$(use_enable test avahi-tests)
  74
  75         # false positives according to bug #413581:
  76         # unrecognized options: --disable-plugins, --disable-avahi-tests
  77 }
  78
  79 src_install() {
  80         MAKEOPTS+=" -j1" default # bug 413581
  81         find "${D}" -name '*.la' -delete || die
  82 }