media-sound/gnome-music/gnome-music-3.32.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python3_{6,7} )
   6
   7 inherit gnome.org gnome2-utils meson python-single-r1 xdg
   8
   9 DESCRIPTION="Music management for Gnome"
  10 HOMEPAGE="https://wiki.gnome.org/Apps/Music"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 IUSE=""
  15 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  16
  17 KEYWORDS="amd64 ~arm64 x86"
  18
  19 DEPEND="${PYTHON_DEPS}
  20         net-libs/gnome-online-accounts[introspection]
  21         >=dev-libs/gobject-introspection-1.54:=
  22         >=x11-libs/gtk+-3.23.1:3[introspection]
  23         >=dev-libs/libdazzle-3.28.0[introspection]
  24         >=media-libs/libmediaart-1.9.1:2.0[introspection]
  25         net-libs/libsoup:2.4[introspection]
  26         >=app-misc/tracker-1.99.1:=[introspection(+)]
  27         >=dev-python/pygobject-3.29.1:3[cairo,${PYTHON_USEDEP}]
  28         >=dev-python/pycairo-1.14.0[${PYTHON_USEDEP}]
  29         >=media-libs/grilo-0.3.4:0.3[introspection]
  30         >=media-plugins/grilo-plugins-0.3.8:0.3
  31 "
  32 # xdg-user-dirs-update needs to be there to create needed dirs
  33 # https://bugzilla.gnome.org/show_bug.cgi?id=731613
  34 RDEPEND="${DEPEND}
  35         || (
  36                 >=app-misc/tracker-miners-1.99.1[gstreamer]
  37                 >=app-misc/tracker-miners-1.99.1[ffmpeg]
  38         )
  39         x11-libs/libnotify[introspection]
  40         media-libs/gstreamer:1.0[introspection]
  41         media-libs/gst-plugins-base:1.0[introspection]
  42         media-plugins/gst-plugins-meta:1.0
  43         media-plugins/grilo-plugins:0.3[tracker]
  44         x11-misc/xdg-user-dirs
  45 "
  46 BDEPEND="
  47         dev-libs/libxml2:2
  48         dev-util/itstool
  49         >=sys-devel/gettext-0.19.8
  50         virtual/pkgconfig
  51 "
  52
  53 RESTRICT="test" # only does desktop and appdata validation, and latter needs network to validate screenshot from https
  54
  55 pkg_setup() {
  56         python_setup
  57 }
  58
  59 src_prepare() {
  60         sed -e '/sys.path.insert/d' -i "${S}"/gnome-music.in || die "python fixup sed failed"
  61         xdg_src_prepare
  62 }
  63
  64 src_install() {
  65         meson_src_install
  66         python_fix_shebang "${D}"/usr/bin/gnome-music
  67         python_optimize
  68 }
  69
  70 pkg_postinst() {
  71         xdg_pkg_postinst
  72         gnome2_schemas_update
  73 }
  74
  75 pkg_postrm() {
  76         xdg_pkg_postrm
  77         gnome2_schemas_update
  78 }