media-gfx/openscad/openscad-2019.05-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit elisp-common qmake-utils xdg
   7
   8 SITEFILE="50${PN}-gentoo.el"
   9
  10 DESCRIPTION="The Programmers Solid 3D CAD Modeller"
  11 HOMEPAGE="https://www.openscad.org/"
  12 SRC_URI="https://github.com/${PN}/${PN}/releases/download/${P}/${P}.src.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86"
  17 IUSE="emacs"
  18
  19 PATCHES=(
  20         "${FILESDIR}/${PN}-2019.05_fix-boost-1.72.0-build.patch"
  21 )
  22
  23 # FIXME: add optional lib3mf
  24 RDEPEND="
  25         dev-cpp/eigen:3
  26         dev-libs/boost:=
  27         dev-libs/double-conversion:=
  28         dev-libs/glib:2
  29         dev-libs/gmp:0=
  30         dev-libs/hidapi
  31         dev-libs/libspnav
  32         dev-libs/libzip:=
  33         dev-libs/mpfr:0=
  34         dev-qt/qtconcurrent:5
  35         dev-qt/qtcore:5
  36         dev-qt/qtdbus:5
  37         dev-qt/qtgui:5[-gles2-only]
  38         dev-qt/qtmultimedia:5
  39         dev-qt/qtnetwork:5
  40         dev-qt/qtopengl:5
  41         dev-qt/qtwidgets:5
  42         media-gfx/opencsg
  43         media-libs/fontconfig
  44         media-libs/freetype
  45         >=media-libs/glew-2.0.0:0=
  46         media-libs/harfbuzz:=
  47         sci-mathematics/cgal:=
  48         >=x11-libs/qscintilla-2.10.3:=
  49         emacs? ( >=app-editors/emacs-23.1:* )
  50 "
  51 DEPEND="${RDEPEND}"
  52 BDEPEND="
  53         sys-devel/bison
  54         sys-devel/flex
  55         virtual/pkgconfig
  56 "
  57
  58 src_prepare() {
  59         default
  60
  61         # fix path prefix
  62         sed -i "s/\/usr\/local/\/usr/g" ${PN}.pro || die
  63 }
  64
  65 src_configure() {
  66         eqmake5 "${PN}.pro"
  67 }
  68
  69 src_compile() {
  70         default
  71
  72         if use emacs ; then
  73                 elisp-compile contrib/*.el
  74         fi
  75 }
  76
  77 src_install() {
  78         emake install INSTALL_ROOT="${D}"
  79
  80         if use emacs; then
  81                 elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  82                 elisp-install ${PN} contrib/*.el contrib/*.elc
  83         fi
  84
  85         einstalldocs
  86 }