media-sound/moc/moc-2.6_alpha3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 MY_P=${PN}-${PV/_/-}
   7 DESCRIPTION="Music On Console - ncurses interface for playing audio files"
   8 HOMEPAGE="https://moc.daper.net"
   9 SRC_URI="http://ftp.daper.net/pub/soft/moc/unstable/${MY_P}.tar.xz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 ~arm ~arm64 ppc ppc64 sparc x86"
  14 IUSE="aac alsa +cache curl debug ffmpeg flac jack libsamplerate mad +magic modplug musepack
  15         oss sid sndfile speex timidity tremor +unicode vorbis wavpack"
  16
  17 RDEPEND="
  18         >=dev-libs/libltdl-2:0
  19         dev-libs/popt
  20         sys-libs/ncurses:0=[unicode?]
  21         aac? ( media-libs/faad2 )
  22         alsa? ( >=media-libs/alsa-lib-1.0.11 )
  23         cache? ( >=sys-libs/db-4.1:= )
  24         curl? ( >=net-misc/curl-7.15.1 )
  25         ffmpeg? ( >=virtual/ffmpeg-9 )
  26         flac? ( >=media-libs/flac-1.1.3 )
  27         jack? ( >=media-sound/jack-audio-connection-kit-0.4 )
  28         libsamplerate? ( >=media-libs/libsamplerate-0.1.0 )
  29         mad? (
  30                 media-libs/libmad
  31                 sys-libs/zlib
  32                 media-libs/libid3tag
  33         )
  34         magic? ( sys-apps/file )
  35         modplug? ( >=media-libs/libmodplug-0.7 )
  36         musepack? (
  37                 media-sound/musepack-tools
  38                 >=media-libs/taglib-1.5
  39         )
  40         sid? ( >=media-libs/libsidplay-2.1.1 )
  41         sndfile? ( >=media-libs/libsndfile-1.0.0 )
  42         speex? ( >=media-libs/speex-1.0.0 )
  43         timidity? (
  44                 >=media-libs/libtimidity-0.1.0
  45                 media-sound/timidity++
  46         )
  47         vorbis? (
  48                 >=media-libs/libogg-1.0
  49                 tremor? ( media-libs/tremor )
  50                 !tremor? ( >=media-libs/libvorbis-1.0 )
  51         )
  52         wavpack? ( >=media-sound/wavpack-4.31 )
  53 "
  54 DEPEND="${RDEPEND}
  55         app-arch/xz-utils
  56         virtual/pkgconfig
  57 "
  58
  59 S=${WORKDIR}/${MY_P}
  60 PATCHES=( "${FILESDIR}/ffmpeg4.patch" )
  61
  62 src_configure() {
  63         local myconf=(
  64                 --docdir="${EPREFIX}"/usr/share/doc/${PF}
  65                 --without-rcc
  66                 $(use_enable debug)
  67                 $(use_enable cache)
  68                 $(use_with oss)
  69                 $(use_with alsa)
  70                 $(use_with jack)
  71                 $(use_with magic)
  72                 $(use_with unicode ncursesw)
  73                 $(use_with libsamplerate samplerate)
  74                 $(use_with aac)
  75                 $(use_with ffmpeg)
  76                 $(use_with flac)
  77                 $(use_with modplug)
  78                 $(use_with mad mp3)
  79                 $(use_with musepack)
  80                 $(use_with sid sidplay2)
  81                 $(use_with sndfile)
  82                 $(use_with speex)
  83                 $(use_with timidity)
  84                 $(use_with vorbis vorbis $(usex tremor tremor ""))
  85                 $(use_with wavpack)
  86                 $(use_with curl)
  87         )
  88
  89         econf "${myconf[@]}"
  90 }
  91
  92 src_install() {
  93         default
  94         find "${D}" -name '*.la' -delete || die
  95 }