media-sound/qmidiarp/qmidiarp-0.6.4-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic qmake-utils
   7
   8 DESCRIPTION="Arpeggiator, sequencer and MIDI LFO for ALSA"
   9 HOMEPAGE="http://qmidiarp.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="nls lv2 osc"
  16
  17 BDEPEND="
  18         nls? ( dev-qt/linguist-tools:5 )
  19         virtual/pkgconfig"
  20 RDEPEND="
  21         dev-qt/qtcore:5
  22         dev-qt/qtgui:5
  23         dev-qt/qtwidgets:5
  24         media-libs/alsa-lib
  25         virtual/jack
  26         lv2? ( media-libs/lv2 )
  27         osc? ( media-libs/liblo )"
  28 DEPEND="${RDEPEND}"
  29
  30 src_configure() {
  31         export PATH="$(qt5_get_bindir):${PATH}"
  32
  33         append-cxxflags -std=c++11
  34
  35         local myeconfargs=(
  36                 --enable-qt5
  37                 $(use_enable lv2 lv2plugins)
  38                 $(use_enable nls translations)
  39                 $(use_enable osc nsm)
  40         )
  41         econf "${myeconfargs[@]}"
  42 }