media-libs/libsndfile/libsndfile-1.0.28-r4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python{2_7,3_6} pypy3 )
   7
   8 inherit python-any-r1 multilib-minimal
   9
  10 MY_P=${P/_pre/pre}
  11
  12 DESCRIPTION="C library for reading and writing files containing sampled sound"
  13 HOMEPAGE="http://www.mega-nerd.com/libsndfile"
  14 if [[ ${MY_P} == ${P} ]]; then
  15         SRC_URI="http://www.mega-nerd.com/libsndfile/files/${P}.tar.gz"
  16 else
  17         SRC_URI="http://www.mega-nerd.com/tmp/${MY_P}b.tar.gz"
  18 fi
  19
  20 LICENSE="LGPL-2.1"
  21 SLOT="0"
  22 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 ~sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  23 IUSE="alsa minimal sqlite static-libs test"
  24 RESTRICT="!test? ( test )"
  25
  26 RDEPEND="
  27         !minimal? (
  28                 >=media-libs/flac-1.2.1-r5[${MULTILIB_USEDEP}]
  29                 >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
  30                 >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}]
  31         )
  32         alsa? ( media-libs/alsa-lib )
  33         sqlite? ( >=dev-db/sqlite-3.2 )"
  34 DEPEND="${RDEPEND}"
  35 BDEPEND="
  36         virtual/pkgconfig
  37         test? ( ${PYTHON_DEPS} )"
  38
  39 S=${WORKDIR}/${MY_P}
  40
  41 PATCHES=(
  42         "${FILESDIR}"/${P}-arm-varargs-failure.patch
  43         "${FILESDIR}"/${P}-CVE-2017-12562.patch
  44         "${FILESDIR}"/${P}-CVE-2018-13139.patch
  45         "${FILESDIR}"/${P}-CVE-2017-6892.patch
  46         "${FILESDIR}"/${P}-CVE-2017-836{3,5,2}.patch
  47         "${FILESDIR}"/${P}-CVE-2017-14634.patch
  48 )
  49
  50 pkg_setup() {
  51         use test && python-any-r1_pkg_setup
  52 }
  53
  54 multilib_src_configure() {
  55         ECONF_SOURCE="${S}" econf \
  56                 --disable-octave \
  57                 --enable-gcc-pipe \
  58                 --enable-gcc-opt \
  59                 $(use_enable static-libs static) \
  60                 $(use_enable !minimal external-libs) \
  61                 $(multilib_native_enable full-suite) \
  62                 $(multilib_native_use_enable alsa) \
  63                 $(multilib_native_use_enable sqlite)
  64 }
  65
  66 multilib_src_install_all() {
  67         einstalldocs
  68
  69         # package provides .pc files
  70         find "${D}" -name '*.la' -delete || die
  71 }