media-sound/qjackctl/qjackctl-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic qmake-utils autotools git-r3 xdg-utils
   7
   8 DESCRIPTION="Qt GUI to control the JACK Audio Connection Kit and ALSA sequencer connections"
   9 HOMEPAGE="https://qjackctl.sourceforge.io/"
  10 EGIT_REPO_URI="https://git.code.sf.net/p/qjackctl/code"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS=""
  15 IUSE="alsa dbus debug portaudio"
  16
  17 BDEPEND="dev-qt/linguist-tools:5"
  18 RDEPEND="
  19         app-arch/gzip
  20         dev-qt/qtcore:5
  21         dev-qt/qtgui:5
  22         dev-qt/qtwidgets:5
  23         dev-qt/qtx11extras:5
  24         dev-qt/qtxml:5
  25         virtual/jack
  26         alsa? ( media-libs/alsa-lib )
  27         dbus? ( dev-qt/qtdbus:5 )
  28         portaudio? ( media-libs/portaudio )"
  29 DEPEND="${RDEPEND}"
  30
  31 src_prepare() {
  32         default
  33         eautoreconf
  34 }
  35
  36 src_configure() {
  37         append-cxxflags -std=c++11
  38         local myeconfargs=(
  39                 $(use_enable alsa alsa-seq)
  40                 $(use_enable dbus)
  41                 $(use_enable debug)
  42                 $(use_enable portaudio)
  43                 --enable-jack-version
  44         )
  45         econf "${myeconfargs[@]}"
  46         eqmake5 ${PN}.pro -o ${PN}.mak
  47 }
  48
  49 src_compile() {
  50         emake -f ${PN}.mak
  51 }
  52
  53 src_install() {
  54         default
  55
  56         gunzip "${D}/usr/share/man/man1/qjackctl.fr.1.gz" || die
  57         gunzip "${D}/usr/share/man/man1/qjackctl.1.gz" || die
  58 }
  59
  60 pkg_postinst() {
  61         xdg_icon_cache_update
  62 }
  63
  64 pkg_postrm() {
  65         xdg_icon_cache_update
  66 }