media-plugins/gst-plugins-opus/gst-plugins-opus-1.16.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GST_ORG_MODULE=gst-plugins-base
   6
   7 inherit gstreamer
   8
   9 DESCRIPTION="Opus audio parser plugin for GStreamer"
  10 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
  11 IUSE=""
  12
  13 COMMON_DEPEND=">=media-libs/opus-1.1:=[${MULTILIB_USEDEP}]"
  14
  15 RDEPEND="${COMMON_DEPEND}
  16         >=media-libs/gst-plugins-base-${PV}:${SLOT}[${MULTILIB_USEDEP},ogg]
  17 "
  18 DEPEND="${COMMON_DEPEND}"
  19
  20 src_prepare() {
  21         default
  22         gstreamer_system_link \
  23                 gst-libs/gst/tag:gstreamer-tag \
  24                 gst-libs/gst/pbutils:gstreamer-pbutils \
  25                 gst-libs/gst/audio:gstreamer-audio
  26 }
  27
  28 # Everything below is for building opusparse from gst-plugins-bad. Once it moves into -base, all below can be removed
  29 SRC_URI+=" https://gstreamer.freedesktop.org/src/gst-plugins-bad/gst-plugins-bad-${PV}.tar.${GST_TARBALL_SUFFIX}"
  30
  31 src_configure() {
  32         multilib-minimal_src_configure
  33         S="${WORKDIR}/gst-plugins-bad-${PV}" multilib-minimal_src_configure
  34 }
  35
  36 src_compile() {
  37         multilib-minimal_src_compile
  38         S="${WORKDIR}/gst-plugins-bad-${PV}" multilib-minimal_src_compile
  39 }
  40
  41 src_install() {
  42         multilib-minimal_src_install
  43         S="${WORKDIR}/gst-plugins-bad-${PV}" multilib-minimal_src_install
  44 }