net-misc/freerdp/freerdp-2.0.0_rc4.ebuild

   1 # Copyright 2011-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit cmake-utils
   7
   8 if [[ ${PV} != 9999 ]]; then
   9         MY_P=${P/_/-}
  10         S="${WORKDIR}/${MY_P}"
  11         SRC_URI="https://pub.freerdp.com/releases/${MY_P}.tar.gz
  12                 https://github.com/FreeRDP/FreeRDP/commit/6931f54fad12eaf46a72c5c02ac05da817ab6b94.patch -> freerdp-2.0.0-rc4-fix-NTLM-AvPair-lists.patch"
  13         KEYWORDS="alpha amd64 arm arm64 ppc ppc64 x86"
  14 else
  15         inherit git-r3
  16         SRC_URI=""
  17         EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
  18 fi
  19
  20 DESCRIPTION="Free implementation of the Remote Desktop Protocol"
  21 HOMEPAGE="http://www.freerdp.com/"
  22
  23 LICENSE="Apache-2.0"
  24 SLOT="0/2"
  25 IUSE="alsa +client cpu_flags_arm_neon cups debug doc ffmpeg gstreamer jpeg libav libressl openh264 pulseaudio server smartcard systemd test usb wayland X xinerama xv"
  26 RESTRICT="!test? ( test )"
  27
  28 RDEPEND="
  29         !libressl? ( dev-libs/openssl:0= )
  30         libressl? ( dev-libs/libressl:0= )
  31         sys-libs/zlib:0
  32         alsa? ( media-libs/alsa-lib )
  33         cups? ( net-print/cups )
  34         client? (
  35                 usb? (
  36                         virtual/libudev:0=
  37                         sys-apps/util-linux:0=
  38                         dev-libs/dbus-glib:0=
  39                         virtual/libusb:1=
  40                 )
  41                 X? (
  42                         x11-libs/libXcursor
  43                         x11-libs/libXext
  44                         x11-libs/libXi
  45                         x11-libs/libXrender
  46                         xinerama? ( x11-libs/libXinerama )
  47                         xv? ( x11-libs/libXv )
  48                 )
  49         )
  50         ffmpeg? (
  51                 libav? ( media-video/libav:0= )
  52                 !libav? ( media-video/ffmpeg:0= )
  53         )
  54         gstreamer? (
  55                 media-libs/gstreamer:1.0
  56                 media-libs/gst-plugins-base:1.0
  57                 x11-libs/libXrandr
  58         )
  59         jpeg? ( virtual/jpeg:0 )
  60         openh264? ( media-libs/openh264 )
  61         pulseaudio? ( media-sound/pulseaudio )
  62         server? (
  63                 X? (
  64                         x11-libs/libXcursor
  65                         x11-libs/libXdamage
  66                         x11-libs/libXext
  67                         x11-libs/libXfixes
  68                         x11-libs/libXrandr
  69                         x11-libs/libXtst
  70                         xinerama? ( x11-libs/libXinerama )
  71                 )
  72         )
  73         smartcard? ( sys-apps/pcsc-lite )
  74         systemd? ( sys-apps/systemd:0= )
  75         wayland? (
  76                 dev-libs/wayland
  77                 x11-libs/libxkbcommon
  78         )
  79         X? (
  80                 x11-libs/libX11
  81                 x11-libs/libxkbfile
  82         )
  83 "
  84 DEPEND="${RDEPEND}
  85         virtual/pkgconfig
  86         client? ( X? ( doc? (
  87                 app-text/docbook-xml-dtd:4.1.2
  88                 app-text/xmlto
  89         ) ) )
  90 "
  91
  92 PATCHES=(
  93         "${FILESDIR}"/2.0.0-rc4-libressl.patch
  94         "${FILESDIR}"/2.0.0-rc4-bitmap-endian.patch
  95         "${DISTDIR}"/freerdp-2.0.0-rc4-fix-NTLM-AvPair-lists.patch
  96 )
  97
  98 src_configure() {
  99         local mycmakeargs=(
 100                 -DBUILD_TESTING=$(usex test)
 101                 -DCHANNEL_URBDRC=$(usex usb)
 102                 -DWITH_ALSA=$(usex alsa)
 103                 -DWITH_CCACHE=OFF
 104                 -DWITH_CLIENT=$(usex client)
 105                 -DWITH_CUPS=$(usex cups)
 106                 -DWITH_DEBUG_ALL=$(usex debug)
 107                 -DWITH_MANPAGES=$(usex doc)
 108                 -DWITH_FFMPEG=$(usex ffmpeg)
 109                 -DWITH_DSP_FFMPEG=$(usex ffmpeg)
 110                 -DWITH_GSTREAMER_1_0=$(usex gstreamer)
 111                 -DWITH_JPEG=$(usex jpeg)
 112                 -DWITH_NEON=$(usex cpu_flags_arm_neon)
 113                 -DWITH_OPENH264=$(usex openh264)
 114                 -DWITH_PULSE=$(usex pulseaudio)
 115                 -DWITH_SERVER=$(usex server)
 116                 -DWITH_PCSC=$(usex smartcard)
 117                 -DWITH_LIBSYSTEMD=$(usex systemd)
 118                 -DWITH_X11=$(usex X)
 119                 -DWITH_XINERAMA=$(usex xinerama)
 120                 -DWITH_XV=$(usex xv)
 121                 -DWITH_WAYLAND=$(usex wayland)
 122         )
 123         cmake-utils_src_configure
 124 }