media-libs/netpbm/netpbm-10.70.00.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="4"
   5
   6 inherit toolchain-funcs eutils multilib
   7
   8 DESCRIPTION="A set of utilities for converting to/from the netpbm (and related) formats"
   9 HOMEPAGE="http://netpbm.sourceforge.net/"
  10 SRC_URI="mirror://gentoo/${P}.tar.xz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux"
  15 IUSE="doc jbig jpeg png rle cpu_flags_x86_sse2 static-libs svga tiff X xml zlib"
  16
  17 RDEPEND="jbig? ( media-libs/jbigkit )
  18         jpeg? ( virtual/jpeg:0 )
  19         png? ( >=media-libs/libpng-1.4:0 )
  20         rle? ( media-libs/urt )
  21         svga? ( media-libs/svgalib )
  22         tiff? ( >=media-libs/tiff-3.5.5:0 )
  23         xml? ( dev-libs/libxml2 )
  24         zlib? ( sys-libs/zlib )
  25         X? ( x11-libs/libX11 )"
  26 DEPEND="${RDEPEND}
  27         app-arch/xz-utils
  28         sys-devel/flex"
  29
  30 netpbm_libtype() {
  31         case ${CHOST} in
  32         *-darwin*) echo dylib;;
  33         *)         echo unixshared;;
  34         esac
  35 }
  36 netpbm_libsuffix() {
  37         local suffix=$(get_libname)
  38         echo ${suffix//\.}
  39 }
  40 netpbm_ldshlib() {
  41         case ${CHOST} in
  42         *-darwin*) echo '$(LDFLAGS) -dynamiclib -install_name $(SONAME)';;
  43         *)         echo '$(LDFLAGS) -shared -Wl,-soname,$(SONAME)';;
  44         esac
  45 }
  46 netpbm_config() {
  47         if use $1 ; then
  48                 [[ $2 != "!" ]] && echo -l${2:-$1}
  49         else
  50                 echo NONE
  51         fi
  52 }
  53
  54 src_prepare() {
  55         epatch "${FILESDIR}"/netpbm-10.31-build.patch
  56         epatch "${FILESDIR}"/netpbm-10.66-test.patch #450530
  57         epatch "${FILESDIR}"/netpbm-10.70-system-libs.patch
  58
  59         # make sure we use system libs
  60         sed -i '/SUPPORT_SUBDIRS/s:urt::' GNUmakefile || die
  61         rm -r urt converter/other/jbig/libjbig converter/other/jpeg2000/libjasper || die
  62
  63         # disable certain tests based on active USE flags
  64         local del=(
  65                 $(usex jbig '' 'jbigtopnm pnmtojbig jbig-roundtrip')
  66                 $(usex rle '' 'utahrle-roundtrip')
  67                 $(usex tiff '' 'tiff-roundtrip')
  68         )
  69         if [[ ${#del[@]} -gt 0 ]] ; then
  70                 sed -i -r $(printf -- ' -e /%s.test/d' "${del[@]}") test/Test-Order || die
  71         fi
  72         del=(
  73                 pnmtofiasco fiascotopnm # We always disable fiasco
  74                 $(usex jpeg '' 'jpegtopnm pnmtojpeg ppmtojpeg')
  75                 $(usex jbig '' 'jbigtopnm pnmtojbig')
  76                 jpeg2ktopam pamtojpeg2k # jasper has been removed
  77                 $(usex rle '' 'pnmtorle rletopnm')
  78                 $(usex tiff '' 'pamtotiff pnmtotiff pnmtotiffcmyk tifftopnm')
  79         )
  80         if [[ ${#del[@]} -gt 0 ]] ; then
  81                 sed -i -r $(printf -- ' -e s/\<%s\>(:.ok)?//' "${del[@]}") test/all-in-place.{ok,test} || die
  82                 sed -i '/^$/d' test/all-in-place.ok || die
  83         fi
  84
  85         # take care of the importinc stuff ourselves by only doing it once
  86         # at the top level and having all subdirs use that one set #149843
  87         sed -i \
  88                 -e '/^importinc:/s|^|importinc:\nmanual_|' \
  89                 -e '/-Iimportinc/s|-Iimp|-I"$(BUILDDIR)"/imp|g'\
  90                 common.mk || die
  91         sed -i \
  92                 -e '/%.c/s: importinc$::' \
  93                 common.mk lib/Makefile lib/util/Makefile || die
  94
  95         # avoid ugly depend.mk warnings
  96         touch $(find . -name Makefile | sed s:Makefile:depend.mk:g)
  97 }
  98
  99 src_configure() {
 100         cat config.mk.in - >> config.mk <<-EOF
 101         # Misc crap
 102         BUILD_FIASCO = N
 103         SYMLINK = ln -sf
 104
 105         # These vars let src_test work by default
 106         PKGDIR_DEFAULT = ${T}/netpbm
 107         RESULTDIR_DEFAULT = ${T}/netpbm-test
 108
 109         # Toolchain options
 110         CC = $(tc-getCC) -Wall
 111         LD = \$(CC)
 112         CC_FOR_BUILD = $(tc-getBUILD_CC)
 113         LD_FOR_BUILD = \$(CC_FOR_BUILD)
 114         AR = $(tc-getAR)
 115         RANLIB = $(tc-getRANLIB)
 116
 117         STRIPFLAG =
 118         CFLAGS_SHLIB = -fPIC
 119
 120         LDRELOC = \$(LD) -r
 121         LDSHLIB = $(netpbm_ldshlib)
 122         LINKER_CAN_DO_EXPLICIT_LIBRARY = N # we can, but dont want to
 123         LINKERISCOMPILER = Y
 124         NETPBMLIBSUFFIX = $(netpbm_libsuffix)
 125         NETPBMLIBTYPE = $(netpbm_libtype)
 126         STATICLIB_TOO = $(usex static-libs Y N)
 127
 128         # The var is called SSE, but the code is actually SSE2.
 129         WANT_SSE = $(usex cpu_flags_x86_sse2 Y N)
 130
 131         # Gentoo build options
 132         TIFFLIB = $(netpbm_config tiff)
 133         # Let tiff worry about its own dependencies #395753
 134         TIFFLIB_NEEDS_JPEG = N
 135         TIFFLIB_NEEDS_Z = N
 136         JPEGLIB = $(netpbm_config jpeg)
 137         PNGLIB = $(netpbm_config png)
 138         ZLIB = $(netpbm_config zlib z)
 139         LINUXSVGALIB = $(netpbm_config svga vga)
 140         XML2_LIBS = $(netpbm_config xml xml2)
 141         JBIGLIB = $(netpbm_config jbig)
 142         JBIGHDR_DIR =
 143         JASPERLIB = NONE
 144         JASPERHDR_DIR =
 145         URTLIB = $(netpbm_config rle)
 146         URTHDR_DIR =
 147         X11LIB = $(netpbm_config X X11)
 148         X11HDR_DIR =
 149         EOF
 150         # cannot chain the die with the heredoc above as bash-3
 151         # has a parser bug in that setup #282902
 152         [ $? -eq 0 ] || die "writing config.mk failed"
 153 }
 154
 155 src_compile() {
 156         emake -j1 pm_config.h version.h manual_importinc #149843
 157         emake
 158 }
 159
 160 src_test() {
 161         # The code wants to install everything first and then test the result.
 162         emake install.{bin,lib}
 163         emake check
 164 }
 165
 166 src_install() {
 167         # Subdir make targets like to use `mkdir` all over the place
 168         # without any actual dependencies, thus the -j1.
 169         emake -j1 package pkgdir="${ED}"/usr
 170
 171         [[ $(get_libdir) != "lib" ]] && mv "${ED}"/usr/lib "${ED}"/usr/$(get_libdir)
 172
 173         # Remove cruft that we don't need, and move around stuff we want
 174         rm "${ED}"/usr/bin/{doc.url,manweb} || die
 175         rm -r "${ED}"/usr/man/web || die
 176         rm -r "${ED}"/usr/link || die
 177         rm "${ED}"/usr/{README,VERSION,{pkgconfig,config}_template,pkginfo} || die
 178         dodir /usr/share
 179         mv "${ED}"/usr/man "${ED}"/usr/share/ || die
 180         mv "${ED}"/usr/misc "${ED}"/usr/share/netpbm || die
 181
 182         doman userguide/*.[0-9]
 183         use doc && dohtml -r userguide
 184         dodoc README
 185         cd doc
 186         dodoc HISTORY Netpbm.programming USERDOC
 187         dohtml -r .
 188 }