net-misc/freerdp/freerdp-2.0.0_rc2-r1.ebuild

   1 # Copyright 2011-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit cmake-utils
   7
   8 if [[ ${PV} != 9999 ]]; then
   9         MY_P=${P/_/-}
  10         S="${WORKDIR}/${MY_P}"
  11         SRC_URI="https://pub.freerdp.com/releases/${MY_P}.tar.gz"
  12         KEYWORDS="alpha amd64 arm ppc ppc64 x86"
  13 else
  14         inherit git-r3
  15         SRC_URI=""
  16         EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
  17 fi
  18
  19 DESCRIPTION="Free implementation of the Remote Desktop Protocol"
  20 HOMEPAGE="http://www.freerdp.com/"
  21
  22 LICENSE="Apache-2.0"
  23 SLOT="0/2"
  24 IUSE="alsa +client cpu_flags_arm_neon cups debug doc ffmpeg gstreamer jpeg libav libressl openh264 pulseaudio server smartcard systemd test usb wayland X xinerama xv"
  25 RESTRICT="!test? ( test )"
  26
  27 RDEPEND="
  28         !libressl? ( dev-libs/openssl:0= )
  29         libressl? ( dev-libs/libressl:0= )
  30         sys-libs/zlib:0
  31         alsa? ( media-libs/alsa-lib )
  32         cups? ( net-print/cups )
  33         client? (
  34                 usb? (
  35                         virtual/libudev:0=
  36                         sys-apps/util-linux:0=
  37                         dev-libs/dbus-glib:0=
  38                         virtual/libusb:1=
  39                 )
  40                 X? (
  41                         x11-libs/libXcursor
  42                         x11-libs/libXext
  43                         x11-libs/libXi
  44                         x11-libs/libXrender
  45                         xinerama? ( x11-libs/libXinerama )
  46                         xv? ( x11-libs/libXv )
  47                 )
  48         )
  49         ffmpeg? (
  50                 libav? ( media-video/libav:0= )
  51                 !libav? ( media-video/ffmpeg:0= )
  52         )
  53         gstreamer? (
  54                 media-libs/gstreamer:1.0
  55                 media-libs/gst-plugins-base:1.0
  56                 x11-libs/libXrandr
  57         )
  58         jpeg? ( virtual/jpeg:0 )
  59         openh264? ( media-libs/openh264 )
  60         pulseaudio? ( media-sound/pulseaudio )
  61         server? (
  62                 X? (
  63                         x11-libs/libXcursor
  64                         x11-libs/libXdamage
  65                         x11-libs/libXext
  66                         x11-libs/libXfixes
  67                         x11-libs/libXrandr
  68                         x11-libs/libXtst
  69                         xinerama? ( x11-libs/libXinerama )
  70                 )
  71         )
  72         smartcard? ( sys-apps/pcsc-lite )
  73         systemd? ( sys-apps/systemd:0= )
  74         wayland? (
  75                 dev-libs/wayland
  76                 x11-libs/libxkbcommon
  77         )
  78         X? (
  79                 x11-libs/libX11
  80                 x11-libs/libxkbfile
  81         )
  82 "
  83 DEPEND="${RDEPEND}
  84         virtual/pkgconfig
  85         client? ( X? ( doc? (
  86                 app-text/docbook-xml-dtd:4.1.2
  87                 app-text/xmlto
  88         ) ) )
  89 "
  90
  91 PATCHES=(
  92         "${FILESDIR}"/2.0.0-rc2-primitives.patch
  93 )
  94
  95 src_configure() {
  96         local mycmakeargs=(
  97                 -DBUILD_TESTING=$(usex test)
  98                 -DCHANNEL_URBDRC=$(usex usb)
  99                 -DWITH_ALSA=$(usex alsa)
 100                 -DWITH_CCACHE=OFF
 101                 -DWITH_CLIENT=$(usex client)
 102                 -DWITH_CUPS=$(usex cups)
 103                 -DWITH_DEBUG_ALL=$(usex debug)
 104                 -DWITH_MANPAGES=$(usex doc)
 105                 -DWITH_FFMPEG=$(usex ffmpeg)
 106                 -DWITH_GSTREAMER_1_0=$(usex gstreamer)
 107                 -DWITH_JPEG=$(usex jpeg)
 108                 -DWITH_NEON=$(usex cpu_flags_arm_neon)
 109                 -DWITH_OPENH264=$(usex openh264)
 110                 -DWITH_PULSE=$(usex pulseaudio)
 111                 -DWITH_SERVER=$(usex server)
 112                 -DWITH_PCSC=$(usex smartcard)
 113                 -DWITH_LIBSYSTEMD=$(usex systemd)
 114                 -DWITH_X11=$(usex X)
 115                 -DWITH_XINERAMA=$(usex xinerama)
 116                 -DWITH_XV=$(usex xv)
 117                 -DWITH_WAYLAND=$(usex wayland)
 118         )
 119         cmake-utils_src_configure
 120 }