media-libs/jpeg/jpeg-9c.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit libtool toolchain-funcs multilib-minimal
   7
   8 DESCRIPTION="Library to load, handle and manipulate images in the JPEG format"
   9 HOMEPAGE="http://jpegclub.org/ http://www.ijg.org/"
  10 SRC_URI="http://www.ijg.org/files/${PN}src.v${PV}.tar.gz
  11         mirror://debian/pool/main/libj/lib${PN}8/lib${PN}8_8d-1.debian.tar.gz"
  12
  13 LICENSE="IJG"
  14 SLOT="0"
  15 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 m68k ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  16 IUSE="static-libs"
  17
  18 DEPEND=""
  19 RDEPEND="!media-libs/libjpeg-turbo:0"
  20
  21 DOCS=( change.log example.c README {coderules,filelist,install,jconfig,libjpeg,structure,usage,wizard}.txt )
  22
  23 PATCHES=( "${FILESDIR}"/${PN}-7-maxmem_sysconf.patch )
  24
  25 src_prepare() {
  26         default
  27         elibtoolize
  28 }
  29
  30 multilib_src_configure() {
  31         # Fix building against this library on eg. Solaris and DragonFly BSD, see:
  32         # http://mail-index.netbsd.org/pkgsrc-bugs/2010/01/18/msg035644.html
  33         local ldverscript=
  34         [[ ${CHOST} == *-solaris* ]] && ldverscript="--disable-ld-version-script"
  35
  36         ECONF_SOURCE=${S} \
  37         econf \
  38                 $(use_enable static-libs static) \
  39                 --enable-maxmem=64 \
  40                 ${ldverscript}
  41 }
  42
  43 multilib_src_compile() {
  44         emake
  45
  46         if multilib_is_native_abi; then
  47                 # Build exifautotran and jpegexiforient
  48                 cd ../debian/extra
  49                 emake CC="$(tc-getCC)" CFLAGS="${LDFLAGS} ${CFLAGS}"
  50         fi
  51 }
  52
  53 multilib_src_install() {
  54         emake DESTDIR="${D}" install
  55 }
  56
  57 multilib_src_install_all() {
  58         find "${D}" -name '*.la' -delete || die
  59
  60         einstalldocs
  61
  62         # Install exifautotran and jpegexiforient
  63         newdoc ../debian/changelog changelog.debian
  64         cd ../debian/extra
  65         emake \
  66                 DESTDIR="${D}" prefix="${EPREFIX}"/usr \
  67                 INSTALL="install -m755" INSTALLDIR="install -d -m755" \
  68                 install
  69         # Remove +x bits from man pages.
  70         find "${ED}"/usr/share/man/ -type f -perm /1 -exec chmod a-x {} + || die
  71 }