media-libs/resid/resid-0.16_p2-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools eutils ltprune multilib-minimal versionator
   6
   7 MY_MAJ=$(get_version_component_range 1-2)
   8
   9 DESCRIPTION="C++ library to emulate the C64 SID chip"
  10 HOMEPAGE="http://sidplay2.sourceforge.net"
  11 SRC_URI="mirror://sourceforge/sidplay2/${P/_p/-p}.tgz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~alpha amd64 ppc sparc x86"
  16 IUSE="static-libs"
  17
  18 S=${WORKDIR}/${PN}-${MY_MAJ}
  19
  20 DOCS=(
  21         AUTHORS ChangeLog NEWS README THANKS TODO VC_CC_SUPPORT.txt
  22 )
  23
  24 src_prepare() {
  25         default
  26
  27         # This is required, otherwise the shared libraries get installed as
  28         # libresid.0.0.0 instead of libresid.so.0.0.0.
  29         eautoreconf
  30
  31         multilib_copy_sources
  32 }
  33
  34 multilib_src_configure() {
  35         econf \
  36                 $(use_enable static-libs static) \
  37                 --disable-dependency-tracking \
  38                 --enable-resid-install \
  39                 --enable-shared
  40 }
  41
  42 multilib_src_install() {
  43         default
  44
  45         prune_libtool_files
  46 }