media-libs/jbigkit/jbigkit-2.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit eutils multilib toolchain-funcs multilib-minimal
   7
   8 DESCRIPTION="data compression algorithm for bi-level high-resolution images"
   9 HOMEPAGE="http://www.cl.cam.ac.uk/~mgk25/jbigkit/"
  10 SRC_URI="http://www.cl.cam.ac.uk/~mgk25/download/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0/2.1" # Since we install libjbig.so and libjbig85.so without version, use ${PV} like 2.1
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 m68k ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="static-libs"
  16
  17 DOCS="ANNOUNCE CHANGES TODO libjbig/*.txt pbmtools/*.txt"
  18
  19 src_prepare() {
  20         epatch "${FILESDIR}"/${P}-build.patch
  21         multilib_copy_sources
  22         tc-export AR CC RANLIB
  23 }
  24
  25 multilib_src_compile() {
  26         emake \
  27                 LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
  28                 $(multilib_is_native_abi || echo lib)
  29
  30         if use static-libs; then
  31                 cd libjbig && emake static
  32         fi
  33 }
  34
  35 multilib_src_test() {
  36         LD_LIBRARY_PATH=${BUILD_DIR}/libjbig emake -j1 test
  37 }
  38
  39 multilib_src_install() {
  40         if multilib_is_native_abi; then
  41                 dobin pbmtools/jbgtopbm{,85} pbmtools/pbmtojbg{,85}
  42                 doman pbmtools/jbgtopbm.1 pbmtools/pbmtojbg.1
  43         fi
  44
  45         insinto /usr/include
  46         doins libjbig/*.h
  47         dolib libjbig/libjbig{,85}$(get_libname)
  48         use static-libs && dolib libjbig/libjbig{,85}.a
  49 }