media-libs/libogg/libogg-1.3.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit multilib-minimal
   6
   7 DESCRIPTION="the Ogg media file format library"
   8 HOMEPAGE="https://xiph.org/ogg/"
   9 SRC_URI="https://downloads.xiph.org/releases/ogg/${P}.tar.xz"
  10
  11 LICENSE="BSD"
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  14 IUSE="static-libs"
  15
  16 DOCS=( AUTHORS CHANGES )
  17
  18 MULTILIB_WRAPPED_HEADERS=(
  19         /usr/include/ogg/config_types.h
  20 )
  21
  22 multilib_src_configure() {
  23         local myeconfargs=(
  24                 --htmldir="${EPREFIX}"/usr/share/doc/${PF}/html
  25                 $(use_enable static-libs static)
  26                 )
  27         ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
  28 }
  29
  30 multilib_src_install_all() {
  31         einstalldocs
  32         find "${ED}" -name "*.la" -delete || die
  33 }