net-libs/davix/davix-0.6.7.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-utils
   7
   8 DESCRIPTION="High-performance file management over WebDAV/HTTP"
   9 HOMEPAGE="https://dmc.web.cern.ch/projects/davix"
  10 SRC_URI="http://grid-deployment.web.cern.ch/grid-deployment/dms/lcgutil/tar/${PN}/${PV}/${P}.tar.gz -> ${P}.tar"
  11
  12 LICENSE="LGPL-2.1"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15 IUSE="doc ipv6 kernel_linux test tools"
  16 RESTRICT="!test? ( test )"
  17
  18 CDEPEND="
  19                 dev-libs/libxml2:2=
  20                 dev-libs/openssl:0=
  21                 kernel_linux? ( sys-apps/util-linux )
  22 "
  23
  24 DEPEND="${CDEPEND}
  25                 doc? (
  26                         app-doc/doxygen[dot]
  27                         dev-python/sphinx
  28                 )
  29                 virtual/pkgconfig
  30 "
  31
  32 RDEPEND="${CDEPEND}"
  33
  34 PATCHES=(
  35                 "${FILESDIR}"/${P}-uio.patch
  36                 "${FILESDIR}"/${P}-uuid.patch
  37 )
  38
  39 REQUIRED_USE="test? ( tools )"
  40
  41 src_configure() {
  42         local mycmakeargs=(
  43                 -DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
  44                 -DDOC_INSTALL_DIR="${EPREFIX}/usr/share/doc/${P}"
  45                 -DENABLE_HTML_DOCS=$(usex doc)
  46                 -DENABLE_IPV6=$(usex ipv6)
  47                 -DENABLE_TOOLS=$(usex tools)
  48                 -DHTML_INSTALL_DIR="${EPREFIX}/usr/share/doc/${P}/html"
  49                 -DSOUND_INSTALL_DIR="${EPREFIX}/usr/share/${PN}/sounds"
  50                 -DSTATIC_LIBRARY=OFF
  51                 -DSYSCONF_INSTALL_DIR="${EPREFIX}/etc"
  52                 -DBUILD_TESTING=$(usex test)
  53                 -DUNIT_TESTS=$(usex test)
  54         )
  55         cmake-utils_src_configure
  56 }
  57
  58 src_compile() {
  59         cmake-utils_src_compile
  60         if use doc; then
  61                 cmake-utils_src_compile doc
  62         fi
  63 }
  64
  65 src_install() {
  66         cmake-utils_src_install
  67
  68         if ! use tools; then
  69                 rm -rf "${ED}/usr/share/man/man1"
  70         fi
  71 }