media-gfx/opentoonz/opentoonz-1.4.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake xdg-utils
   7
   8 DESCRIPTION="An open-source full-featured 2D animation creation software"
   9 HOMEPAGE="https://github.com/opentoonz/opentoonz"
  10 SRC_URI="https://github.com/opentoonz/opentoonz/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="BSD libtiff"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15
  16 BDEPEND="
  17         dev-qt/linguist-tools:5
  18         virtual/pkgconfig
  19 "
  20 RDEPEND="
  21         app-arch/lz4:=
  22         >=dev-libs/boost-1.55.0:=
  23         dev-libs/lzo:2
  24         >=dev-qt/qtcore-5.9:5
  25         >=dev-qt/qtgui-5.9:5
  26         >=dev-qt/qtmultimedia-5.9:5[widgets]
  27         >=dev-qt/qtnetwork-5.9:5
  28         >=dev-qt/qtopengl-5.9:5
  29         >=dev-qt/qtprintsupport-5.9:5
  30         >=dev-qt/qtscript-5.9:5
  31         >=dev-qt/qtsvg-5.9:5
  32         >=dev-qt/qtwidgets-5.9:5
  33         >=dev-qt/qtxml-5.9:5
  34         media-libs/freeglut
  35         media-libs/freetype:2
  36         media-libs/glew:=
  37         media-libs/libjpeg-turbo
  38         >=media-libs/libmypaint-1.3.0:=
  39         media-libs/libpng:=
  40         >=sci-libs/superlu-4.1:=
  41         sys-libs/zlib
  42         virtual/cblas
  43         virtual/libusb:1
  44         virtual/opengl
  45 "
  46 DEPEND="
  47         ${RDEPEND}
  48 "
  49
  50 CMAKE_USE_DIR="${S}"/toonz/sources
  51 CMAKE_MAKEFILE_GENERATOR=emake
  52
  53 src_configure() {
  54         local mycmakeargs=(
  55                 -DTIFF_LIBRARY="${S}/thirdparty/tiff-4.0.3/libtiff/.libs/libtiff.a"
  56                 -DSUPERLU_INCLUDE_DIR="${EPREFIX}/usr/include/superlu"
  57                 -DLZO_INCLUDE_DIR="${EPREFIX}/usr/include/lzo"
  58                 -DCMAKE_SKIP_RPATH=ON
  59         )
  60
  61         # The upstream uses their own modified libtiff
  62         # See: https://github.com/opentoonz/opentoonz/blob/master/doc/how_to_build_linux.md#building-libtiff
  63         cd thirdparty/tiff-4.0.3 || die
  64         econf \
  65                 --with-pic \
  66                 --disable-jbig \
  67                 --enable-static \
  68                 --disable-shared
  69
  70         cmake_src_configure
  71 }
  72
  73 src_compile() {
  74         cd "${S}"/thirdparty/tiff-4.0.3 || die
  75         emake
  76
  77         cmake_src_compile
  78 }
  79
  80 pkg_postinst() {
  81         xdg_icon_cache_update
  82 }
  83
  84 pkg_postrm() {
  85         xdg_icon_cache_update
  86 }