media-libs/lilv/lilv-0.24.4-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python{2_7,3_6,3_7} )
   7 PYTHON_REQ_USE='threads(+)'
   8
   9 inherit python-any-r1 waf-utils bash-completion-r1 multilib-build multilib-minimal
  10
  11 DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
  12 HOMEPAGE="http://drobilla.net/software/lilv/"
  13 SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
  14
  15 LICENSE="ISC"
  16 SLOT="0"
  17 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ppc ppc64 ~sparc x86"
  18 IUSE="doc +dyn-manifest static-libs test"
  19 RESTRICT="!test? ( test )"
  20
  21 RDEPEND="
  22         >=dev-libs/serd-0.28.0-r1[${MULTILIB_USEDEP}]
  23         >=dev-libs/sord-0.16.0-r1[${MULTILIB_USEDEP}]
  24         media-libs/libsndfile
  25         >=media-libs/lv2-1.14.0-r1[${MULTILIB_USEDEP}]
  26         >=media-libs/sratom-0.6.0-r1[${MULTILIB_USEDEP}]
  27 "
  28 DEPEND="${RDEPEND}
  29         ${PYTHON_DEPS}
  30         doc? ( app-doc/doxygen )
  31         virtual/pkgconfig[${MULTILIB_USEDEP}]
  32 "
  33
  34 PATCHES=( "${FILESDIR}/includedir.patch" )
  35
  36 src_prepare() {
  37         default
  38         sed -i -e 's/^.*run_ldconfig/#\0/' wscript || die
  39         multilib_copy_sources
  40 }
  41
  42 multilib_src_configure() {
  43         waf-utils_src_configure \
  44                 --docdir="${EPREFIX}"/usr/share/doc/${PF} \
  45                 --no-bash-completion \
  46                 $(multilib_native_usex doc --docs "") \
  47                 $(usex test --test "") \
  48                 $(usex static-libs --static "") \
  49                 $(usex dyn-manifest --dyn-manifest "")
  50 }
  51
  52 multilib_src_test() {
  53         ./waf test || die
  54 }
  55
  56 multilib_src_install() {
  57         waf-utils_src_install
  58 }
  59
  60 multilib_src_install_all() {
  61         newbashcomp utils/lilv.bash_completion ${PN}
  62         dodir /etc/env.d
  63         echo "LV2_PATH=${EPREFIX}/usr/$(get_libdir)/lv2" > "${ED}/etc/env.d/60lv2"
  64 }