media-gfx/gscan2pdf/gscan2pdf-2.6.7.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DIST_TEST="do"
   7
   8 inherit eutils perl-module virtualx xdg-utils
   9
  10 DESCRIPTION="Scan documents, perform OCR, produce PDFs and DjVus"
  11 HOMEPAGE="http://gscan2pdf.sourceforge.net/"
  12 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
  13
  14 LICENSE="GPL-3"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE="test"
  18 RESTRICT="!test? ( test )"
  19
  20 RDEPEND="
  21         dev-perl/Config-General
  22         dev-perl/Data-UUID
  23         dev-perl/Date-Calc
  24         dev-perl/Filesys-Df
  25         dev-perl/glib-perl
  26         dev-perl/GooCanvas2
  27         dev-perl/Gtk3
  28         dev-perl/Gtk3-SimpleList
  29         dev-perl/HTML-Parser
  30         dev-perl/Image-Sane
  31         dev-perl/List-MoreUtils
  32         dev-perl/Locale-gettext
  33         dev-perl/Log-Log4perl
  34         dev-perl/PDF-API2
  35         dev-perl/Proc-ProcessTable
  36         dev-perl/Readonly
  37         dev-perl/Set-IntSpan
  38         dev-perl/Try-Tiny
  39         virtual/perl-Archive-Tar
  40         virtual/perl-Carp
  41         virtual/perl-Data-Dumper
  42         virtual/perl-File-Temp
  43         virtual/perl-Getopt-Long
  44         virtual/perl-threads
  45         virtual/perl-threads-shared
  46         media-gfx/imagemagick[png,tiff,perl]
  47         media-gfx/sane-backends
  48         media-libs/tiff"
  49
  50 BDEPEND="
  51         test? (
  52                 ${RDEPEND}
  53                 dev-perl/Sub-Override
  54                 media-libs/fontconfig
  55
  56                 app-text/djvu[tiff]
  57                 app-text/poppler[utils]
  58                 app-text/tesseract[-opencl,osd(+),tiff]
  59                 app-text/unpaper
  60                 media-gfx/imagemagick[djvu,png,tiff,perl]
  61                 media-gfx/sane-backends[sane_backends_test]
  62                 media-gfx/sane-frontends
  63         )"
  64
  65 PERL_RM_FILES=( t/{90_MANIFEST,91_critic,99_pod}.t )
  66
  67 mydoc="History"
  68
  69 pkg_postinst() {
  70         xdg_desktop_database_update
  71
  72         optfeature "DjVu file support" "app-text/djvu[tiff] media-gfx/imagemagick[djvu]"
  73         optfeature "encrypting PDFs" app-text/pdftk
  74         optfeature "creating PostScript files from PDFs" app-text/poppler[utils]
  75         optfeature "adding to an existing PDF" app-text/poppler[utils]
  76         optfeature "Optical Character Recognition" app-text/tesseract[osd,tiff]
  77         optfeature "scan post-processing" app-text/unpaper
  78         optfeature "automatic document feeder support" media-gfx/sane-frontends
  79         optfeature "sending PDFs as email attachments" x11-misc/xdg-utils
  80 }
  81
  82 pkg_postrm() {
  83         xdg_desktop_database_update
  84 }
  85
  86 src_test() {
  87         local confdir="${HOME}/.config/ImageMagick"
  88         mkdir -p "${confdir}" || die
  89         cat > "${confdir}/policy.xml" <<-EOT || die
  90                 <policymap>
  91                         <policy domain="coder" rights="read|write" pattern="PDF" />
  92                         <policy domain="coder" rights="read" pattern="PS" />
  93                 </policymap>
  94         EOT
  95         NO_AT_BRIDGE=1 virtx perl-module_src_test
  96 }