net-misc/netifrc/netifrc-0.5.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit eutils systemd udev
   7
   8 DESCRIPTION="Gentoo Network Interface Management Scripts"
   9 HOMEPAGE="https://www.gentoo.org/proj/en/base/openrc/"
  10
  11 if [[ ${PV} == "9999" ]]; then
  12         EGIT_REPO_URI="git://anongit.gentoo.org/proj/${PN}.git"
  13         #EGIT_REPO_URI="https://github.com/gentoo/${PN}" # Alternate
  14         inherit git-r3
  15 else
  16         SRC_URI="https://dev.gentoo.org/~robbat2/distfiles/${P}.tar.bz2"
  17         KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
  18 fi
  19
  20 LICENSE="BSD-2"
  21 SLOT="0"
  22 IUSE=""
  23
  24 DEPEND="kernel_linux? ( virtual/pkgconfig )
  25         !<sys-fs/udev-172"
  26 RDEPEND="sys-apps/gentoo-functions
  27         >=sys-apps/openrc-0.15
  28         !<sys-fs/udev-init-scripts-27"
  29
  30 src_prepare() {
  31         if [[ ${PV} == "9999" ]] ; then
  32                 local ver="git-${EGIT_VERSION:0:6}"
  33                 sed -i "/^GITVER[[:space:]]*=/s:=.*:=${ver}:" mk/git.mk || die
  34                 einfo "Producing ChangeLog from Git history"
  35                 GIT_DIR="${S}/.git" git log >"${S}"/ChangeLog
  36         fi
  37
  38         # Allow user patches to be applied without modifying the ebuild
  39         epatch_user
  40 }
  41
  42 src_compile() {
  43         MAKE_ARGS="${MAKE_ARGS}
  44                 UDEVDIR=${EPREFIX}$(get_udevdir)
  45                 LIBEXECDIR=${EPREFIX}/lib/${PN} PF=${PF}"
  46
  47         use prefix && MAKE_ARGS="${MAKE_ARGS} MKPREFIX=yes PREFIX=${EPREFIX}"
  48
  49         emake ${MAKE_ARGS} all
  50 }
  51
  52 src_install() {
  53         emake ${MAKE_ARGS} DESTDIR="${D}" install
  54         dodoc README CREDITS FEATURE-REMOVAL-SCHEDULE STYLE TODO ChangeLog
  55
  56         # Install the service file
  57         LIBEXECDIR=${EPREFIX}/lib/${PN}
  58         UNIT_DIR="$(systemd_get_unitdir)"
  59         sed "s:@LIBEXECDIR@:${LIBEXECDIR}:" "${S}/systemd/net_at.service.in" > "${T}/net_at.service" || die
  60         systemd_newunit "${T}/net_at.service" 'net@.service'
  61         dosym "${UNIT_DIR#${EPREFIX}}/net@.service" "${UNIT_DIR#${EPREFIX}}/net@lo.service"
  62 }
  63
  64 pkg_postinst() {
  65         if [[ ! -e "${EROOT}"/etc/conf.d/net && -z $REPLACING_VERSIONS ]]; then
  66                 elog "The network configuration scripts will use dhcp by"
  67                 elog "default to set up your interfaces."
  68                 elog "If you need to set up something more complete, see"
  69                 elog "${EROOT}/usr/share/doc/${P}/README"
  70         fi
  71 }