media-tv/v4l-dvb-saa716x/v4l-dvb-saa716x-0.0.1_p20170225.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit linux-info linux-mod
   7
   8 DESCRIPTION="driver for saa716x based dvb cards like TT S2-6400 or Skystar 2 eXpress HD"
   9 HOMEPAGE="https://bitbucket.org/powARman/v4l-dvb-saa716x/overview"
  10
  11 HG_REVISION="3b9fce66666a"
  12 HG_REVISION_DATE="20160322"
  13
  14 SRC_URI="https://bitbucket.org/powARman/v4l-dvb-saa716x/get/${HG_REVISION}.tar.gz
  15 -> v4l-dvb-saa716x-0.0.1_p${HG_REVISION_DATE}.tar.gz"
  16
  17 LICENSE="GPL-2"
  18 SLOT="0"
  19 KEYWORDS="amd64 ~x86"
  20 IUSE="+firmware"
  21
  22 DEPEND=""
  23 RDEPEND="${DEPEND}
  24         firmware? ( sys-firmware/tt-s2-6400-firmware )"
  25
  26 S="${WORKDIR}/powARman-v4l-dvb-saa716x-${HG_REVISION}"
  27
  28 BUILD_TARGETS="modules"
  29 MODULE_NAMES="saa716x_ff(misc:${EROOT%/}/usr/src/linux:${S}/linux/drivers/media/common/saa716x)
  30         saa716x_core(misc:${EROOT%/}/usr/src/linux:${S}/linux/drivers/media/common/saa716x)
  31         saa716x_budget(misc:${EROOT%/}/usr/src/linux:${S}/linux/drivers/media/common/saa716x)
  32         saa716x_hybrid(misc:${EROOT%/}/usr/src/linux:${S}/linux/drivers/media/common/saa716x)"
  33
  34 CONFIG_CHECK="DVB_CORE DVB_STV6110x DVB_STV090x"
  35
  36 src_prepare() {
  37         default
  38
  39         eapply -p0 "${FILESDIR}/OSD_RAW_CMD_patch_2.diff"
  40         eapply "${FILESDIR}/v4l-dvb-saa716x-Makefilepatch-2.diff"
  41         kernel_is ge 3 19 0 && eapply "${FILESDIR}/v4l-dvb-saa716x-3.19-set_gpio.patch"
  42         kernel_is ge 4 2 0 && eapply "${FILESDIR}/v4l-dvb-saa716x-4.2-fix-compile.patch"
  43         kernel_is ge 4 5 2 && eapply "${FILESDIR}/v4l-dvb-saa716x-4.5.2-fix-compile.patch"
  44         kernel_is ge 4 6 0 && eapply "${FILESDIR}/v4l-dvb-saa716x-4.6.0-fix-compile.patch"
  45         kernel_is ge 4 9 0 && eapply "${FILESDIR}/v4l-dvb-saa716x-4.9-fix-warnings.patch"
  46         kernel_is ge 4 10 0 && eapply "${FILESDIR}/v4l-dvb-saa716x-4.10-fix-compile.patch"
  47 }
  48
  49 src_compile() {
  50         BUILD_PARAMS="SUBDIRS=${S}/linux/drivers/media/common/saa716x \
  51         CONFIG_SAA716X_CORE=m CONFIG_DVB_SAA716X_FF=m CONFIG_DVB_SAA716X_BUDGET=m \
  52         CONFIG_DVB_SAA716X_HYBRID=m"
  53         addpredict "${EROOT%/}"/usr/src/linux/
  54         linux-mod_src_compile
  55 }