net-libs/libktorrent/libktorrent-1.3.1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 KDE_SCM="git"
   8 if [[ ${PV} != 9999* ]]; then
   9         inherit versionator
  10         # upstream likes to skip that _ in beta releases
  11         MY_PV="${PV/_/}"
  12         KTORRENT_VERSION=$(($(get_major_version)+3)).$(get_version_component_range 2-3 ${MY_PV})
  13         MY_P="${PN}-${MY_PV}"
  14         KDE_HANDBOOK="optional"
  15         KDE_DOC_DIRS="doc"
  16
  17         KDE_LINGUAS="ar ast be bg bs ca ca@valencia cs da de el en_GB eo es et eu
  18                 fi fr ga gl hi hne hr hu is it ja km ku lt lv ms nb nds nl nn oc pl
  19                 pt pt_BR ro ru se si sk sl sr sr@ijekavian sr@ijekavianlatin
  20                 sr@latin sv tr ug uk zh_CN zh_TW"
  21         SRC_URI="http://ktorrent.org/downloads/${KTORRENT_VERSION}/${MY_P}.tar.bz2"
  22         S="${WORKDIR}"/"${MY_P}"
  23
  24         KEYWORDS="amd64 ~arm ppc ppc64 x86"
  25 else
  26         KEYWORDS=""
  27 fi
  28 VIRTUALX_REQUIRED="test"
  29 inherit kde4-base
  30
  31 DESCRIPTION="A BitTorrent library based on KDE Platform"
  32 HOMEPAGE="http://ktorrent.pwsp.net/"
  33
  34 LICENSE="GPL-2"
  35 SLOT="4"
  36 IUSE="debug"
  37
  38 RDEPEND="
  39         app-crypt/qca:2[qt4(+)]
  40         dev-libs/gmp:0=
  41         dev-libs/libgcrypt:0=
  42 "
  43 DEPEND="${RDEPEND}
  44         dev-libs/boost
  45         sys-devel/gettext
  46 "
  47
  48 src_prepare() {
  49         kde4-base_src_prepare
  50         # do not build non-installed example binary
  51         sed -i -e '/add_subdirectory(examples)/d' CMakeLists.txt || die
  52 }