net-analyzer/netcat/netcat-110-r9.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit eutils toolchain-funcs flag-o-matic
   7
   8 PATCH_VER="1.0"
   9 MY_P=nc${PV}
  10 DESCRIPTION="the network swiss army knife"
  11 HOMEPAGE="http://nc110.sourceforge.net/"
  12 SRC_URI="mirror://sourceforge/nc110/${MY_P}.tgz
  13         ftp://sith.mimuw.edu.pl/pub/users/baggins/IPv6/nc-v6-20000918.patch.gz
  14         mirror://gentoo/${P}-patches-${PATCH_VER}.tar.bz2"
  15
  16 LICENSE="netcat"
  17 SLOT="0"
  18 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 m68k ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc64-solaris ~x64-solaris"
  19 IUSE="crypt ipv6 static"
  20
  21 LIB_DEPEND="crypt? ( dev-libs/libmix[static-libs(+)] )"
  22 RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )"
  23 DEPEND="${RDEPEND}
  24         static? ( ${LIB_DEPEND} )"
  25
  26 S=${WORKDIR}
  27
  28 src_prepare() {
  29         epatch "${DISTDIR}"/nc-v6-20000918.patch.gz patch
  30         sed -i 's:#define HAVE_BIND:#undef HAVE_BIND:' netcat.c
  31         sed -i 's:#define FD_SETSIZE 16:#define FD_SETSIZE 1024:' netcat.c #34250
  32         [[ ${CHOST} == *-solaris* ]] && \
  33                 sed -i 's:gethostbyname2(\([^)]\+\)):getipnodebyname(\1, AI_DEFAULT, NULL):' netcat.c
  34 }
  35
  36 src_compile() {
  37         export XLIBS=""
  38         export XFLAGS="-DLINUX -DTELNET -DGAPING_SECURITY_HOLE"
  39         use ipv6 && XFLAGS="${XFLAGS} -DINET6"
  40         use static && export STATIC="-static"
  41         use crypt && XFLAGS="${XFLAGS} -DAESCRYPT" && XLIBS="${XLIBS} -lmix"
  42         [[ ${CHOST} == *-solaris* ]] && XLIBS="${XLIBS} -lnsl -lsocket"
  43         emake -e CC="$(tc-getCC) ${CFLAGS} ${LDFLAGS}" nc
  44 }
  45
  46 src_install() {
  47         dobin nc
  48         dodoc README* netcat.blurb debian-*
  49         doman nc.1
  50         docinto scripts
  51         dodoc scripts/*
  52 }