media-sound/musescore/musescore-3.4.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 CMAKE_MAKEFILE_GENERATOR="emake"
   7 CHECKREQS_DISK_BUILD=3500M
   8 inherit cmake xdg check-reqs
   9
  10 DESCRIPTION="WYSIWYG Music Score Typesetter"
  11 HOMEPAGE="https://musescore.org/"
  12 # MuseScore_General-0.1.3.tar.bz2 packaged from https://ftp.osuosl.org/pub/musescore/soundfont/MuseScore_General/
  13 # It has to be repackaged because the files are not versioned, current version can be found in VERSION file there.
  14 SRC_URI="https://github.com/musescore/MuseScore/archive/v${PV}.tar.gz -> ${P}.tar.gz
  15         https://dev.gentoo.org/~fordfrog/distfiles/MuseScore_General-0.1.8.tar.bz2"
  16
  17 LICENSE="GPL-2"
  18 SLOT="0"
  19 KEYWORDS="amd64 x86"
  20 IUSE="alsa debug jack mp3 osc omr portaudio portmidi pulseaudio +sf3 sfz webengine"
  21 REQUIRED_USE="portmidi? ( portaudio )"
  22
  23 BDEPEND="
  24         dev-qt/linguist-tools:5
  25         virtual/pkgconfig
  26 "
  27 DEPEND="
  28         dev-qt/designer:5
  29         dev-qt/qtconcurrent:5
  30         dev-qt/qtcore:5
  31         dev-qt/qtdeclarative:5
  32         dev-qt/qtgui:5
  33         dev-qt/qthelp:5
  34         dev-qt/qtnetwork:5
  35         dev-qt/qtprintsupport:5
  36         dev-qt/qtquickcontrols2:5
  37         >=dev-qt/qtsingleapplication-2.6.1_p20171024[X]
  38         dev-qt/qtsvg:5
  39         dev-qt/qtxml:5
  40         dev-qt/qtxmlpatterns:5
  41         >=media-libs/freetype-2.5.2
  42         media-libs/libsndfile
  43         sys-libs/zlib:=
  44         alsa? ( >=media-libs/alsa-lib-1.0.0 )
  45         jack? ( virtual/jack )
  46         mp3? ( media-sound/lame )
  47         omr? ( app-text/poppler )
  48         portaudio? ( media-libs/portaudio )
  49         portmidi? ( media-libs/portmidi )
  50         pulseaudio? ( media-sound/pulseaudio )
  51         sf3? ( media-libs/libvorbis )
  52         webengine? ( dev-qt/qtwebengine:5[widgets] )
  53 "
  54 RDEPEND="${DEPEND}"
  55
  56 PATCHES=(
  57         "${FILESDIR}/${PN}-3.0.1-man-pages.patch"
  58 )
  59
  60 S="${WORKDIR}/MuseScore-${PV}"
  61
  62 src_prepare() {
  63         cmake_src_prepare
  64
  65         # Move soundfonts to the correct directory
  66         mv "${WORKDIR}"/sound/* "${S}"/share/sound/ || die "Failed to move soundfont files"
  67 }
  68
  69 src_configure() {
  70         local mycmakeargs=(
  71                 -DAEOLUS=OFF # does not compile
  72                 -DBUILD_ALSA="$(usex alsa)"
  73                 -DBUILD_CRASH_REPORTER=OFF
  74                 -DBUILD_JACK="$(usex jack)"
  75                 -DBUILD_LAME="$(usex mp3)"
  76                 -DBUILD_PCH=ON
  77                 -DBUILD_PORTAUDIO="$(usex portaudio)"
  78                 -DBUILD_PORTMIDI="$(usex portmidi)"
  79                 -DBUILD_PULSEAUDIO="$(usex pulseaudio)"
  80                 -DBUILD_SHARED_LIBS=ON
  81                 -DBUILD_TELEMETRY_MODULE=ON
  82                 -DBUILD_WEBENGINE="$(usex webengine)"
  83                 -DCMAKE_SKIP_RPATH=ON
  84                 -DDOWNLOAD_SOUNDFONT=OFF
  85                 -DHAS_AUDIOFILE=ON
  86                 -DOCR=OFF
  87                 -DOMR="$(usex omr)"
  88                 -DSOUNDFONT3=ON
  89                 -DZERBERUS="$(usex sfz)"
  90                 -DUSE_PATH_WITH_EXPLICIT_QT_VERSION=ON
  91                 -DUSE_SYSTEM_FREETYPE=ON
  92                 -DUSE_SYSTEM_POPPLER=ON
  93                 -DUSE_SYSTEM_QTSINGLEAPPLICATION=ON
  94         )
  95         cmake_src_configure
  96 }
  97
  98 src_compile() {
  99         cd "${BUILD_DIR}" || die
 100         cmake_build -j1 lrelease manpages
 101         cmake_src_compile
 102 }